Вывести определённую информацию о всех компьютерах в сети

Dim objRoot, strDomain, strTemp, blnTemp
Dim objConnection, objCommand, objRSet
Const ADS_SCOPE_SUBTREE = 2
Const ADS_UF_ACCOUNTDISABLE = 2
 
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
objCommand.CommandText = "SELECT cn,userAccountControl,operatingSystem FROM 'LDAP://" & strDomain & "' WHERE objectCategory='Computer'"
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 30
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRSet = objCommand.Execute
objRSet.MoveFirst
Do
    If Not (objRSet.Fields("userAccountControl").Value AND ADS_UF_ACCOUNTDISABLE) Then
        strTemp = objRSet.Fields("operatingSystem").Value
        If Not IsNull(strTemp) Then
            If InStr(1, strTemp, "server", vbTextCompare) = 0 And InStr(1, strTemp, "2000", vbTextCompare) = 0 Then
                WScript.Echo objRSet.Fields("cn").Value & " -> " & strTemp
            End If
        End If
    End If
    objRSet.MoveNext
Loop While Not objRSet.EOF
Set objRSet = Nothing: Set objCommand = Nothing
objConnection.Close: Set objConnection = Nothing
WScript.Quit 0

Dim objShell, objExec, objOutStream, strWS, strTemp, intLBracket, intRBracket, strIP
 
strWS = "anycomputer"
Set objShell = CreateObject("WScript.Shell")
Set objExec = objShell.Exec("ping -n 1 -w 130 " & strWS)
Set objOutStream = objExec.StdOut
strTemp = vbNullString
While Not objOutStream.AtEndOfStream
    strTemp = strTemp & Trim(objOutStream.ReadLine)
Wend
intLBracket = InStr(1, strTemp, "[")
If intLBracket > 0 Then
    intRBracket = InStr(1, strTemp, "]")
    strIP = Mid(strTemp, intLBracket + 1, intRBracket - intLBracket - 1)
    If InStr(1, strTemp, "TTL", vbTextCompare) > 0 Then
        WScript.Echo "[ + ] " & strWS & " = " & strIP
    Else
        WScript.Echo "[ - ] " & strWS & " = " & strIP
    End If
End If
WScript.Quit 0

Dim strWS, intStatus, strUser
 
strWS = "anycomputer"
Dim strWS, strUser, intStatus
 
strUser = Logged_Session(strWS, intStatus)
If intStatus >= 0 Then
    WScript.Echo strWS & " -> "  & strUser
Else
    WScript.Echo strWS & " -> " & strUser
End If
WScript.Quit 0
 
'======
 
Function Logged_Session(strComputer, intStat)
Dim objWMI, objCollection, objItem, strName, strTemp
Dim arrParameters, strRegShell, strRegUser, strRegDomain, i
 
strName = vbNullString
On Error Resume Next
Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!" & strComputer & "\root\cimv2")
If Err.Number = 0 Then
    Set objCollection = objWMI.ExecQuery("SELECT UserName FROM Win32_ComputerSystem")
    If Err.Number = 0 Then
        For Each objItem In objCollection
            If Err.Number = 0 Then
                strName = objItem.UserName
                If IsNull(strName) Then
                    strName = "сеанс не обнаружен"
                    intStat = 2
                Else
                    intStat = 0
                End If
            Else
                Err.Clear
                strName = "неидентифицированный сеанс"
                intStat = 1
            End If
        Next
        Set objItem = Nothing
    Else
        Err.Clear
        strName = "не удалось выполнить запрос"
        intStat = -1
    End If
    Set objCollection = Nothing
Else
    Err.Clear
    strName = "подключение не разрешено"
    intStat = -1
End If
Set objWMI = Nothing
On Error GoTo 0
Logged_Session = strName
End Function