Вопросы по генетическим алгоритмам

program GAv9;
uses crt; {подключение библиотеки по обслуживанию консоли}
 
const { объявление констант}
maxpop = 80;  {максимальное число популяций}
maxstring = 20;  {максимальная длина строки}
dim = 2;  {размерность пространства поиска}
 
type
     allele = boolean; {Алель - битовое значение гена в битовой строке}
     chromosome = array[1..maxstring*dim] of allele;   {битовая строка}
     fenotype = array[1..dim] of real;
     individual = record
     chrom:chromosome; { генотип = битовая строка }
      x:fenotype; { фенотип = массив вещественных
      координат точки в пространстве поиска }
      fitness:real; {значение целевой функции }
      end;
     population = array[1..maxpop] of individual;
 
const
     xmax:fenotype=(5.12,5.12);{массив максимальных
     значений для координат  точки в пространстве поиска}
     xmin:fenotype=(-5.12,-5.12);{массив минимальных
     значений для координат точки в пространстве поиска}
 
var { объявление переменных }
   oldpop, newpop, intpop :population;  {Три непересекающихся
                    популяции - старая, новая и промежуточная}
   popsize, lchrom, gen, maxgen: integer; {Глобальные целые переменные}
   pcross, pmutation, sumfitness:real;  {глобальные вещественные переменные}
   nmutation, ncross:integer;  {Статистические целые}
   avg, max, mmin, min:real;  {Статистические вещественные}
   h, psize, razpop, s, b:Integer;
   Otv, Otvet:Real;    {Прочие переменные}
   Povtor : integer;   {количество повторов программы}
   Fres : text;        {текстовый файл для вывода результатов}
   Tmp:string;         {временная текстовая переменная}
   Fname: string;      {Имя файла}
 
{Вероятностные процедуры}
function random_:real; {процедура нахождения случайного числа }
begin
random_:= random(65535)/(65535-1); {вычисление случайного числа}
end;
 
function flip(probability:real):boolean; {функция ->подбрасывание монетки - true если орел}
begin
if probability = 1.0 then
flip := true
else
flip :=(random_<= probability);
end;
 
function rnd(low,high:integer):integer; {Функция  - >  случайный выбор между low и high}
 var
   i:integer;
begin
   if low >= high then
   i := low
else begin
   i := trunc( random_ * (high-low+1) + low); {преобразование  вещественного числа в целое}
   if i > high then i := high;
end;
   rnd := i;
end;
 
{интерфейсные процедуры: decode and objfunc}
 
function objfunc(x:fenotype):real;
begin
 objfunc:= int(x[1])+int(x[2]);  {исходная функция двух переменных}
end;
 
procedure decode(chrom:chromosome; lbits:integer; var x:fenotype);
{Процедура декодирования строки в массив вещественных
 координат точки в пространстве поиска - true=1, false=0}
var
  i,j:integer;
  f, accum, powerof2:real;
begin
for i:=1 to dim do begin
  accum :=0.0; {инициализация переменной для подсчета сумма}
  powerof2 := 1; {инициализация переменной для подсчета произведения}
  f:=1;
for j := 1+lbits*(i-1) to lbits+lbits*(i-1) do begin
 if chrom[j] then accum := accum + powerof2;
  powerof2 := powerof2 * 2;
  f:=f*2;
end;
  x[i] := xmin[i]+(xmax[i]-xmin[i])*accum/(f-1); {выходной массив с координатами x}
end ;
end;
 
{Расчет статистических величин: statistics}
procedure statistics(popsize:integer;var max,avg,min,sumfitness:real;
                     var pop:population);
 {Расчет статистик популяции}
var
   j:integer;
begin
{Инициализация}
   sumfitness := pop[1].fitness;
   min := pop[1].fitness;
   max := pop[1].fitness;
   {Цикл для max, min, sumfitness }
   for j := 2 to popsize do with pop[j] do begin
   sumfitness := sumfitness + fitness;
   {Накопление суммы значений функции пригодности}
   if fitness>max then max := fitness;
   {Новое значение max}
   if fitness<min then min := fitness;
   {Новое значение min}
end;
   {Расчет среднего}
   avg := sumfitness/popsize;
end;
 
{Процедура инициализации initpop}
procedure initpop;
{Инициализация начальной популяции случайным образом }
var
   j, j1:integer;
begin
   for j := 1 to popsize do with oldpop[j] do begin
   for  j1  :=  1 to lchrom*dim do chrom[j1]:=flip(0.5);
   {Бросок монетки}
   decode(chrom,lchrom,x);
   {Декодирование строки}
   fitness := objfunc(x);
   {Вычисление  начальных  значений   функции пригодности}
   end;
end;
 
 {3 генетических оператора: отбора (select), скрещивания (crossover) и мутации (mutation)}
procedure select;   {процедура выбора}
var
 ipick:integer;
procedure shuffle(var pop:population); {процедура перемешивания популяции в процессе отбора}
var
  i,j:integer;   {переменные цикла}
  ind0:individual;
begin
for i:= popsize downto 2 do begin
  j:= random(i-1)+1;
  ind0:=pop[i];
  pop[i]:=pop[j];
  pop[j]:=ind0;
 end;
end;
 
function select_1:integer;
var
 j1,j2,m:integer;
begin
 if (ipick>popsize) then begin
 shuffle(oldpop);
 ipick:=1
end;
 j1:=ipick;
 j2:=ipick+1;
 if (oldpop[j2].fitness<oldpop[j1].fitness) then
 m:=j2
else
 m:=j1;
 ipick:=ipick+2;
 select_1:=m;
end;
var
 j:integer; {переменная  цикла}
begin
 ipick:=1;
for j:=1 to popsize do begin
 intpop[j]:=oldpop[select_1];
end;
 oldpop:=intpop;
end;
 
function mutation (alleleval:allele; pmutation:real;
var nmutation:integer):allele;
{мутация одного бита в строке (аллеля) с вероятностью pmutation}
{подсчет числа мутаций}
var
 mutate:boolean; {логический тип данных True=1,False=0}
begin
 mutate := flip(pmutation); {имитация мутации с вероятностью pmutation}
 if mutate then begin {true если орел} {если мутация произошла}
 nmutation := nmutation + 1;  {увеличиваем счетчик мутаций на 1}
 mutation := not alleleval; {Изменение  битового значения}
end else
 mutation := alleleval; {Нет изменения битового значения}
end;
 
procedure crossover(var parent1, parent2, child1, child2:chromosome;
flchrom:integer; var ncross, nmutation, jcross:integer;
var pcross, pmutation:real); {Процедура скрещивания 2 родительских строк, результат помещается в 2 строках-потомках}
{вещественные переменные вероятности скрещивания и мутации}
 
var
j:integer;  {переменная  цикла}
begin
if flip(pcross) then begin  {Выполняется скрещивание с вероятностью pcross}
jcross := rnd(1,flchrom-1); {Определение точки сечения в диапазоне между 1 и L -1}
 
ncross := ncross + 1;  {Инкрементирование счетчика скрещиваний}
end else
  jcross := flchrom;
  {певая часть обмена обмена, 1 to 1 and 2 to 2 }
  for j := 1 to jcross do begin
   child1[j] := mutation(parent1[j], pmutation, nmutation);
   child2[j] := mutation(parent2[j], pmutation, nmutation);
  end;
  {вторая часть обмена, 1 to 2 and 2 to 1 ]
  if jcross<>flchrom then
  {пропуск, если точка скрещивания равна flchrom--
          скрещивание не происходит}
  for j := jcross+1 to flchrom do begin
   child1[j] := mutation(parent2[j], pmutation, nmutation);
   child2[j] := mutation(parent1[j], pmutation, nmutation);
   end;
end;
{Процедура создания нового поколения: generation}
procedure generation;
{Генерирование нового поколения при помощи отбора, скрещивания и мутации}
{Прим: предполагается, что популяция имеет четный размер}
var
 j,mate1, mate2,jcross:integer;{переменные целого типа, отвечающие за выбор родительской пары}
begin
 select;
 j := 1;
repeat  {выполняются отбор, скрещивание и мутация, пока полностью не сформируется новая популяция - newpop}
 mate1:= j; {выбор родительской пары}
 mate2:= j+1;
 {скрещивание и мутация - мутация вставлена в процедуру скрещивания}
 crossover(oldpop[mate1].chrom, oldpop[mate2].chrom,newpop[j ].chrom, newpop[j+1].
 chrom,lchrom*dim, ncross, nmutation, jcross, pcross, pmutation); {Декодирование строки и вычисление пригодности}
with newpop[j] do begin
 decode(chrom, lchrom,x);   {Декодирование хромосомной последовательности}
 fitness := objfunc(x);     { вычисление пригодности}
end;
with newpop[j+1] do begin
 decode(chrom, lchrom,x);   {Декодирование хромосомной последовательности}
 fitness := objfunc(x);     { вычисление пригодности}
end;
 j := j + 2;
until j>popsize
end;
 
begin {Главная программа}
 BEGIN
clrscr;
 Write('Введите количество повторов программы ');
 Readln(Povtor);
 Writeln;Writeln;
For h:=1 to 2 do begin {Выбор количества поколений}
 case h of
 1 : psize:=40; {Количество поколений}
 2:  psize:=80;
 end;
 for s:=1 to 3 do begin
  Case s of
  1: razpop:=8; {Размеры популяций}
  2: razpop:=12;
  3: razpop:=20;
 end;
  {Формирование имени файла}
   Str(psize,Tmp);
   Str(razpop,Tmp);
   Fname:=Fname+'-'+Tmp+'.txt';
   Otv:=0; {Инициализация переменной ответа}
   Writeln('Поиск минимума: Размер популяции ',razpop:2,' Количество поколений ', psize:2 );
   {открытие файла для вывода результатов}
   Assign(FRes,FName);   Rewrite(FRes);
   Writeln(FRes,'Поиск минимума: Размер популяции ',razpop:2,' Количество поколений ', psize:2 );
  For b:=1 to Povtor do begin {Программа прогоняется Povtor раз для более точного ответа ответа}
   popsize:=razpop; {размер популяции}
   lchrom:=20; {число битов на один кодируемый параметр. Каждая переменная кодируется 20 битами}
   maxgen:=psize; {максимальное число поколений}
   pmutation:=0.01; {вероятность скрещивания}
   pcross:=0.9; {вероятность мутации}
   randomize;{Инициализация генератора случайных чисел}
   nmutation := 0; {Инициализация счетчика мутаций}
   ncross := 0; {Инициализация счетчика количества скрещиваний}
   initpop;    {Инициализация популяции}
   statistics(popsize, max, avg, min, sumfitness, oldpop);
   gen := 0; {Установка счетчика поколений в 0}
   
         if b=1 then mmin:=min;
         
  repeat {Главный итерационный цикл}
   gen := gen + 1;  {инкрементация счетчика поколений}
   generation;  {создания нового поколения}
   statistics(popsize,  max,  avg,  min,  sumfitness, newpop);
   Writeln(Fres, 'N=',b:3,' Минимум функции= ',min:10:4);
   oldpop := newpop; {переход на новое поколение }
   until (gen >= maxgen);
   Otv:=Otv+min;
   
   if mmin>min then mmin:=min;
 
             
  end;{End циклов основной программы}
   Otvet:=Otv/Povtor;{Находим среднее значение ответа.}
   Writeln('Средний минимум функции  ',otvet:10:4);
   Writeln(FRes,'Средний минимум функции ',otvet:10:4);
   
    writeln('Лучшее значение функции=',mmin);
    
   writeln;
   Otv:=0; {Очищаем переменную}
   Close(FRes);
  End;{End цикла выбора количества популяций}
  End; {End цикла выбора количества поколений}
   Readln;
 End;
End. {Конец Главной программы)