Ассемблер: флаг Болгарии - Assembler - Ответ 5906704

; masm dos com #
.model tiny
.CODE
.386
ORG 100H
WIDTH_SCREEN    equ 320
HEIGHT_SCREEN   equ 200 
X = 40
Y = 80
H = 90
W = 2*H
 
start:  mov     ax,13h
    int     10h
    fninit
    fld1
    fldz
mainloop:;заполняю видеобуфер цветом фона
        push    ds
    pop     es
    mov     di,offset BUFF
    mov     cx,WIDTH_SCREEN*HEIGHT_SCREEN/4
    mov     eax,09090909h   ;BACKGROWND
    rep     stosd
    push    0A000h
    pop     es              ;es=0A000h
;DRAW FLAG---------------------
        mov     si,W
@@:     mov     x,si
;GET Y-------------------------
        fild    x
        push (H/5)*10000h+20
        fidiv   word ptr [esp]  ;st(0)=x/20
        fadd    st,st(1)    ;st(0)=x/20+T
        fsin            ;st(0)=sin(x/20+T)
        fimul   x       ;st(0)=x*sin(x/20+T)
        fidiv   word ptr [esp+2];st(0)=5*x*sin(x/20+T)/H
        fistp   word ptr [esp]  ;TMP
        pop edx     ;dx=TMP
        add     dx,Y
        mov     ax,x
        db  0D4h,5      ;ah=x/5
        SUB     dl,ah
;--------------------------------
    mov     al,0Fh      ;ярко-белый
    call    DRAW_VERTICAL_LINE
    mov     al,2        ;зеленый
    call    DRAW_VERTICAL_LINE
    mov     al,0Ch      ;ярко-красный
    call    DRAW_VERTICAL_LINE
    dec     si
    jnz     @b
;задержка на 0.165 сек------------------
    int 1Ah
    mov bx,dx
    add bx,3
@@: int 1Ah
    cmp bx,dx
    jnz @b
;COPY BUFF-----------------------
    mov     dx,3DAh
@@:     in      al,dx
    test    al,8;VERTICAL RETRACE CHECK
    jz     @b
@@:     in      al,dx
    test    al,8 ;VERTICAL RETRACE CHECK
    jnz      @b
    mov     si,offset BUFF 
    mov     di,WIDTH_SCREEN*8
    mov     cx,WIDTH_SCREEN*192/4
    rep     movsd
;-----------------------------
    fadd    st,st(1)    ;T=T+1
    mov es,cx       ;es=0
    mov ax,es:[41Ah]
    sub ax,es:[41Ch]
        jz  mainloop; if press key goto exit
        mov     ax,3
    int     10h
        ret ;exit to DOS
;------------------------------- 
DRAW_VERTICAL_LINE PROC
        imul    bx,dx,WIDTH_SCREEN  ;bx = X + Y * 320
        mov     cx,H/3
@@:     mov     byte ptr BUFF[bx+si+X],al
        add     bx,WIDTH_SCREEN
        loop    @b
        add dx,H/3
        ret
DRAW_VERTICAL_LINE ENDP
;-------------------------------
x       dw ?
BUFF:    
end start