Полезные BAT/CMD скрипты

@echo off
  setlocal enabledelayedexpansion
    for %%i in (lodctr.exe) do (
      if not exist "%%~$PATH:i" (
        echo:Could not retrieve system up time.
        goto:eof
      )
    )
    set "pc=%tmp%\perf.tmp" % rem : performance counters list
    lodctr /s:%pc%
    call:findlocalestr 2   object
    call:findlocalestr 674 counter
    for /f delims^=^"^ tokens^=3 %%i in (
      'typeperf "%object%%counter%" -sc 1 ^| findstr /rc:":"'
    ) do 2>nul set /a "s=%%i" % rem : total seconds
    set /a "ss=s%%60", "s/=60", "mm=s%%60", "s/=60", "hh=s%%24", "dd=s/24"
    for %%i in (%hh% %mm% %ss%) do (
      if %%i lss 10 (set "t=!t!0%%i:") else (set "t=!t!%%i:")
    )
    echo:%dd%.%t:~,-1%
    del /f /q "%pc%"
  endlocal
exit /b
 
:findlocalestr
for /f "tokens=2 delims==" %%i in (
  'find "%~1=" "%pc%" ^| findstr /brc:"%~1="'
) do set "%2=\%%i"
exit /b

@echo off
rem v2.1
 
rem путь к файлу конфигурации VirtualBox
set "Vbox=%userprofile%\.VirtualBox\VirtualBox.xml"
 
rem путь к файлу vboxmanage.exe должен быть прописан в системной переменной Path,
rem либо для корректного запуска необходимо указать абсолютный путь:
set "vbman=vboxmanage.exe"
 
rem -----
rem Инициализация переменных, для поддерживаемых расширений. Число расширений
rem можно увеличить добавлением переменных extN, по аналогии с существующими.
rem Кроме того, необходимо указать их количество в переменной n
set "ext1=*.vdi"
set "ext2=*.vhd"
set "ext3="
set n=2
rem -----
 
for /l %%g in (1,1,%n%) do (
    if defined ext%%g (call :dper %%g)
)
for /l %%h in (1,1,%n%) do (
    if defined ext%%h (call :fper %%h)
)
goto pp
:dper
set vn=%1
call set "dext=%%dext%% "%%ext%vn%%%""
exit /b
:fper
set nv=%1
call set "fext=%%fext%% /c:"%%ext%nv%:~1%%""
exit /b
:pp
echo Сценарий упаковки файла динамического виртуального диска Oracle VirtualBox.
echo Перед упаковкой, необходимо в загруженной гостевой ОС выполнить максимальную
echo дефрагментацию, затем заполнить нулями свободное пространство ^(для этого
echo хорошо подходит программа sDelete ^(sysinternals.com^)^).
echo Примечание: Имя упаковываемого, неподключенного файла виртуального диска НЕ
echo должно совпадать с любым подключенным файлом, либо абсолютный путь в сценарии
echo должен быть указан только от реально подключенного виртуального диска.
echo.
choice /c yn /m "Продолжаем "
if "%errorlevel%"=="1" goto begin
echo.
echo Выходим
echo.
pause&&exit
:begin
choice /n /c 12 /m "Выберите 1 - для работы с подключенными дисками, 2 - для указания абсолютного пути: "
goto disk%errorlevel%
:disk1
set "vm=%Vbox%"
goto run
:disk2
set "vm="
:run
cls
echo Выполните следующие действия:
echo.
pushd "%~dp0"
if not exist "%vm%" goto out
echo Список имен подключенных машин:
set cnt=0 
for /f tokens^=2^ delims^=^" %%i in ('^<"%vm%" find "MachineEntry"') do call :list "%%~i"
echo.
goto out
:list
if "%~1"=="" (echo Нет подключенных машин&&goto out)
set /a cnt+=1
set "vbu%cnt%=%~1"
call set "tmp=%%vbu%cnt%%%"
for /f "tokens=2 delims=: " %%j in ('%vbman% showvminfo %tmp%') do echo %cnt%. %%j&&goto ex
:ex 
exit /b
:vbox
set ct=0
set "v=%~1"
%vbman% showvminfo %v% |findstr /i %fext% >nul
if errorlevel 1 (echo Диски не найдены&&exit /b 1)
for /f "tokens=3,4 delims=)(" %%a in ('%vbman% showvminfo %v% ^|findstr /i %fext%') do (
    call :hd "%%~a" "%%~b"
)
exit /b
:hd
set "$1=%~1"
set "$2=%~2"
set /a ct+=1
set hd%ct%=%$2:~6%
echo %ct% %~nx1
exit /b
:out
if exist "%vm%" (
    echo Выберите номер подключенной VM
    set /p x="(q=выход): "
) else (
    echo Укажите абсолютный путь к каталогу с виртуальным диском 
    set /p x="(q=выход): "
    goto q2
)
:q1
if "%x%"=="" goto begin
if "%x%"=="q" (goto chce)
if defined vbu%x% (
    echo.
    echo Список дисков в выбранной виртуальной машине:
    echo.
    call :vbox "%%vbu%x%%%" ||goto chce
) else (
    goto begin
)
goto file
:q2
if "%x%"=="" goto begin
if "%x%"=="q" (goto chce)
set kon=0
for /l %%k in (1,1,%n%) do (
    if defined ext%%k call :tm %%k
)
goto tt
:tm
set dn=%1
call set prn=%%ext%dn%%%
if exist "%x%\%prn%" set /a kon+=1
exit /b
:tt
if %kon%==0 (echo.&&echo В этом каталоге нет файлов виртуальных дисков&&echo.&&goto chce)
:cont
cd /d "%x%"
echo.
echo Список файлов виртуального диска:
echo.
set cnt=0
for /f "delims=" %%a in ('dir /a-d/b %dext%') do (
    call :per "%%~a"
)
goto file
:per
set /a cnt+=1
set var%cnt%=%~1
call echo %cnt%. %%var%cnt%%%
exit /b
:file
echo.
set /p y="Введите номер виртуального диска: "
if defined hd%y% (call set "dsk=%%hd%y%%%"&&goto pusk)
call set "dsk=%%var%y%%%"
if not defined dsk (echo.&&echo Нет такого диска&&goto chce) else (goto pusk)
pause&&exit
:chce
choice /c yn /m "Выходим "
goto answ%errorlevel%
echo Ошибка. Выходим
pause&&exit
:answ1
echo Выход
timeout /t 3
exit
:answ2
goto begin
:pusk
echo.
echo Запускаем упаковку:
echo.
%vbman% modifyhd "%dsk%" --compact
if errorlevel 1 (
    echo.
    echo. ╔═══════════════════════════════════════════════════════════╗
    echo. ║ Ошибка!!! Имя файла виртуального диска совпадает с именем ║
    echo. ║ подключенного файла, при отличающихся абсолютных путях    ║
    echo. ╚═══════════════════════════════════════════════════════════╝
    echo.
)
echo.
goto chce
:answ255
:disk255
echo Ошибка&&pause&&exit

@echo off
SetLocal EnableExtensions
 
set "mp3=c:\windows\media\tada.wav"
 
:: кол-во секунд воспроизведения
set delay=2
 
call :PlaySnd "%mp3%" %delay%
 
pause
goto :eof
 
:PlaySnd [Path] [Delay]
  set "SndPath=%~1" & set /a "delay2=%2+1"
  set "pause=new ActiveXObject('WScript.Shell').Run('ping -n $ localhost', 0, true)"
  set "script=<script>document.all.sound.src = '%SndPath:\=\\%'</script>"
  set "script2=<script>%%pause:$=%delay2%%%; close()</script>"
  call start /min /wait mshta "about:<bgsound id=sound>%script%%script2%"
exit /B

@echo off
  setlocal enabledelayedexpansion
    set "hklm=HKLM"
    set "hkcu=HKCU"
    set "key=\Software\Microsoft\Windows\CurrentVersion"
    set "key=%key%\Explorer\Shell Folders"
    
    set "i=0"
    call:getnames %hklm% %i%
    call:getnames %hkcu% %i%
    
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if !i! neq 1 goto:man
    
    set "i=0"
    for /f "tokens=1,* delims==" %%i in (
      'set arr ^| findstr /irc:"=%~1"'
    ) do (
      set "map=!map!%%~j..."
      set /a "i+=1"
    )
    set "map=!map:~,-3!"
    if /i "!map!" equ "~,-3" goto:man
    if !i! neq 1 echo !map!&goto:eof
    rundll32 shell32.dll,ShellExec_RunDLL "shell:!map:.=!"
  endlocal
exit /b
 
:getnames
  set "i=%2"
  for /f "tokens=1,2" %%i in (
    'reg query "%1!key!" ^| findstr /irc:"reg_sz"'
  ) do (
    if /i "%%j" equ "reg_sz" (
      set "arr.!i!=%%i"
    ) else (
      set "arr.!i!=%%i %%j"
    )
    set /a "i+=1"
  )
exit /b
 
:man
  set "map=" % rem : flush wrong pattern
  for %%i in (
    "Usage: %~n0 [path name]"
    ""
    "Example 1:"
    "   C:\> %~n0 d"
    "This command opens Desktop folder."
    ""
    "Example 2:"
    "   C:\> %~n0 ``common p''"
    "Jumps to Common Programs folder."
    ""
    "The next paths are available on this system:"
  ) do echo:%%~i
  for /f "tokens=1,* delims==" %%i in ('set arr') do (
    set "map=!map!%%j..."
  )
  echo !map:~,-3!
exit /b

@echo off
  for %%i in (certutil.exe) do (
    if not exist "%%~$PATH:i" goto:err
  )
  setlocal enabledelayedexpansion
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if !i! equ 1 (
      call:sum "%~1"
      goto:eof
    )
    if !i! equ 2 (
      call:sum "%~1" "%~2"
      goto:eof
    )
    goto:man
  endlocal
exit /b
 
:err
  echo:Certutil has not been found.
exit /b
 
:man
  for %%i in (
    "Usage: %~n0 file [algorithm]"
    ""
    "Default algorithm is sha256."
    "Supported algorithms are md2, md4, md5,"
    "sha1, sha256, sha384 and sha512."
    ""
    "Note: this one was written and tested"
    "on Windows 7."
  ) do echo:%%~i
exit /b
 
:sum
  if not exist "%~1" goto:man
  if "%~2" equ "" (
    set "alg=SHA256"
  ) else (
    for /f "tokens=2 delims=:" %%i in (
      '2^>^&1 find "" %~2'
    ) do set "alg=%%i"
  )
  set "alg=!alg: =!"
  for /f "skip=1 delims=" %%i in (
    'certutil -hashfile "%~1" !alg!^
    ^| findstr /virc:"certutil"'
  ) do set "hash=%%i"
  if /i "!hash!" equ "" (
    echo:=^>err
  ) else (echo !hash: =!)
exit /b

@echo off
  for /f "tokens=2 delims=][." %%i in ('ver') do (
    for /f "tokens=2" %%j in ("%%i") do (
      if %%j lss 6 (
        echo:This requires Vista or above.
        goto:eof
      )
    )
  )
  setlocal enabledelayedexpansion
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if !i! neq 1 goto:man
    
    set "arg=%~1"
    if "!arg:~0,1!" neq "-" if "!arg:~0,1!" neq "/" goto:man
    if /i "!arg:~1!" equ "mount" (
      call:secureinput "User"
      echo.
      call:secureinput "Pass"
      echo.
      net use * https://webdav.yandex.ru !pass!^
      /user:!user!@yandex.ru /persistent:yes
      goto:eof
    )
    if /i "!arg:~1!" equ "unmount" (
      for /f "tokens=1" %%i in (
        'net use ^| findstr /irc:"yandex"'
      ) do net use %%i /delete
      goto:eof
    )
    goto:man
  endlocal
exit /b
 
:man
  for %%i in (
    "Usage: %~n0 [action]"
    "Where <action> is one of the next:"
    "   mount or unmount"
    ""
    "Example 1:"
    "   C:\bin> %~n0 -mount"
    ""
    "Note that while entering a user name and"
    "password both values are not displayed on"
    "the screen."
    ""
    "Example 2:"
    "   C:\bin> %~n0 -unmount"
  ) do echo:%%~i
exit /b
 
:secureinput
  <nul set /p "%~1=%~1: "
  for /f %%i in (
    '"prompt;$H&for %%i in (1) do rem"'
  ) do set "$=%%i"
  :repeat
    set "c="
    for /f "delims=" %%i in (
      '2^>nul xcopy /l /w "%~f0" "%~f0"'
    ) do if not defined c set "c=%%i"
    set "c=%c:~-1%"
    if not defined c goto:end
    if !$! equ !c! (
      <nul set /p "=!$! !$!"
      set "c="
      if defined %~1 set "%~1=!%~1:~0,-1!"
    ) else <nul set /p "="
    if not defined %~1 (
      set "%~1=!c!"
    ) else for /f delims^=^ eol^= %%i in ("!%~1!") do (
      set "%~1=%%i!c!"
    )
    goto:repeat
  :end
exit /b

@echo off
if "%*"=="" (echo parameters are absent!& echo:[re-executing]& pause) else (set "f_in=%~1"& set "f_out=%~2"& set "teg=%~3"& set "sn=%~4")
setlocal enabledelayedexpansion
<"%f_in%" (for /f "delims=[]" %%a in ('find /n /v ""^|findstr/lc:"%teg%"') do @set/a n+=1, n_=n-1, sn_=sn+1& set "N!n!=%%a")
if "%sn%"=="" (set/a nd=N%n_%+1, kd=N%n%-1) else (set/a nd=N%sn%+1, kd=N%sn_%-1)
setlocal disabledelayedexpansion
<"%f_in%">"%f_out%" (for /f "delims=" %%a in ('"for /l %%a in (%nd%,1,%kd%) do @find /n /v ""|find "[%%a]""') do @set "s=%%a"& cmd/v/c echo[!s:*]^^=!)
exit

WMIC nicconfig WHERE "Caption like '%ethernet%'" GET IPAddress /FORMAT:value

WMIC nicconfig WHERE "Caption like '%ethernet%'" GET Caption, IPAddress, IPSubnet /FORMAT:value

wmic nicconfig where "Caption like '%PPP%'" get Caption, IPAddress, IPSubnet /format:value

sudo notepad "C:\file1.txt"

root C:\Users\FraidZZ

cd C:\Users\FraidZZ
root

@echo off
>nul 2>&1 net session&&goto run
if /i "%~1"=="yes" goto run
>"%temp%\uac.vbs" echo set objShell=CreateObject^("Shell.Application"^)
>>"%temp%\uac.vbs" echo objShell.ShellExecute "%~0", "yes", , "runas", 1
"%temp%\uac.vbs"
exit /b
 
:run
del "%temp%\uac.vbs"
cd /d "%~dp0"
title %cd%
rem Место для основной программы. Текущий каталог = каталог запуска сценария.
echo Successfull! UAC unlock. Demo - this line remove...
pause

@echo off
SetLocal EnableExtensions
 
set "MAX_STREAM_SIZE=1000"
 
cd /d "%~dp0"
2>nul del ADS.log
echo _______________________________
echo  ADS scaner by Alex Dragokas
title ADS scaner by Alex Dragokas
echo _______________________________
echo.
echo Scanning disk %SystemDrive% ...
echo Please, wait.
echo.
 
net session >NUL 2>NUL || (
  echo Запустите утилиту от имени Администратора !!!
  echo You need to launch this app. as Admin !!!
  pause>nul & goto :eof
)
:: for pseudo progress-bar purposes
 
set Drive=%SystemDrive%
 
call :ScanFolder %Drive%
 
:: 1 level
for /f "delims=" %%a in ('dir /b /ad-l "%Drive%\*"') do (
 
  call :ScanFolder "%Drive%\%%a"
 
  rem 2 level
  for /f "delims=" %%b in ('dir /b /ad-l "%Drive%\%%a\*"') do (
 
    rem Start recursive scanning on 2 level
    call :ScanFolder "%Drive%\%%a\%%b" /s
  )
)
 
del t.log t2.log
explorer ADS.log
pause
goto :eof
 
:ScanFolder [Path] [/s for recursive]
 
echo "%~1"
dir /r /a-l /-c %~2 "%~1\*" > t.log
echo Parsing ...
< t.log > t2.log findstr /r /c:":.*:" /c:"Содержимое папки" /c:"Directory of"
 
for /f "tokens=1-2*" %%a in (t2.log) do (
 
  if "%%a %%b"=="Содержимое папки" (
    set "Folder=%%c"
  ) else (
  if "%%a %%b"=="Directory of" (
    set "Folder=%%c"
  ) else (
  if %%a GTR %MAX_STREAM_SIZE% call :Log "%%a" "%%b %%c"
  ))
)
exit /b
 
:Log
echo %~1 "%Folder%\%~2" >> ADS.log
exit /b

@echo off
  if /i "%~1" equ "" if not defined run goto:box
  setlocal enabledelayedexpansion
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if !i! neq 1 goto:err
 
    echo:%~1|>nul findstr /irc:"[a-f,x]"&&(
      2>nil (set /a "dec=0%~1"||set /a "dec=0x%~1")&&(
        for /l %%i in (1, 1, 32) do (
          set /a "bit=dec&1, dec>>=1"
          set "bin=!bit!!bin!"
        )
        echo:!bin!
      )||goto:err
    )||(
      echo:%~1|>nul findstr /irc:"[3-9a-z]"&&goto:err
      set "bin=%~1"
      for /l %%i in (1, 1, 32) do (
        if defined bin (
          set /a "dec=(dec<<1)|!bin:~0,1!"
          set "bin=!bin:~1!"
        )
      )
      cmd /c exit /b !dec!& echo 0x!=exitcode!
    )
  endlocal
exit /b
 
:err
  echo:=^>err
exit /b
 
:box
  for %%i in (
    "%~n0 v1.01 - converts hex to binary and vice versa"
    "[Enter .c to clear output data or .q to exit]"
    ""
  ) do echo:%%~i
  setlocal
    set "run=true"
    :repeat
      set /p "i=>>> "
      cmd /c "%~f0" %i%
      if /i "%i%" equ ".c" cls
      if /i "%i%" equ ".q" goto:eof
      goto:repeat
  endlocal
exit /b

@echo off
  setlocal
    for /f "tokens=3,4,5,7" %%i in (
      'robocopy . . $ /l /njh /nfl /ndl^
      ^| findstr /rc:"%time:~0,-3%"'
    ) do (
      set "dow=%%i" % rem : день недели
      set "mon=%%j" % rem : месяц
      set "day=%%k" % rem : день
      :: високосный?
      set "year=%%l"
    )
    set "d=31;28;31;30;31;30;31;31;30;31;30;31" % rem : количество дней в месяцах
    set /a "leap=!(year%%4)+(!!(year%%100)-!!(year%%400))"
    if %leap% equ 1 set "d=%d:8=9%" % rem : если високосный, корректируем февраль
    set "m=Jan;Feb;Mar;Apr;May;Jun;Jul;Aug;Sep;Oct;Nov;Dec"
    set "w=Mon;Tue;Wed;Thu;Fri;Sat;Sun"
    call:printcal
  endlocal
exit /b
 
:printcal
  setlocal enabledelayedexpansion
    :: всего дней в текущем месяце
    call:getindex "!m!" "!mon!"
    call:getdays  "!d!"
    :: день недели первого дня месяца
    call:getindex "!w!" "!dow!"
    for /l %%i in (!day!, -1, 1) do (
      if %%i neq 1 if !$_! equ 1 set "$_=8"
      set /a "$_-=1"
    )
    :: строка-заготовка календаря
    set "raw=Mo Tu We Th Fr Sa Su"
    for /l %%i in (1, 1, !$_!) do set "raw=!raw!   "
    for /l %%i in (1, 1, !$$!) do (
      if %%i lss 10 (
        set "raw=!raw!  %%i"
      ) else ( set "raw=!raw! %%i" )
    )
    :: бъем строку на блоки и выводим результат
    call:strlen "!raw!"
    echo:      !mon! !year!
    for /l %%i in (0, 21, !i!) do echo !raw:~%%i,20!
  endlocal
exit /b
 
:getdays
  set "i=0"
  for %%i in (%~1) do (
    set /a "i+=1"&if !i! equ !$_! set "$$=%%i"
  )
exit /b
 
:getindex
  set "i=0"
  for %%i in (%~1) do (
    set /a "i+=1"&if /i "%%i" equ "%~2" set "$_=!i!"
  )
exit /b
 
:strlen
  set "i=0"
  set "str=%~1"
  :repeat
    set "c=!str:~%i%,1!"
    if defined c set /a "i+=1"&goto:repeat
exit /b

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error
 
:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done
 
:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%
 
:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
 
GOTO:EOF
 
:s_error
Echo GetDate.cmd
Echo Displays date and time independent of OS Locale, Language or date format.
Echo Requires Windows XP Professional, Vista or Windows 7

@echo off
for /f "tokens=1* delims==" %%a in ('"wmic path win32_localtime get Day,Month,Year,Hour,Minute,Second /value|find "^=""') do set "%%a=0%%b"
echo %Year:~-5%.%Month:~-3%.%Day:~-3%-%Hour:~-3%'%Minute:~-3%'%Second:~-3%
pause& exit