Блок-схема для кода в 1С

Процедура ОбменСФилиалами() Экспорт
 
    ВыборкаУзлов = ПланыОбмена.Филиалы.Выбрать();
 
    Пока ВыборкаУзлов.Следующий() Цикл
 
        // Произвести обмен данными со всеми узлами,
        // кроме текущего (ЭтотУзел)
        Если ВыборкаУзлов.Ссылка <> ПланыОбмена.Филиалы.ЭтотУзел() Тогда
            УзелОбъект = ВыборкаУзлов.ПолучитьОбъект();
 
            // Получить сообщение
            УзелОбъект.ПрочитатьСообщениеСИзменениями();
 
            // Сформировать сообщение
            УзелОбъект.ЗаписатьСообщениеСИзменениями();
 
        КонецЕсли;
    
    КонецЦикла;
 
КонецПроцедуры

Процедура ЗаписатьСообщениеСИзменениями() Экспорт
 
    Сообщить("-------- Выгрузка в узел " + Строка(ЭтотОбъект) + " ------------");
    Каталог = КаталогВременныхФайлов();
     // Сформировать имя временного файла
    ИмяФайла = Каталог +?(Прав(Каталог, 1) = "\","", "\") + "Message" 
                    + СокрЛП(ПланыОбмена.Филиалы.ЭтотУзел().Код) + "_" + СокрЛП(Ссылка.Код) + ".xml";
 
    // Создать объект записи XML
    // *** Запись XML-документов
    ЗаписьXML = Новый ЗаписьXML;
    ЗаписьXML.ОткрытьФайл(ИмяФайла);
    ЗаписьXML.ЗаписатьОбъявлениеXML();
 
    // *** Инфраструктура сообщений
    ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();
    ЗаписьСообщения.НачатьЗапись(ЗаписьXML, Ссылка);
    Сообщить("    Номер сообщения: " + ЗаписьСообщения.НомерСообщения);
 
    // Получить выборку измененных данных
    // *** Механизм регистрации изменений
    ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(ЗаписьСообщения.Получатель, ЗаписьСообщения.НомерСообщения);
    Пока ВыборкаИзменений.Следующий() Цикл
        // Записать данные в сообщение
        // *** XML-сериализация
        ЗаписатьXML(ЗаписьXML, ВыборкаИзменений.Получить());
    КонецЦикла;
 
    ЗаписьСообщения.ЗакончитьЗапись();
    ЗаписьXML.Закрыть();
    Сообщить("-------- Конец выгрузки------------");
 
КонецПроцедуры

Процедура ПрочитатьСообщениеСИзменениями() Экспорт
 
    Каталог = КаталогВременныхФайлов();
 
    // Сформировать имя файла
    ИмяФайла = Каталог +?(Прав(Каталог, 1) = "\", "", "\") + "Message" 
                    + СокрЛП(Ссылка.Код) + "_" + СокрЛП(ПланыОбмена.Филиалы.ЭтотУзел().Код) + ".xml";
    Файл = Новый Файл(ИмяФайла);
    Если Не Файл.Существует() Тогда
        Возврат;
    КонецЕсли;
 
    // *** Чтение документов XML    
    // Попытаться открыть файл
    ЧтениеXML = Новый ЧтениеXML;
    Попытка 
        ЧтениеXML.ОткрытьФайл(ИмяФайла);
    Исключение 
        Сообщить("Невозможно открыть файл обмена данными.");
        Возврат;
    КонецПопытки;
    Сообщить("-------- Загрузка из " + Строка(ЭтотОбъект) + "------------");
    Сообщить(" - Считывается файл " + ИмяФайла);
   
    // Загрузить из найденного файла
    // *** Инфраструктура сообщений
    ЧтениеСообщения = ПланыОбмена.СоздатьЧтениеСообщения();
 
    // Читать заголовок сообщения обмена данными - файла XML
    ЧтениеСообщения.НачатьЧтение(ЧтениеXML);
   
    // Сообщение предназначено не для этого узла
    Если ЧтениеСообщения.Отправитель <> Ссылка Тогда
        ВызватьИсключение "Неверный узел";
    КонецЕсли;
 
    // Удаляем регистрацию изменений
    // для узла отправителя сообщения
    // *** Служба регистрации изменений
    ПланыОбмена.УдалитьРегистрациюИзменений(ЧтениеСообщения.Отправитель,ЧтениеСообщения.НомерПринятого);
     
    // Читаем данные из сообщения
    // *** XML-сериализация
    Пока ВозможностьЧтенияXML(ЧтениеXML) Цикл
        // Читаем очередное значение
        Данные = ПрочитатьXML(ЧтениеXML);
 
        // Не переносим изменение, полученное
        // в главный из неглавного,
        // если есть регистрация изменения
        Если Не ЧтениеСообщения.Отправитель.Главный
              И ПланыОбмена.ИзменениеЗарегистрировано(ЧтениеСообщения.Отправитель, Данные) Тогда
            Сообщить("- Изменения отклонены");
            Продолжить;
        КонецЕсли;
 
        // Записать полученные данные
        Данные.ОбменДанными.Отправитель = ЧтениеСообщения.Отправитель;
        Данные.ОбменДанными.Загрузка = Истина;
        Данные.Записать();
    КонецЦикла;
 
    ЧтениеСообщения.ЗакончитьЧтение();
    ЧтениеXML.Закрыть();
    УдалитьФайлы(ИмяФайла);
    Сообщить("-------- Конец загрузки------------");
 
КонецПроцедуры