Русский Post запрос в базу через http

'************************************************************************************
'********Набор функций для кодирования русских символов для передачи в скрипт php****
'************************************************************************************
Public Function URLEncode(url As String) As String
    URLEncode = URLEncodeByUTF8(EncodeUTF8(url))
End Function
 
Public Function URLEncodeByUTF8(sRawURL As String) As String
On Error GoTo Catch
Dim iLoop As Integer
Dim sRtn As String
Dim sTmp As String
Const sValidChars = "1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz:/.?=_-$(){}~&"
 
    If Len(sRawURL) > 0 Then
        For iLoop = 1 To Len(sRawURL)
            sTmp = Mid(sRawURL, iLoop, 1)
            If InStr(1, sValidChars, sTmp, vbBinaryCompare) = 0 Then
                ' If not ValidChar, convert to HEX and prefix with %
                sTmp = Hex(Asc(sTmp))
                If sTmp = "20" Then
                    sTmp = "+"
                ElseIf Len(sTmp) = 1 Then
                    sTmp = "%0" & sTmp
                Else
                    sTmp = "%" & sTmp
                End If
            End If
            sRtn = sRtn & sTmp
        Next iLoop
        URLEncodeByUTF8 = sRtn
     End If
Finally:
     Exit Function
Catch:
     URLEncodeByUTF8 = ""
     Resume Finally
End Function
 
Function ToLong(intVal) As Long
    If intVal < 0 Then
        ToLong = CLng(intVal) + &H10000
    Else
        ToLong = CLng(intVal)
    End If
End Function
 
'кодируем символы в UTF-8
Function EncodeUTF8(s$) As String
Dim i, c, utfc, b1, b2, b3
    For i = 1 To Len(s)
        c = ToLong(AscW(Mid(s, i, 1)))
 
        If c < 128 Then
            utfc = Chr(c)
        ElseIf c < 2048 Then
            b1 = c Mod &H40
            b2 = (c - b1) / &H40
            utfc = Chr(&HC0 + b2) & Chr(&H80 + b1)
        ElseIf c < 65536 And (c < 55296 Or c > 57343) Then
            b1 = c Mod &H40
            b2 = ((c - b1) / &H40) Mod &H40
            b3 = (c - b1 - (&H40 * b2)) / &H1000
            utfc = Chr(&HE0 + b3) & Chr(&H80 + b2) & Chr(&H80 + b1)
        Else
            utfc = Chr(&HEF) & Chr(&HBF) & Chr(&HBD) 'Младший или старший суррогат UTF-16
        End If
 
        EncodeUTF8 = EncodeUTF8 + utfc
    Next
End Function
'************************************************************************************
'************************************************************************************