Скрипт для перезагрузки роутера по значению внешнего IP

Option Explicit
Const Login = "admin"
Const Passw = "12345"
Const Limit = 100  ' макс. число перезапусков роутера
Const IpURL = "http://ipinfo.io/ip"
'—————————————————————————————————————————
Dim oHTTP, IP, oWSH, oWMI, PID, i
Set oHTTP = CreateObject("Msxml2.XMLHTTP")
 
On Error Resume Next
With oHTTP
   .Open "GET", IpURL, 0: .Send 0: .Abort
End With
If Err.Number <> 0 Then MsgBox "Смените URL для получения IP!", 4144: Quit
On Error Goto 0
 
Set oWSH = CreateObject("WScript.Shell")
Set oWMI = GetObject("winmgmts:\root\cimv2")
With oWMI.Get("Win32_Process.Handle='" & oWSH.Exec("rundll32 kernel32,Sleep").ProcessId & "'")
   PID = .ParentProcessId: .Terminate
End With
IP = 85: oWSH.Run "%ComSpec%"
For Each i In oWMI.ExecQuery("SELECT Handle FROM Win32_Process WHERE ParentProcessId=" & PID)
   PID = i.Handle: i = 0
Next
While Split(IP, ".")(0) = 85
   If i = Limit Then Quit() Else i = i + 1
   Send 100, "cls~telnet 192.168.0.1~"
   Send 300, Login & "~"
   Send 100, Passw & "~"
   Send 100, "reboot~"
   While oWMI.Get("Win32_PingStatus.Address='ya.ru'").StatusCode
      WSH.Sleep 300
   Wend
   With oHTTP
      .Open "GET", IpURL, 0: .Send 0: IP = .ResponseText: .Abort
   End With
Wend
MsgBox "Внешний IP сменился на " & IP, 4160
Quit
 
Sub Send(ms, command)
   WSH.Sleep ms: oWSH.AppActivate PID
   WSH.Sleep 20: oWSH.SendKeys command
End Sub
 
Sub Quit
   If PID Then oWMI.Get("Win32_Process.Handle=" & PID).Terminate
   Set oHTTP = Nothing: Set oWSH = Nothing: Set oWMI = Nothing: WSH.Quit
End Sub