Как узнать принадлежит ли компьютер к домену по IP?

Dim objRoot, objComputer, strDomain, strComputer, strTemp
strComputer = "192.168.1.10"
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = Replace(Replace(objRoot.Get("defaultNamingContext"), "dc=", "", 1, -1, vbTextCompare), ",", ".", 1, -1, vbTextCompare)
Set objRoot = Nothing
If Available(strComputer) Then
    On Error Resume Next
    Set objComputer = GetObject("WinNT://" & strComputer & ",computer")
    If Err.Number = 0 Then
        strTemp = objComputer.ADsPath
        If Err.Number = 0 Then
            If IsNull(strTemp) Then
                WScript.Echo strComputer & " -> идентификация членства в домене не выполнена"
            Else
                If InStr(1, strTemp, "/" & strDomain & "/", vbTextCompare) > 0 Then
                    WScript.Echo strComputer & " -> входит в домен"
                Else
                    WScript.Echo strComputer & " -> не входит в домен"
                End If
            End If
        Else
            WScript.Echo strComputer & " -> ошибка при чтении значения свойства " & Err.Number & vbNewLine & Err.Description
        End If
    Else
        WScript.Echo strComputer & " -> ошибка при попытке подключения " & Err.Number & vbNewLine & Err.Description
        Err.Clear
    End If
    Set objComputer = Nothing
Else
    WScript.Echo strComputer & " -> не отвечает или не существует"
End If
WScript.Quit 0
 
'======
 
Function Available(strName)
Dim objExec, objOutStream, strTemp
 
Set objExec = CreateObject("WScript.Shell").Exec("ping -n 1 -w 130 " & strName)
Set objOutStream = objExec.StdOut
While Not objOutStream.AtEndOfStream
    strTemp = strTemp & Trim(objOutStream.ReadLine)
Wend
Set objOutStream = Nothing
Set objExec = Nothing
If InStr(1, strTemp, "TTL", vbTextCompare) > 0 Then
    Available = True
Else
    Available = False
End If
End Function