Полезные BAT/CMD скрипты

@echo off
  setlocal
    set "i=0"
    for %%i in (%*) do set /a "i+=1"
    if %i% neq 1 echo:Index is out of range.&goto:eof
    set "__COMPAT_LAYER=RunAsInvoker"
    start "" %1
  endlocal
exit /b

E:\sandbox> cdb -z %comspec% -c "vertarget;q"

E:\sandbox> cdb -z %comspec% -c "vertarget;q" | findstr /irc:"ver" | sed $!d

@echo off
  setlocal enabledelayedexpansion
    set "str=011101010111001101100101011100100011101001110000011000010111001101110011"
    set "i=0"
    :loop
      set "oct=!str:~%i%,8!"
      set "bin=%oct%"
      set "dec="
      for /l %%i in (1, 1, 32) do (
        if defined bin (
          set /a "dec=(dec<<1)|!bin:~0,1!"
          set "bin=!bin:~1!"
        )
      )
      cmd /c exit /b %dec%
      set "res=!res!!=exitcodeascii!"
      if defined oct set /a "i+=8"&goto:loop
    echo:%res%
  endlocal
exit /b

@echo off
  setlocal
    rem Завтра
    call:shiftDate %date% + 1
    echo:%day%
    rem Вчера
    call:shiftDate %date% - 1
    echo:%day%
  endlocal
exit /b
 
:toJulianDay
  set /a "jdn=(1461*(%3+4800+(%2-14)/12))/4+(367*(%2-2-12*((%2-14)/12)))/12-(3*((%3+4900+(%2-14)/12)/100))/4+%1-32075"
exit /b
 
:fromJulianDay
  set /a "a=jdn+32044, b=(4*a+3)/146097, c=a-146097*b/4, d=(4*c+3)/1461, e=c-1461*d/4, m=(5*e+2)/153"
  set /a "dd=e-(153*m+2)/5+1, mm=m+3-12*(m/10), yy=100*b+d-4800+m/10"
  if %dd% lss 10 set "dd=0%dd%"
  if %mm% lss 10 set "mm=0%mm%"
  set "day=%dd%.%mm%.%yy%"
exit /b
 
:shiftDate
  set "d=%~1"
  2>nul set /a "dd=%d:~0,2%, mm=%d:~3,2%, yy=%d:~6,4%"
  call:toJulianDay %dd% %mm% %yy%
  set /a "jdn%~2=%~3"
  call:fromJulianDay
exit /b

@echo off
  setlocal
    call:shiftDate 28.02.2018 + 1
    echo:%day%
 
    call:shiftDate 01.01.2019 - 1
    echo:%day%
  endlocal
exit /b
 
...

@echo off
chcp 1251 >nul
title Таймер
:A
color a
echo Выберите подходящий вам пункт меню:
echo 1 - Таймер по секундам
echo 2 - Таймер по минутам
echo 3 - Таймер по минутам и секундам
echo 4 - Таймер по часам
echo 5 - Таймер по часам и минутам
echo 6 - Таймер по часам, минутам и секундам
echo Ваш выбор:
set /p v=
if "%v%"=="1" goto second
if "%v%"=="2" goto minutes
if "%v%"=="3" goto mands
if "%v%"=="4" goto hours
if "%v%"=="5" goto handm
if "%v%"=="6" goto hms
cls
goto a
:second
cls
echo Введите время в Секундах.
set /p s=
echo Вы установили таймер на %s% с.
timeout /t %s% /nobreak
echo Время истекло!
start Таймер.vbs
exit
:minutes
cls
echo Введите время в Минутах.
set /p m=
set /a m1=%m%*60
echo Вы установили таймер на %m% мин.
timeout /t %m1% /nobreak
echo Время истекло!
start Таймер.vbs
exit
:mands
cls
echo Введите время в Минутах и Секундах.
echo Введите время в Минутах:
set /p m=
echo Введите время в секундах:
set /p s=
set /a ma=%m%*60+%s%
echo Вы установили таймер на %m% мин. и %s% с.
timeout /t %ma% /nobreak
echo Время истекло!
start Таймер.vbs
exit
:hours
cls
echo Введите время в Часах.
set /p h=
set /a h1=%h%*3600
echo Вы установили таймер на %h% ч.
timeout /t %h1% /nobreak
echo Время истекло!
start Таймер.vbs
exit
:handm
cls
echo Введите время в Часах и Минутах.
echo Введите время в Часах:
set /p h2=
echo Введите время в Минутах:
set /p m2=
set /a h3=%h2%*3600
set /a m3=%m2%*60
set /a hm=%h3%+%m3%
echo Вы установили таймер на %h2% ч. %m2% мин.
timeout /t %hm% /nobreak
echo Время истекло!
start Таймер.vbs
exit
:hms
cls
echo Введите время в Часах, Минутах и Секундах.
echo Введите время в Часах:
set /p h4=
echo Введите время в Минутах:
set /p m4=
echo Введите время в Секундах:
set /p s4=
set /a h5=%h4%*3600
set /a m5=%m4%*60
set /a hms=%h5%+%m5%+%s4%
echo Вы установили таймер на %h4% ч. %m4% мин. и %s4% с.
timeout /t %hms% /nobreak
echo Время истекло!
start Таймер.vbs
exit

@echo off
  setlocal enabledelayedexpansion
    set "key=HKLM\SOFTWARE\Microsoft\RADAR\HeapLeakDetection"
    set "key=%key%\DiagnosedApplications"
    for /f "tokens=3,7 delims=\ " %%i in (
      '2^>nul reg query %key% /s /v LastDetectionTime'
    ) do (
      if /i "%%~j" neq "" call:printf 37 %%j
      if /i "%%~i" neq "microsoft" (
        for /f "tokens=2 delims=-" %%i in (
          'w32tm /ntte %%i'
        ) do echo:%%i
      )
    )
  endlocal
exit /b
 
:printf
  set "i=%~1" % rem : пробелы выравнивания
  set "s=%~2" % rem : входная строка
  :while
    set "s=!s:~1!"
    if defined s set /a "i-=1"&goto:while
  set "s=%~2" % rem : добавим пробелов
  for /l %%i in (1,1,!i!) do set "s=!s! "
  <nul set /p "=!s!"
exit /b

@echo off
  setlocal enabledelayedexpansion
    set "key=HKLM\SYSTEM\CurrentControlSet\Control\Windows"
    for /f "tokens=3" %%i in ('reg query !key! /v ShutdownTime') do set "ft=%%i"
    for /l %%i in (16, -2, 0) do set "r=!r!!ft:~%%i,2!"
    for /f "tokens=4,5" %%i in ('w32tm /ntte 0x!r!') do set "d=%%i"&set "t=%%j"    
    call:getHoursDelta !t!
    call:getDaysDelta !d!
  endlocal
exit /b
 
:getDaysDelta
  set "ts=%~1"
  call:toJulianDay !ts:~0,2! !ts:~3,2! !ts:~6,4! ts
  call:toJulianDay !date:~0,2! !date:~3,2! !date:~6,4! now
  set /a "days=!now! - !ts!"
  echo: up !days! days
exit /b
 
:getHoursDelta
  call:toSeconds %~1 a
  call:toSeconds !time:~0,8! b
  set /a "a-=b"
  if !a! lss -1 set /a "a*=-1"
  set /a "h=a/3600, m=a%%3600/60, s=a%%3600%%60"
  for %%i in (h m s) do (
    if !%%i! lss 10 set "%%~i=0!%%~i!"
  )
  <nul set /p "=!h!:!m!:!s!"
exit /b
 
:toJulianDay
  set /a "d=100%~1-100, m=100%~2-100"
  set "jdn=(1461*(%~3+4800+(m-14)/12))/4+(367*(m-2-12*((m-14)/12"
  set "jdn=!jdn!)))/12-(3*((%~3+4900+(m-14)/12)/100))/4+d-32075"
  set /a "%~4=!jdn!"
exit /b
 
:toSeconds
  set "tm=%~1"
  set "i=0"
  for %%i in ("!tm::=";"!") do (
    2>nul set /a "arr.!i!=%%~i"
    set /a "i+=1"
  )
  set /a "s=arr.0*3600+arr.1*60+arr.2"
  set "%~2=!s!"
exit /b

@echo off
::запуск определенной виртуальной машины
"C:\Program Files\Oracle\VirtualBox\VBoxManage.exe" startvm "VM_Name"
::Вместо "VM_Name" необходимо указать имя виртуальной машины, которую требуется запустить

::пауза на 15 секунд (чего вполне достаточно для запуска виртуальной машины)
>nul ping -n 15 127.0.0.1
::блокировка пользователя (равносильно нажатию сочетания клавиш "Win+L")
RunDll32.exe user32.dll,LockWorkStation

@echo off
::Отключение функции "Участие в программе улучшения качества ПО"
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\SQMClient\Windows" /f /v CEIPEnable /t REG_DWORD /d 0
::Отключение службы "Diagnostics Tracking Service"
net stop DiagTrack
sc config DiagTrack start= disabled
::Отключение задач телеметрии в планировщике
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\AITAgent" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\ProgramDataUpdater" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Autochk\Proxy" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\Consolidator" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\KernelCEIPTask" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\UsbCEIP" /Disable
SchTasks /Change /TN "\Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticDataCollector" /Disable
::Удаление обновлений телеметрии
start /w wusa.exe /uninstall /kb:3075249 /quiet /norestart
start /w wusa.exe /uninstall /kb:3080149 /quiet /norestart
start /w wusa.exe /uninstall /kb:3021917 /quiet /norestart
start /w wusa.exe /uninstall /kb:3022345 /quiet /norestart
start /w wusa.exe /uninstall /kb:3068708 /quiet /norestart
start /w wusa.exe /uninstall /kb:3022345 /quiet /norestart
start /w wusa.exe /uninstall /kb:2976978 /quiet /norestart
::Перезагрузка компьютера, чтобы изменения вступили в силу
shutdown -r -t 000

@echo off
::Отключение телеметрии в реестре
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Data Collection" /f /v AllowTelemetry /t REG_DWORD /d 0
::Отключение служб телеметрии
net stop bits
net stop dosvc
net stop DiagTrack
net stop dmwappushservice
sc config bits start= disabled
sc config dosvc start= disabled
sc config DiagTrack start= disabled
sc config dmwappushservice start= disabled
::Отключение задач телеметрии в планировщике
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\StartupAppTask" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\ProgramDataUpdater" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Autochk\Proxy" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\Consolidator" /Disable
SchTasks /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\UsbCEIP" /Disable
SchTasks /Change /TN "\Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticDataCollector" /Disable
SchTasks /Change /TN "\Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticResolver" /Disable
::Перезагрузка компьютера, чтобы изменения вступили в силу
shutdown -r -t 000

@set @a=0/*
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Отобразить текущую сборку ПК (FlasherX, 20.02.2021) ::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off&setlocal enabledelayedexpansion&chcp 1251>nul
echo Материнская плата:&wmic CsProduct get Name,Vendor|find "-"
echo.&echo Процессор:
for /f "tokens=1*" %%i in ('"wmic Path Win32_Processor get Name,SocketDesignation,MaxClockSpeed|findstr [0-9]"') do set j=%%j&echo !j:~,-11!  %%i MGz
echo.&echo Оперативная память:
echo ————————————————————————
echo  № ^| Размер ^|  MGz ^| Тип
echo ————————————————————————
for /f tokens^=1-3 %%c in ('"wmic MemoryChip get Capacity,Speed,MemoryType|findstr [0-9]"') do (
  set/a c+=1 &if %%d leq 1 (set t=не распознан) else (^
  for %%# in (DRAM.2 "Synchronous DRAM.3" "Cache DRAM.4" EDO.5 EDRAM.6 VRAM.7 SRAM.8 RAM.9 ROM.10 Flash.11 EEPROM.12 FEPROM.13 EPROM.14 CDRAM.15 3DRAM.16 SDRAM.17 SGRAM.18 RDRAM.19 DDR.20 DDR2.21 "DDR2 FB-DIMM.22" DDR3.24 FBD2.25 DDR4.26) do if %%~x#==.%%d set "t=%%~n#")
  for /f delims^= %%n in ('cscript /e:jscript "%~f0" %%c') do set "s=%%n"
  echo  !c! ^| !s:~2! ^| %%e ^| !t!
)
echo.&echo Видеоконтроллер:
for /f tokens^=1* %%i in ('"wmic Path Win32_VideoController get AdapterRAM,Name|findstr [0-9]"') do ^
set "n=%%j" & for /f delims^= %%n in ('cscript /e:jscript "%~f0" %%i') do set "s=%%n"&echo !n:~,-3!!s:~2!
echo.&echo HDD/SSD диск:
echo ——————————————————————
echo  № ^|  Размер  ^| Модель
echo ——————————————————————
for /f tokens^=1-2 %%i in ('"wmic DiskDrive get SerialNumber,Size|findstr [A-Z][0-9]"') do (
  set/a x+=1 & for /f delims^=^ eol^= %%n in ('cscript /e:jscript "%~f0" %%j') do set "SZ!x!=%%n"
)
for /f delims^= %%i in ('"wmic DiskDrive get Model|findstr [0-9]"') do set/a i+=1 & call:r !i! "%%i"
echo.&echo Оптический привод:
wmic CDROM get Name|findstr [0-9]||echo — отсутствует —
echo.&echo Звуковая карта:
wmic SOUNDDEV get Name|findstr /vrc:"^Name[^\w]"|find /i /v "phone"|find /v "NVIDIA"|find /v "AMD"
echo Сетевая карта:
for /f tokens^=3* %%i in ('wmic nic get name^|find " PCI"') do echo %%i %%j
pause>nul
exit
 
:r
echo  %1 ^| !SZ%1! ^| %~2
exit/b
 
*/n=Math.abs(WSH.Arguments(0))/1024/1024;t='MB';if(n>=1024){n=n/1024;t='GB'}
s=Math.round(n)+' '+t; WSH.echo(Array(9-s.length).join(' ')+s)

@echo off
::Очистка записей DNS
ipconfig /flushdns
::Очистка и перезагрузка таблицы удаленного буфера имен, (ключ -R должен быть именно заглавным)
nbtstat -R
::Cброс параметров стека сетевых протоколов
netsh int ip reset
netsh winsock reset
::Перезагрузка
shutdown -r -f -t 000