Копирование\вставка текста в\из буфер обмена DOS??? (На Ассемблере)

;------------------------------------------------------------------;
; Работа с буфером обмена Windows 98 из сеанса MS-DOS              ;
; на фоне графического экрана и управления мыщью                   ;
; Th: http://www.frolov-lib.ru/books/bsp/v06/ch7_3.htm             ;
; Левая кнопка мыши - ставит точку и разрешает запись              ;
; в буфер обмена.                                                  ;
; Левая кнопка мыши - в правом верхнем углу 32 х 32 :              ;
; выход из программы.                                              ;
; Правая кнопка мыши - запись в буфер обмена Windows               ;
; Клавиша пробел - выход из программы.                             ;
; Любая клавиша  - запись в буфер обмена Windows                   ;
; Запись в буфер обмена Windows блокирует повторную                ;
; запись сразу же, Левая кнопка мыши снимает блок.                 ;
; Из Windows тестировать буфер обмена лучше так:                   ;
; http://vsokovikov.narod.ru/New_MSDN_API/Clipboard/add_win_cb.htm ;
;------------------------------------------------------------------;
 
 .model tiny
 .code
SEG_A           SEGMENT BYTE PUBLIC
                ASSUME  CS:SEG_A, DS:SEG_A, ES:SEG_A
 
  org  100h
 .186                    
start:
  jmp  begin
Clipbd_mess        db       "ABCD",0,0 ; строка - в буфер обмена
press_key          dw       0          ; предыдущее нажатие
 
begin:
  mov  ax,10h;инициализация гр. режима
  int  10h
  mov  ax,0  ;инициализация мыши
  int  33h
seti:
  mov  ax,1  ; показать курсор
  int  33h
 
  mov  ax,000ch  ; Установка обработки щелчка
  mov  cx,000ch  ; 0000.0010b - нажатие левой кнопки
                 ; 0000.0100b - отпускание левой кнопки
                 ; 0000.1000b - нажатие правой кнопки
                 ; 0001.0000b - отпускание правой кнопки
  mov  dx,offset mouse_click ; ES:DX - адрес обработчика
  int  33h
 
  mov  ah,0  ; Ожидание ввода символа
  int  16h   ; AL = ASCII символ, AH = Сканкод  или Расширенный код ASCII
 
  push ax
  mov  ax,000ch  ; Отменить обработчик
  mov  cx,0000h
  int  33h
 
  mov  al,'.'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  cmp  al,20h; пробел, или клик в правом углу 32х32
  jnz  clbd
  jmp  exit
 
clbd:
  mov  ax,CS:WORD PTR press_key
  cmp  ax,0ffffh
  jz   seti
askc:
  push ax
  mov  al,'>'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
tsit:
  mov  ax,1700h; Проверяем доступность CLIPBOARD.
  int  2Fh
  cmp  ax,1700h; Clipboard недоступна
  jnz  opkb
erro:
  push ax
  mov  al,'_'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  jmp  quit
 
opkb:
  push ax
  and  al,0fh
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  push ax
  mov  al,'@'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  mov  ax,1701h; Открываем CLIPBOARD
  int  2Fh
  or   ax,ax;    Ошибка при открытии Clipboard
  jz   erro
 
  push ax
  and  al,0fh
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  push ax
  mov  al,'w'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  mov  ax,1702h; Очищаем CLIPBOARD
  int  2Fh
 
  push cs
  pop  es
  mov  bx,offset Clipbd_mess ; ES:BX - Указатель на записываемые данные
  mov  si,0
  mov  cx,5; SI:CX - Длина записываемых данных
  mov  dx,1; текст - Формат данных, записываемых в CLIPBOARD:
  mov  ax,1703h; запись данных в WINDOWS CLIPBOARD.
  int  2Fh
  or   ax,ax; Ошибка при открытии Clipboard
  jz   erro
 
  push ax
  and  al,0fh
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  push ax
  mov  al,'c'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  mov  ax,1708h; Закрыть CLIPBOARD
  int  2Fh
  or   ax,ax;    Ошибка при Закрытии Clipboard
  jnz  fin
  jmp  erro
fin:
  push ax
  and  al,0fh
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  mov  ax,0ffffh
  mov  CS:WORD PTR press_key,ax
 
  push ax
  mov  al,'#'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  mov  al,10
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  mov  al,13
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  jmp  seti
 
exit:
  mov  ax,3  ; возврат в текстовый режим
  int  10h
 
  INT  20H   ; возврат в систему
 
mouse_click:
  push ax
  mov  ax,2  ; спрятать курсор
  int  33h
  pop  ax
 
; На входе в прерывание:
; AX contains a bit mask identifying which event has occurred;
; СХ = Х-координата
; DX = Y-координата
;  jmp  tyta
  push dx
  push cx
  push ax
  and  al,0fh
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  push ax
  and  al,0f0h
  shr  al,4
  add  al,30h
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
  pop  cx
  pop  dx
 
  test al,08h; - нажатие правой кнопки ()
  jnz  there ; бит 0000.1000b установлен
 
  cmp  dx,20h
  jnc  rdot
  cmp  cx,20h
  jnc  rdot
 
here:
  mov  cl,20h; имитация [Пробел]
  mov  ch,39h
  mov  ah,05h;Поместить код клавиши в буфер клавиатуры.
  int  16h
  jmp  quit
 
there:
  mov  cl,0dh; имитация [Enter]
  mov  ch,1Ch
  mov  ah,05h;Поместить код клавиши в буфер клавиатуры.
  int  16h
  jmp  quit
 
; 0 ¦ Black       ¦ 8  ¦ Gray
; 1 ¦ Blue        ¦ 9  ¦ Bright Blue
; 2 ¦ Green       ¦ 10 ¦ Bright Green
; 3 ¦ Cyan        ¦ 11 ¦ Bright Cyan
; 4 ¦ Red         ¦ 12 ¦ Bright Red
; 5 ¦ Magenta     ¦ 13 ¦ Bright Magenta
; 6 ¦ Brown       ¦ 14 ¦ Bright Yellow
; 7 ¦ White       ¦ 15 ¦ Bright White
 
rdot:
  mov  al,0ch; цвет
sdot:
; DX,CX = строка,колонка
  mov  ah,0ch; вывести точку
  int  10h
 
  mov  ax,0000h
  mov  CS:WORD PTR press_key,ax
 
  push ax
  mov  al,'~'
  mov  bl,0CH
  mov  ah,0eh
  mov  cx,1
  int  10h
  pop  ax
 
  mov  ax,1  ; показать курсор
  int  33h
quit:
  retf  ;Обработчик событий должен быть оформлен как дальняя процедура
;===============================
SEG_A           ENDS
                END     START