Удаление пустых папок

@Spartak1211 · Регистрация: 13.07.2023

Студворк — интернет-сервис помощи студентам

Доброго времени суток подскажите пожалуйста скрипт для удаление пустых папок и проверку их на то что они пустые! допустим создаются папки с файлами и без, нужен скрипт который проверит что папка пуста и через 2.5 месяца ее удалит. как то так! заранее спасибо!

FlasherX · 02.11.2023, 14:58

А поискать? Прямо на первой странице тема "Скрипт удаления пустых папок".
Подправить под 2.5 месяца не проблема.

@Spartak1211 · 02.11.2023, 15:06 **[ТС]**

Спасибо

@Spartak1211 · 14.11.2023, 08:33 **[ТС]**

Спасибо еще раз за скрин.Не пригодился, т.к. я его не смог прочитать даже изменить не смог что бы 2.5 месяца). Мне надо научиться этому если не затруднит ответить с чего начать. на работе попросили учить язык для писанины скриптов, я выбрал VBS.Предлогалось много но выбрал этот пока!спасибо заранее

@Angry Old Man · 14.11.2023, 15:16

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
RootFolder = "D:\CMD_Forum\Box_In"  'Стартовая папка для выбора обрабатываемой подпапки
DayOld = 76                         'Пустая папка удаляется если не изменялась количество дней
 
With CreateObject("Shell.Application")
    Set SeleFolder = .BrowseForFolder(0, "Выбирайте папку для поиска пустых подпапок", 1, RootFolder)
    If SeleFolder Is Nothing Then
        MsgBox "Folder not selected", 16
        WScript.Quit
    Else
        BoxIn = SeleFolder.Self.Path
    End If
End With
 
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Dict = CreateObject("Scripting.Dictionary")
 
N = 0
AllFoldersDir FSO, Dict, BoxIn, N, CLng(Now) - DayOld
 
For i = N To 2 Step -1
    Set F = FSO.GetFolder(Dict.Item(i))
    With FSO.GetFolder(Dict.Item(i))
        If .SubFolders.Count + .Files.Count = 0 Then FSO.DeleteFolder Dict.Item(i), True
    End With
Next
 
Sub AllFoldersDir(FSO, Dict, inDir, N, M)   ' ---------------------------------------------
    Set F = FSO.GetFolder(inDir)
    If N <> 0 Then
        If CLng(F.DateLastModified) < M Then
            N = N + 1
            Dict.Add N, F.Path
        End If
    Else
        N = 1
    End If
    
    Set SubF = F.SubFolders
    For Each Folder In SubF
        AllFoldersDir FSO, Dict, inDir + "\" + Folder.Name, N, M
    Next
End Sub

FlasherX · 14.11.2023, 16:37

Я не давал никаких скринов. Начать с азов.
Через 2.5 месяца после запуска скрипта или создания каталога? Если последнее, то правка такая:

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit: Dim oFSO, oCol, D
Const Dir = "C:\Folder", Days = 75
'—————————————————————————————————
Const Title = " Удаление пустых подпапок     "
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oCol = CreateObject("System.Collections.ArrayList")
If Not oFSO.FolderExists("\\?\" & Dir) Then _
MsgBox "Укажите путь к существующему каталогу!", 262192, Title: WSH.Quit
On Error Resume Next
Recursion oFSO.GetFolder("\\?\" & Dir)
oCol.Sort: oCol.Reverse
For Each D in oCol
   Set D = oFSO.GetFolder(D)
   If Now - D.DateCreated > Days Then _
   If D.SubFolders.Count + D.Files.Count = 0 Then D.Delete 1
Next
Set oFSO = Nothing: Set oCol = Nothing
CreateObject("WScript.Shell").Popup "  Выполнено!", 1.7, Title, 4160
 
Sub Recursion(oDir)
   For Each D in oDir.SubFolders
      If D.SubFolders.Count Then
         oCol.Add D.Path
         Recursion D
      ElseIf Now - D.DateCreated > Days Then If D.Files.Count = 0 Then D.Delete 1
      End If
   Next
End Sub

Отработает быстрее и без спотыкачей на длинных путях (260+) и с игнором занятых.

@Angry Old Man · 14.11.2023, 17:54

FlasherX, имхо, возможно надо не DateCreated а DateLastModified. Папка может быть создана очень давно, а стала пустой недавно. Но при этом Ваш алгоритм не отработает, например, на такой структуре пустых вложенных папок
MD "Z:\Box_In\Папка1\Папка2\Папка3\Папка4\П апка5"
Будет удалена только последняя папка.

FlasherX · 14.11.2023, 23:08

Сообщение от Angry Old Man

имхо, возможно надо не DateCreated а DateLastModified

>>>

Сообщение от Spartak1211

И чтоб удалялось по дате создания!

Сообщение от Angry Old Man

Папка может быть создана очень давно, а стала пустой недавно.

И что? Нельзя на 100% отследить только по дате модификации, когда папка в последний раз очищалась.

Сообщение от Angry Old Man

Но при этом Ваш алгоритм не отработает, например, на такой структуре пустых вложенных папок

Указал C:\Box_In в шапке, cоздал остальную цепочку подпапок, заменил год даты создания в них, и скрипт прекрасно очистил указанную папку.

1. Ваш алгоритм не отработает на 260+ путях. BrowseForFolder этого точно не даст.
2.

Visual Basic
31
32
            N = N + 1
            Dict.Add N, F.Path

Тут проще без счётчика. Можно спокойно сохранять пути в ключах Dict.Add F.Path, Empty, в 19 строке написать Arr = Dict.Keys, а с 20 строки писать For i = Dict.Count To 2 Step -1, заменив Dict.Item(i) на Arr(i).
Кстати, я ещё давно пробовал обратный цикл, но у меня на некоторых структурах были проблемы с удалением таким способом.
3.

Visual Basic
39
40
41
    For Each Folder In SubF
        AllFoldersDir FSO, Dict, inDir + "\" + Folder.Name, N, M
    Next

Зачем в цикле крутить такие сущности, как FSO, Dict, N и M? Пустая трата времени.
А вот не использовать его для удаления несколько странно, ведь это увеличивает число итераций для последнего.
И Folder.Path всяко проще чем inDir + "\" + Folder.Name, не так ли?

Впрочем, и тут объект папки лучше для передачи в процедуру, чем полный путь, дабы в 21-22 строках не дёргать метод GetFolder по два раза за итерацию.
4. В 18 и 31 строках не нужен CLng, потому что вычитание дат и так возвращает число дней в double, что при сравнении с integer даёт нужный результат.
5. Возьмите за правило при рекурсиях и больших циклах использовать Option Explicit, что в разы ускоряет доступ к объявленным переменным и созданным объектам.

@Spartak1211 · 15.11.2023, 08:44 **[ТС]**

Set fso = CreateObject("Scripting.FileSystemObject ")
startFolder = "C:\111"

DeleteEmptyDir startFolder

Function DeleteEmptyDir(folderName)
Dim folder, folderCollection, subFolder
Set folder = fso.GetFolder(folderName)
Set folderCollection = folder.SubFolders
For Each subFolder In folderCollection
DeleteEmptyDir subFolder.Path
If subFolder.Size = 0 _
And DateDiff("D", Folder.DateCreated, Now()) < 30 Then
subFolder.Delete true
End If
Next
End Function

А почему вот этот не работает, что делаю не так. Выразился я неправильно изначально мне нужно удалять пустые подпапки старше даты создания 2.5 месяца

Добавлено через 1 минуту
FlasherX, вы не давали скринов но дали ссылку куда смотреть то что на первой странице есть тема где и находится скрипт!

Добавлено через 42 минуты
Изначально не правильно написал.Есть папка в нее создаются папки с файлами.некоторые пустые. скринт будет работать через Effector saver(он его будет запускать) нужно просто чтоб скрипт удалял пустые подпапки старше н времени от даты создания! привел выше скрипт он удаляет почему то пустые подпапки а на возраст не смотрит.

FlasherX · 15.11.2023, 09:48

Spartak1211, не работает, потому что сделан с ошибками. Он удаляет не пустые подпапки, а подпапки нулевого размера, что совсем не одно и то же. К тому же прямой перебор не будет работать при рекурсии, пытаясь удалять папку, которая ещё не очищена. Если кто-то где-то предлагает код понравившегося размера, это ещё не значит, что он отработает быстрее или вообще рабочий. А рабочий приведён выше. Вот и пользуйтесь.

@Spartak1211 · 15.11.2023, 10:04 **[ТС]**

Спасибо большое. но я его сейчас попробовал выставив значение папки 10 дней пустые папки не удалило. может я что то не так сделал

Добавлено через 1 минуту
я в этом честно говоря вообще ничего не понимаю только только начал изучать. а хотелось бы понять. я же его могу редактировать ваш скрипт чтобы не вылезало сообщение?

Добавлено через 10 минут
FlasherX, Скажите пожалуйста он удаляет как по дате создания так по дате изменения или это разницы не какой не имеет.

FlasherX · 15.11.2023, 10:18

Spartak1211, чтобы понять, надо изучать язык, читать справочники, литературу.
Разница дат всегда есть, выше это обсуждалось. Вы запросили ориентир на дату создания, вот я это и реализовал. Дата модификации у папки может меняться по ходу внутренних изменений в её корне. Удалять сразу по обеим датам не имеет смысла, у них разное целеполагание.
Чтобы не вылезало двухсекундное сообщение, достаточно удалить 18 строку.

@Spartak1211 · 15.11.2023, 12:02 **[ТС]**

Спасибо еще раз. очень помог. Всем спасибо.

Добавлено через 59 минут
А можно вообще еще 2 путя добавить, чтоб с трех папок удаляло подпапки?

Добавлено через 8 минут
FlasherX, Подскажите какую литературу почитать или в теме "Подскажите литературу для начинающего" все есть.где это все брать или есть это все в интернете? и сколько понадобится времени примерно чтоб писать такие скрипты?

@Angry Old Man · 15.11.2023, 16:52

Несколько папок

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
Public FSO, Dict, N, M
 
Const DayOld = 76           'Пустая папка удаляется если не изменялась(создана ранее?) количество дней
Dim AllBoxIn: AllBoxIn = Array("D:\CMD_Forum\Box_In", "D:\CMD_Forum\Soft_In", "Z:\Почта 1", "Z:\Почта 2")
 
Dim BoxIn, i
M = Now - DayOld
Set FSO = CreateObject("Scripting.FileSystemObject")
 
For Each BoxIn In AllBoxIn
    If FSO.FolderExists(BoxIn) Then
        Set Dict = CreateObject("Scripting.Dictionary")
        N = 0
        AllFoldersPub BoxIn
        For i = N To 2 Step -1
            With FSO.GetFolder(Dict.Item(i))
                If .SubFolders.Count + .Files.Count = 0 Then FSO.DeleteFolder Dict.Item(i), True
            End With
        Next
    Else
        MsgBox BoxIn + vbCr + vbCr + "not found", 16, "Folder not found"
    End If
Next
 
Sub AllFoldersPub(inDir)   ' ---------------------------------------------
    Dim F: Set F = FSO.GetFolder(inDir)
    If N <> 0 Then
        If F.DateCreated < M Then   'Если надо анализировать дату создания
        'If F.DateLastModified < M Then 'Если надо анализировать дату изменения
            N = N + 1
            Dict.Add N, F.Path
        End If
    Else
        N = 1
    End If
    
    Dim Folder, SubF: Set SubF = F.SubFolders
    For Each Folder In SubF
        AllFoldersPub Folder.Path
    Next
End Sub

volodin661 · 15.11.2023, 19:47

Сообщение от Spartak1211

Мне надо научиться этому , если не затруднит ответить с чего начать. на работе попросили учить язык для писанины скриптов, я выбрал VBS.Предлоагалось много , но выбрал этот пока!

Инструмент VBScript появился в недрах Windows в конце 20-го века ( 1996 г ),
прекратил своё развитие в начале 21-го века ( 2010 примерно; здесь могу ошибаться ),
а официально об'ьявлен устаревшим и подлежащим выпиливанию из последующих версий Windows совсем недавно, в окт. 2023.
https://learn.microsoft.com/en-us/windows/whats-new/deprecated-features

Знаменит тем, что долгое время ( лет 12 ) являлся единственным вменяемым средством автоматизации, всегда имевшимся на борту у разных версий данной ОС. ( Win98, XP, 2000, 7,8,10,11 )

Ни в каких других опер. средах ( DOS, OS/2, Unix/Linux/MacOS etc ) VBScript не был реализован.

Стоит ли тратить время на его изучение ?
- Скорее всего, да, он достаточно прост и популярен в старых версиях Windows.

Какие альтернативы ?
- Powershell, Python ( оба кросс-платформ, последний просто мегапопулярен, но первый исторически ориентирован на Windows и является рекомендуемым M$ современным средством автоматизации, потому что реализован не просто как скрипт. язык, а как shell - командная оболочка )

Добавлено через 53 минуты
пока я тут разговаривал сам с собой, оказалось, что прошлой ночью релизнулся dotnet 8 ( .NET 8 ).
и это означает, что через недельку выйдет новая версия powershell, которая едет, как верхом на лошадке,
на технологии .NET и проезжает, не оглядываясь на COM-ограду, за которой уже больше 20 лет стоит маленький оловянный бюстик vbscript.

и это я к тому, на какой скрипт.инструмент быстрой разработки стоит обратить внимание. нмв.

FlasherX · 15.11.2023, 22:04

Сообщение от Spartak1211

А можно вообще еще 2 путя добавить, чтоб с трех папок удаляло подпапки?

2 путя ... с 3 папок? Это как?

Через | перечисляем:

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit: Dim oFSO, oCol, D
Const Days = 75, Dirs = "C:\Folder1|D:\Folder2|E:\Folder3"
'—————————————————————————————————————————————————————————
Const Title = " Удаление пустых подпапок     "
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oCol = CreateObject("System.Collections.ArrayList")
On Error Resume Next
For Each D in Split(Dirs, "|")
   If oFSO.FolderExists("\\?\" & D) Then _
   Recursion oFSO.GetFolder("\\?\" & D)
Next
oCol.Sort: oCol.Reverse
For Each D in oCol
   Set D = oFSO.GetFolder(D)
   If Now - D.DateCreated > Days Then _
   If D.SubFolders.Count + D.Files.Count = 0 Then D.Delete 1
Next
Set oFSO = Nothing: Set oCol = Nothing
 
Sub Recursion(oDir)
   For Each D in oDir.SubFolders
      If D.SubFolders.Count Then
         oCol.Add D.Path
         Recursion D
      ElseIf Now - D.DateCreated > Days Then If D.Files.Count = 0 Then D.Delete 1
      End If
   Next
End Sub

Сообщение от Spartak1211

где это все брать или есть это все в интернете?

Начните с этих ссылок. И ещё я бы советовал осваивать параллельно AutoIt (похожий синтаксис) или AHK. Обновляются, удобны в переноске, можно спокойно использовать без инклюдов и других свистоплясок, как у всяких питонов/пёрлов и подобных им, достаточно популярны в русскоязычном форумном сегменте.

и подлежащим выпиливанию из последующих версий Windows

Добрались-таки до святого грязные мелкомягкие ручонки.

VBScript будет доступен как функция по запросу, прежде чем будет удален в будущих выпусках Windows. Первоначально функция VBScript on demand будет предустановлена для обеспечения бесперебойного использования, пока вы готовитесь к выходу VBScript из эксплуатации.

Столько бестолкового выпила просто отвернёт пользователей от перехода на новые версии.
Хочу обратить внимание, что в списке не затронуты JScript и mshta, что по сути одного поля ягоды, особенно учитывая, что JScript вообще имеет общие интерпретаторы с VBscript. Логика такой своеобразной выборки непонятна...

@Spartak1211 · 16.11.2023, 08:11 **[ТС]**

Спасибо за информацию. Буду учиться.

@Spartak1211 · 07.05.2024, 20:11 **[ТС]**

Здравствуйте, по вашему скрипту добавил пути, когда запускаю до не удаляет папки по дате изменения может из-а того то что пути по русски?

Visual Basic
1
Dirs = "D:\Яндекс.Диск\Жешарт\Документ\Взвешивание|D:\Яндекс.Диск\Жешарт\Документ\ПриемоСдаточныйАкт|D:\Яндекс.Диск\Жешарт\Документ\ПриемоСдаточныйАктЦветМет"

Полный код

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit: Dim oFSO, oCol, D
Const Days = 70, Dirs = "D:\Яндекс.Диск\Жешарт\Документ\Взвешивание|D:\Яндекс.Диск\Жешарт\Документ\ПриемоСдаточныйАкт|D:\Яндекс.Диск\Жешарт\Документ\ПриемоСдаточныйАктЦветМет"
'—————————————————————————————————————————————————————————
Const Title = " Удаление пустых подпапок     "
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oCol = CreateObject("System.Collections.ArrayList")
On Error Resume Next
For Each D in Split(Dirs, "|")
   If oFSO.FolderExists("\\?" & D) Then _
   Recursion oFSO.GetFolder("\\?" & D)
Next
oCol.Sort: oCol.Reverse
For Each D in oCol
   Set D = oFSO.GetFolder(D)
   If Now - D.DateCreated > Days Then _
   If D.SubFolders.Count + D.Files.Count = 0 Then D.Delete 1
Next
Set oFSO = Nothing: Set oCol = Nothing
 
Sub Recursion(oDir)
   For Each D in oDir.SubFolders
      If D.SubFolders.Count Then
         oCol.Add D.Path
         Recursion D
      ElseIf Now - D.DateCreated > Days Then If D.Files.Count = 0 Then D.Delete 1
      End If
   Next
End Sub

FlasherX · 07.05.2024, 20:27

Не надо оверквотить кодом. Достаточно переменной Dirs.
Код должен быть в ANSI.

@Spartak1211 · 07.05.2024, 20:58 **[ТС]**

Код и есть в ansi?

Новые блоги и статьи Все статьи Все блоги /
Access VikBal 11.12.2025 Помогите пожалуйста !! Как объединить 2 одинаковые БД Access с разными данными.	Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .	Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .
Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .	Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .	Фото: Daniel Greenwood kumehtar 13.11.2025

Удаление пустых папок

Решение

Решение

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36

	Удаление пустых папок 02.11.2023, 14:45. Показов 3736. Ответов 40 Метки нет (Все метки) Доброго времени суток подскажите пожалуйста скрипт для удаление пустых папок и проверку их на то что они пустые! допустим создаются папки с файлами и без, нужен скрипт который проверит что папка пуста и через 2.5 месяца ее удалит. как то так! заранее спасибо! 0

FlasherX 6962 / 2857 / 1099 Регистрация: 06.06.2017 Сообщений: 9,694
	02.11.2023, 14:58
	А поискать? Прямо на первой странице тема "Скрипт удаления пустых папок". Подправить под 2.5 месяца не проблема. 1

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	02.11.2023, 15:06 [ТС]
	Спасибо 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	14.11.2023, 08:33 [ТС]
	Спасибо еще раз за скрин.Не пригодился, т.к. я его не смог прочитать даже изменить не смог что бы 2.5 месяца). Мне надо научиться этому если не затруднит ответить с чего начать. на работе попросили учить язык для писанины скриптов, я выбрал VBS.Предлогалось много но выбрал этот пока!спасибо заранее 0

@Angry Old Man 2995 / 738 / 310 Регистрация: 26.03.2022 Сообщений: 1,379 Записей в блоге: 1
	14.11.2023, 17:54
	FlasherX, имхо, возможно надо не DateCreated а DateLastModified. Папка может быть создана очень давно, а стала пустой недавно. Но при этом Ваш алгоритм не отработает, например, на такой структуре пустых вложенных папок MD "Z:\Box_In\Папка1\Папка2\Папка3\Папка4\П апка5" Будет удалена только последняя папка. 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	15.11.2023, 08:44 [ТС]
	Set fso = CreateObject("Scripting.FileSystemObject ") startFolder = "C:\111" DeleteEmptyDir startFolder Function DeleteEmptyDir(folderName) Dim folder, folderCollection, subFolder Set folder = fso.GetFolder(folderName) Set folderCollection = folder.SubFolders For Each subFolder In folderCollection DeleteEmptyDir subFolder.Path If subFolder.Size = 0 _ And DateDiff("D", Folder.DateCreated, Now()) < 30 Then subFolder.Delete true End If Next End Function А почему вот этот не работает, что делаю не так. Выразился я неправильно изначально мне нужно удалять пустые подпапки старше даты создания 2.5 месяца Добавлено через 1 минуту FlasherX, вы не давали скринов но дали ссылку куда смотреть то что на первой странице есть тема где и находится скрипт! Добавлено через 42 минуты Изначально не правильно написал.Есть папка в нее создаются папки с файлами.некоторые пустые. скринт будет работать через Effector saver(он его будет запускать) нужно просто чтоб скрипт удалял пустые подпапки старше н времени от даты создания! привел выше скрипт он удаляет почему то пустые подпапки а на возраст не смотрит. 0

FlasherX 6962 / 2857 / 1099 Регистрация: 06.06.2017 Сообщений: 9,694
	15.11.2023, 09:48
	Spartak1211, не работает, потому что сделан с ошибками. Он удаляет не пустые подпапки, а подпапки нулевого размера, что совсем не одно и то же. К тому же прямой перебор не будет работать при рекурсии, пытаясь удалять папку, которая ещё не очищена. Если кто-то где-то предлагает код понравившегося размера, это ещё не значит, что он отработает быстрее или вообще рабочий. А рабочий приведён выше. Вот и пользуйтесь. 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	15.11.2023, 10:04 [ТС]
	Спасибо большое. но я его сейчас попробовал выставив значение папки 10 дней пустые папки не удалило. может я что то не так сделал Добавлено через 1 минуту я в этом честно говоря вообще ничего не понимаю только только начал изучать. а хотелось бы понять. я же его могу редактировать ваш скрипт чтобы не вылезало сообщение? Добавлено через 10 минут FlasherX, Скажите пожалуйста он удаляет как по дате создания так по дате изменения или это разницы не какой не имеет. 0

FlasherX 6962 / 2857 / 1099 Регистрация: 06.06.2017 Сообщений: 9,694
	15.11.2023, 10:18
	Spartak1211, чтобы понять, надо изучать язык, читать справочники, литературу. Разница дат всегда есть, выше это обсуждалось. Вы запросили ориентир на дату создания, вот я это и реализовал. Дата модификации у папки может меняться по ходу внутренних изменений в её корне. Удалять сразу по обеим датам не имеет смысла, у них разное целеполагание. Чтобы не вылезало двухсекундное сообщение, достаточно удалить 18 строку. 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	15.11.2023, 12:02 [ТС]
	Спасибо еще раз. очень помог. Всем спасибо. Добавлено через 59 минут А можно вообще еще 2 путя добавить, чтоб с трех папок удаляло подпапки? Добавлено через 8 минут FlasherX, Подскажите какую литературу почитать или в теме "Подскажите литературу для начинающего" все есть.где это все брать или есть это все в интернете? и сколько понадобится времени примерно чтоб писать такие скрипты? 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	16.11.2023, 08:11 [ТС]
	Спасибо за информацию. Буду учиться. 0

FlasherX 6962 / 2857 / 1099 Регистрация: 06.06.2017 Сообщений: 9,694
	07.05.2024, 20:27
	Не надо оверквотить кодом. Достаточно переменной Dirs. Код должен быть в ANSI. 0

@Spartak1211 0 / 0 / 0 Регистрация: 13.07.2023 Сообщений: 36
	07.05.2024, 20:58 [ТС]
	Код и есть в ansi? 0