Полезные BAT/CMD скрипты

chcp 65001
::Создание папки с именем компьютера на сервере
MD \\Server\ARM\%COMPUTERNAME%
::Модель материнской платы
wmic baseboard get Manufacturer >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
wmic baseboard get product >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
::Информация о процессоре
wmic cpu get name >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
::Суммарный объем ОЗУ
wmic OS Get TotalVisibleMemorySize >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
::Определение модели ноутбука
wmic csproduct get name >> \\Server\ARM\%COMPUTERNAME%\ARM\%COMPUTERNAME%-conf.txt
::Модель и объем накопителей
wmic diskdrive get model, SerialNumber, size >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
::Версия установленной ОС
wmic os get name >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
wmic os get version >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-conf.txt
::Список установленных программ
wmic product get name, version >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-soft.txt
::Сетевые параметры системы
ipconfig /all >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-lan.txt
::Статические маршруты системы
route print >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-lan.txt
rem подключенные сетевые папки
net use >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-lan.txt
::Имя текущего пользователя и домена
echo %userdomain% >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-user.txt
echo %username% >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-user.txt
::Вывести список подключенных принтеров и портов
wmic printer get DeviceID, PortName >> \\Server\ARM\%COMPUTERNAME%\%COMPUTERNAME%-Printers.txt
::Завершение работы интерпретатора cmd
Exit /b

@echo off
::Включение служб для сетевого обнаружения
::Обнаружение SSDP
sc config SSDPSRV start= auto
net start SSDPSRV
::Публикация ресурсов обнаружения функций
sc config FDResPub start= auto
net start FDResPub
::Рабочая станция
sc config LanmanWorkstation start= auto
net start LanmanWorkstation
::Сервер
sc config LanmanServer start= auto
net start LanmanServer
::Узел универсальных PNP-устройств
sc config upnphost start= auto
net start upnphost
::Хост поставщика функции обнаружения
sc config fdPHost start= auto
net start fdPHost
::Включить обнаружение сети
netsh advfirewall firewall set rule group="Обнаружение сети" new enable=Yes
::Завершение работы интерпретатора
Exit /b

@Echo Off
 
REM == EXAMPLE =============================================
Call :CheckInternet
echo Network is avalible: %network_connection_state%
pause
REM ========================================================
 
 
REM == CODE ================================================
:CheckInternet
Set host1=wikipedia.org
Set host2=google.com
 
>"nul"="%SystemRoot%\System32\ping.exe" %host1% -l 1 -n 1
If "%errorlevel%"=="1" (>"nul"="%SystemRoot%\System32\ping.exe" %host2% -l 1 -n 2);
If "%errorlevel%"=="0" (Set "network_connection_state=True") Else (Set "network_connection_state=False");
Exit /b
REM ========================================================

:strlen10  StrVar  [RtnVar]
setlocal EnableDelayedExpansion
set "s=#!%~1!"
set /a "len=0"
for /l %%A in (13,-1,0) do (
  set /a "len|=1<<%%A"
  for %%B in ("!len!") do if "!s:~%%B,1!"=="" set /a "len&=~1<<%%A"
)
endlocal&if "%~2" neq "" (set /a "%~2=%len%") else echo %len%
exit /b

:strlen2  StrVar  [RtnVar]
setlocal EnableDelayedExpansion
echo("!%~1!">"tempFile"
for %%F in ("tempFile") do set /a "len=%%~zF-2"
endlocal&if "%~2" neq "" (set /a "%~2=%len%") else echo %len%
exit /b

@echo off
::Переход в каталог со списком баз по умолчанию
CD /D "%appdata%\1C\1CEStart"
::Удаление ibases.v8i
DEL ibases.v8i
::Создание нового ibases.v8i
set "F="%appdata%\1C\1CEStart\ibases.v8i""
::Название базы в квадратных скобках, как отображается в списке
@echo [Информационная база]>%F%
::Строка соединения с информационной базой: для файлового варианта Connect=File=<Путь>
::для клиент-серверного варианта Connect=Srvr=<ИмяСервера1С>;Ref=<ИмяБазы1С>.
@echo Connect=Srvr="СЕРВЕР";Ref="БАЗА";>>%F%
::Уникальный идентификатор базы в рамках файла, формируется автоматически
@echo ID=00000000-00000-0000-0000-000000000000>>%F%
::Порядок в списке при представлении списком;
@echo OrderInList=-1>>%F%
::Наименование ветви в дереве
@echo Folder=/>>%F%
::Порядок в ветви при представлении деревом
@echo OrderInTree=256>>%F%
::Если значение отличается от 0, то база удаляется из списка
@echo External=0>>%F%
::Скорость соединения для тонкого и веб клиентов: Normal — обычная, Low — низкая.
@echo ClientConnectionSpeed=Normal>>%F%
::Тип клиентского приложения: Auto – автоматический выбор типа клиентского приложения;
::ThinClient – тонкий клиент, ThickClient – толстый клиент, WebClient – веб-клиент.
@echo App=Auto>>%F%
::Аутентификация Windows (1 — вход под учетной записью ОС (авто), а в случае ошибки запрашивается имя пользователя и пароль, 0 — аутентификация 1С);
@echo WA=1>>%F%
::Версия платформы
@echo Version=8.3>>%F%
::Завершение работы интерпретатора
exit /b

@echo off
::Остановка и отключение службы SuperFetch
sc stop "SysMain" && sc config "SysMain" start=disabled
::Остановка и отключение службы Индексирования
sc stop "wsearch" && sc config "wsearch" start=disabled
::Отключение Prefetch
REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Memory Management\PrefetchParameters" /v EnablePrefetcher /t REG_DWORD /d 0 /f
::Отключение ClearPageFileAtShutdown
REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Memory Management" /v ClearPageFileAtShutdown /t REG_DWORD /d 0 /f
::Отключение LargeSystemCache
REG ADD "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Memory Management" /v LargeSystemCache /t REG_DWORD /d 0 /f
::Отключение гибернации
powercfg -h off
::Активация TRIM
fsutil behavior set DisableDeleteNotify 0
::Отключение дефрагментации в Планировщике задач
schtasks /Change /TN \Microsoft\Windows\Defrag\ScheduledDefrag /DISABLE
::Перезагрузка компьютера, чтобы изменения вступили в силу
shutdown -r -t 000

@echo off
::Остановка службы Диспетчер печати
net stop Spooler
::Очистка очереди печати
DEL /F /Q %systemroot%\System32\spool\PRINTERS\*
::Запуск службы Диспетчер печати
net start Spooler
::Завершение работы интерпретатора
exit /b

@echo off
::Указываем где будет хранится наш лог-файл, куда будет писаться дата и время запуска и остановки службы
set logfile="C:\Windows\Logs\1C\1C_agent.txt"
::Пишем в Лог дату и время начала остановки
echo %date% %time% >>%logfile%
::Останавливаем службу агента сервера и пишем ее статус в лог файл
net stop "1C:Enterprise 8.3 Server Agent (x86-64)" >>%logfile%
::Далее делаем задержку в 15 секунд, чтобы дождаться, пока служба останавливается
ping -n 16 localhost>Nul
::Опять записываем в лог дату в время
echo %date% %time% >>%logfile%
::Запускаем службу обратно
net start "1C:Enterprise 8.3 Server Agent (x86-64)" >>%logfile%
::Делаем задержку в 5 минут, если служба не остановилась за 15 секунд, то она не запустится естественно, что то видимо зависло сильно и будем ждать 5 минут.
ping -n 301 localhost>Nul
::Далее проверяем, запустилась ли служба и работает ли она? Если не работает, то выполняем ее повторный старт.
SetLocal EnableExtensions
Set ProcessName=1C:Enterprise 8.3 Server Agent (x86-64)
TaskList /FI "ImageName EQ %ProcessName%" | Find /I "%ProcessName%"
If %ErrorLevel% NEQ 0 net start "1C:Enterprise 8.3 Server Agent (x86-64)"
::Завершение работы интерпретатора cmd
exit /b

setlocal EnableExtensions DisableDelayedExpansion
 
%SystemRoot%\System32\wbem\wmic.exe BaseBoard get SerialNumber  >"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe baseboard get Manufacturer  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe baseboard get product  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe cpu get name  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe OS Get TotalVisibleMemorySize  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe csproduct get name  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe diskdrive get model, SerialNumber, size  >>"%TEMP%\%~n0.tmp"
%SystemRoot%\System32\wbem\wmic.exe os get name  >>"%TEMP%\%~n0.tmp"
 
if not exist "%TEMP%\%~n0.tmp" goto EndBatch
 
for /F "skip=1 tokens=1,2" %%I in ('type "%TEMP%\%~n0.tmp"') do echo %%I %%J >> %p%
del "%TEMP%\%~n0.tmp"
 
:EndBatch
endlocal

@DELETE SYSINFO.TXT 2>NUL
@WMIC OS Get Name, TotalVisibleMemorySize /format:MY.FORMAT.XSL >> SYSINFO.TXT

wmic computersystem GET TotalPhysicalMemory, Domain, NumberOfProcessors, NumberOfLogicalProcessors /format:rawxml

@echo off
chcp 866
 
:start
cls
title Script copy USER PROFILE v1.1
color 3
 
echo Укажите имя каталога от корня, вида:( D:\User или D:\User\Admin )
set /p var=" "
 
set DISK=%var%
if not exist %DISK% ( 
mkdir %DISK%
echo [.ShellClassInfo] > %DISK%\desktop.ini
echo IconResource=%SystemRoot%\system32\imageres.dll,117 >> %DISK%\desktop.ini
attrib +S %DISK%
attrib +R +S +H %DISK%\desktop.ini
)
 
if exist %DISK% (
  REM *****************************************************************
  call :CopyProfile Desktop
  call :CopyProfile Documents
  call :CopyProfile Downloads
  call :CopyProfile Music
  call :CopyProfile Videos
  call :CopyProfile Pictures
  REM *****************************************************************  
  call :CreateProfile Fotos 326
  call :CreateProfile Install 162
  call :CreateProfile Arhiv 8
  REM *****************************************************************
  mklink /D "%DISK%\Documents\Мои видеозаписи" %DISK%\Videos
  mklink /D "%DISK%\Documents\Мои рисунки" %DISK%\Pictures 
  mklink /D "%DISK%\Documents\Моя музыка" %DISK%\Music
  mklink /D "%DISK%\Documents\Мои загрузки" %DISK%\Downloads
  mklink /D "%DISK%\Documents\Мои фотографии" %DISK%\Fotos
  REM ***************************************************************** 
  pause
) else goto Error
 
exit  
REM *****************************************************************
 
:CopyProfile
set KAT=%1
set KATALOG=%USERPROFILE%\%KAT%
set KATALOG_NEW=%DISK%\%KAT%
if not exist %KATALOG_NEW% mkdir %KATALOG_NEW%
 xcopy %KATALOG% %KATALOG_NEW% /c /v /s /e /i /h /y >nul
 attrib +S %KATALOG_NEW%
 attrib +R +S +H %KATALOG_NEW%\desktop.ini
 rmdir /s /q %KATALOG%
 mklink /D %KATALOG% %KATALOG_NEW%
exit /b
 
:CreateProfile
set KAT=%DISK%\%1
set ICO=%2
mkdir %KAT%
echo [.ShellClassInfo] > %KAT%\desktop.ini
echo IconFile=%SystemRoot%\system32\shell32.dll >> %KAT%\desktop.ini
echo IconResource=%SystemRoot%\System32\shell32.dll,%ICO% >> %KAT%\desktop.ini
attrib +S %KAT%
attrib +R +S +H %KAT%\desktop.ini 
exit /b
 
:Error   
color c
echo %DISK%!!!
echo Проверьте путь к каталогу!
pause
goto start

@echo off
setlocal
 
for /f "tokens=2 delims=:" %%i in ('chcp') do (
    set sPrevCP=%%i
    chcp 1251 >nul
)
 
for /f "usebackq delims=" %%i in (
    `@"%systemroot%\system32\mshta.exe" "about:<FORM><INPUT type='file' name='qq'></FORM><script>document.forms[0].elements[0].click();var F=document.forms[0].elements[0].value;try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(F)};catch (e){};close();</script>" ^
    1^|more`
) do set sFileName=%%i
 
chcp %sPrevCP% >nul
 
if defined sFileName (
    echo Выбран файл: [%sFileName%].
) else (
    echo Файл не был выбран.
)
 
endlocal
exit /b 0

@echo off
::Установка принтера по умолчанию в реестре (в данном случае ECOSYS M3040dn)
reg Add "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows" /v Device /t REG_SZ /d "ECOSYS M3040dn,winspool,Ne05:" /y
::Применение политики, чтобы не перезагружать систему для применения параметра в реестре
gpupdate /force
::Завершение работы интерпретатора
Exit /b

@echo off
:: Создание батника в %appdata%
set "F="%appdata%\1C\taskkill1c.bat""
echo @echo off>>%F%
echo taskkill.exe /IM 1cv8c.exe /F>>%F%
echo Exit /b>>%F%
:: Создание задачи в планировщике от имени текущей учетной записи, 02:00 ежедневно
schtasks /create /f /rl highest /sc daily /st 02:00:00 /tn Taskkill_1C /tr "'%appdata%\1C\taskkill1c.bat'"
::Завершение работы интерпретатора командной строки
Exit /b

@echo off
::Указать путь до devcon.exe
::Если путь содержит пробелы его необходимо заключить в кавычки
"%userprofile%\AppData\Roaming\DevCon\devcon.exe" rescan
::Завершение работы интерпретатора командной строки
exit /b

@echo off
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v NoRecentDocsHistory /t REG_DWORD /d 1
exit /b

@echo off
:: Импорт ключей в реестр, увеличивающих абсолютное значение
reg add "HKLM\System\CurrentControlSet\services\w32time\Config" /f /v MaxNegPhaseCorrection /t REG_DWORD /d 0xffffffff
reg add "HKLM\System\CurrentControlSet\services\w32time\Config" /f /v MaxPosPhaseCorrection /t REG_DWORD /d 0xffffffff
::Запуск и установка автоматического типа запуска службы времени Windows  на случай, если служба неактивна
net start W32Time
sc config W32Time start= auto
::Изменение конфигурации службы времени, для использования сервера NTP ru.pool.ntp.org
W32Tm /config /syncfromflags:manual /manualpeerlist:ru.pool.ntp.org /update
::Создание командного файла на принудительный запуск заданий в планировщике:
set "F="%ProgramFiles%\SyncTime.bat""
echo @echo off>>%F%
echo C:\Windows\System32\schtasks.exe /run /tn "\Microsoft\Windows\Time Synchronization\ForceSynchronizeTime">>%F%
echo C:\Windows\System32\schtasks.exe /run /tn "\Microsoft\Windows\Time Synchronization\SynchronizeTime">>%F%
echo exit /b>>%F%
:: Создание задачи в планировщике с триггером "При входе в систему"
schtasks /create /RU "LOCAL SERVICE" /f /rl highest /sc onlogon /tn SyncTime /tr "'%ProgramFiles%\SyncTime.bat'"
::Завершение работы интерпретатора
exit /b