Как записать в Label из другого класса

//модель; количество подходов, интервал перерыва
type Exercise = {Count:int; Interval:int}
                with static member GetDefault = {Count = 3; Interval = 120}
 
type MainViewModel() as self = 
    inherit ViewModelBase()    
 
    let second = 1000.0 
    let mutable exercise = Exercise.GetDefault 
 
    //наблюдаемые переменные 
    let enabled = self.Factory.Backing(<@ self.Enabled @>, true)
    let buttonEnabled = self.Factory.Backing(<@ self.ButtonEnabled @>, true)
    let time = self.Factory.Backing(<@ self.Time @>, exercise.Interval)
 
    //функция обновления, вызывается каждую секундку
    let update (timer:System.Timers.Timer) x = 
        if x >= 0 then time.Value <- x //если еще не дошли до 0, уменьшаем значение
        else //в противном случае
           timer.Stop() //останавливаем таймер
           time.Value <- exercise.Interval //возвращаем исходный интервал
           buttonEnabled.Value <- true //разрешаем запустить таймер снова 
           exercise <- {exercise with Count = exercise.Count - 1} // уменьшаем количество оставшихся подходов
           self.RaisePropertyChanged(<@ self.Count @>) //обновляем отображение
           if exercise.Count = 0 then enabled.Value <- true 
        self.RaisePropertyChanged(<@ self.Time @>)
 
    let start _ = 
        buttonEnabled.Value <- false //блокируем кнопку
        //если текстовые поля еще не заблокированы, блокируем их
        if enabled.Value = true then enabled.Value <- false
        //создаем таймер
        let timer = new System.Timers.Timer(second)
        (exercise.Interval, timer.Elapsed)    
        ||> Observable.scan(fun x _ -> x - 1)     //"сканируем" событие, уменьшая на единицу старторове значение
        |> Observable.subscribe(update timer) //вызываем функцию при каждом наблюдении
        |> ignore //игнорируем результат
        async { timer.Start() }
 
        
    let startCommand = self.Factory.CommandAsync(start)
 
    //свойства для связи с View
    //комманда, выполняема при нажатии на кнопку
    member self.StartCommand = startCommand
    
    member self.Count with get() = exercise.Count
                      and set v  = exercise <- {exercise with Count = v}
 
    member self.Interval with get() = exercise.Interval 
                         and set v  = exercise <- {exercise with Interval = v}
                                      time.Value <- v
                                      self.RaisePropertyChanged(<@ self.Time @>)    
 
    member self.Time with get() = time.Value 
    member self.Enabled with get() = enabled.Value
    member self.ButtonEnabled with get() = buttonEnabled.Value