Как изменить размер существующего поля таблицы ACCESS?

// сохранение в контексте события TDataSet.BeforeClose
procedure SaveGridColumnsLayout(Grid: TCustomGrid; IniFile: TIniFile);
var
  Owner: TComponent;
  i: Integer;
  slw, slo: TStringList;
  s: AnsiString;
  NeedOpenFile: Boolean;
begin
  s := Grid.Name;
  Owner := Grid.Owner;
  while Assigned(Owner) and not (Owner is TForm) do
    Owner := Owner.Owner;
  if Assigned(Owner) then
    s := Format('%s.%s', [Owner.Name, s]);

  NeedOpenFile := not Assigned(IniFile);
  if NeedOpenFile then
    IniFile := TIniFile.Create(frmSetup.IniFileName);
  slw := TStringList.Create;
  slo := TStringList.Create;
  try
    slw.Delimiter := ',';
    slo.Delimiter := ',';
    if Grid is TDBGrid then
      for i := 0 to TDBGrid(Grid).Columns.Count - 1 do
        begin
          slo.Add(TDBGrid(Grid).Columns[i].FieldName);
          slw.Add(IntToStr(TDBGrid(Grid).Columns[i].Width));
        end
    else if Grid is TValueListEditor then
      for i := 0 to TValueListEditor(Grid).TitleCaptions.Count - 1 do
        begin
          slo.Add(TValueListEditor(Grid).TitleCaptions[i]);
          slw.Add(IntToStr(TValueListEditor(Grid).ColWidths[i]));
        end
    else
      Exit;
    IniFile.WriteString('ControlsAdjustment', Format('%s.ColumnsOrder', [s]), slo.DelimitedText);
    IniFile.WriteString('ControlsAdjustment', Format('%s.ColumnsWidth', [s]), slw.DelimitedText);
  finally
    slw.Free;
    slo.Free;
    if NeedOpenFile then
      IniFile.Free;
  end;
end;

// восстановление в контексте события TDataSet.AfterOpen
procedure RestoreGridColumnsLayout(Grid: TCustomGrid; IniFile: TIniFile);
var
  Owner: TComponent;
  i,k,w: Integer;
  slw, slo: TStringList;
  s: AnsiString;
  NeedOpenFile: Boolean;
begin
  s := Grid.Name;
  Owner := Grid.Owner;
  while Assigned(Owner) and not (Owner is TForm) do
    Owner := Owner.Owner;
  if Assigned(Owner) then
    s := Format('%s.%s', [Owner.Name, s]);
  NeedOpenFile := not Assigned(IniFile);
  if NeedOpenFile then
    IniFile := TIniFile.Create(frmSetup.IniFileName);
  slw := TStringList.Create;
  slo := TStringList.Create;
  try
    slw.Delimiter := ',';
    slo.Delimiter := ',';
    slo.DelimitedText := IniFile.ReadString('ControlsAdjustment', Format('%s.ColumnsOrder', [s]), '');
    slw.DelimitedText := IniFile.ReadString('ControlsAdjustment', Format('%s.ColumnsWidth', [s]), '');
    if Grid is TDBGrid then
      begin
        for k := 0 to slo.Count - 1 do
          for i := 0 to TDBGrid(Grid).Columns.Count - 1 do
            if AnsiCompareText(TDBGrid(Grid).Columns[i].FieldName, slo[k]) = 0 then
              begin
                try
                  TDBGrid(Grid).Columns[i].Index := k;
                except
                end;
                Break;
              end;
        for k := 0 to slw.Count - 1 do
          if TryStrToInt(slw[k], w) then
            try
              TDBGrid(Grid).Columns[k].Width := w;
            except
            end;
      end
    else if Grid is TValueListEditor then
      begin
        for k := 0 to slw.Count - 1 do
          if TryStrToInt(slw[k], w) then
            try
              TValueListEditor(Grid).ColWidths[k] := w;
            except
            end;
      end
    else
      Exit;
  finally
    slw.Free;
    slo.Free;
    if NeedOpenFile then
      IniFile.Free;
  end;
end;