Ввести с клавиатуры строку, состоящую из целых чисел, разделенных пробелами. Найти минимальное число и вывести на экран

@cinekst_207 · Регистрация: 25.03.2018

Студворк — интернет-сервис помощи студентам

Я вроде чё-то понял, но вроде и нет

. Можете подсказать, где и что не так? А то не понимаю, что не так. Вот например при вызове INT 21h у меня нет никакого ввода, я тыкаю, а ничего не вводится.
Вот код:

Assembler

.model SMALL
.386
 
STACK 100h
 
DATASEG
 
BUF     dB 11        
ENTERED dB (?)        
STRING  dB 11 dup (?) 
FIRST   dB 0
MIN     dD ?
NEGATI  dB 0
 
CODESEG 
    START: 
 
STARTUPCODE 
    
    LEA DX, BUF 
    MOV AL, 0Ah 
    INT     21h 
    MOV CX, 11
    MOV BX, 10
    MOV AX, 0
    MOV EAX,0
    
    COMPARE:
        LODSB
        CMP   AL, '-'
        JZ    NEGAT
        
        CICLE:  
            YES:
                CMP AL, ' '
                JZ SPACE
                
                CMP AL, '0'
                JZ COM0
                
                CMP AL, '1'
                JZ COM1
                
                CMP AL, '2'
                JZ COM2
                
                CMP AL, '3'
                JZ COM3
                
                CMP AL, '4'
                JZ COM4
                
                CMP AL, '5'
                JZ COM5
                
                CMP AL, '6'
                JZ COM6
                
                CMP AL, '7'
                JZ COM7
                
                CMP AL, '8'
                JZ COM8
                
                CMP AL, '9'
                JZ COM9
        
                NO: 
                    JCXZ SPACE
                    LODSB
                    LOOP YES
                COM0:
                    MUL BX
                    JMP NO
                EX:
                    JCXZ QUIT
                    LOOP COMPARE
                COM1:
                    MUL BX
                    ADD EAX, 1
                    JMP NO
                COM2:
                    MUL BX
                    ADD EAX, 2
                    JMP NO
                COM3:
                    MUL BX
                    ADD EAX, 3
                    JMP NO
                COM4:
                    MUL BX
                    ADD AX, 4
                    JMP NO
                COM5:
                    MUL BX
                    ADD EAX, 5
                    JMP NO
                COM6:
                    MUL BX
                    ADD EAX, 6
                    JMP NO
                COM7:
                    MUL BX
                    ADD EAX, 7
                    JMP NO
                COM8:
                    MUL BX
                    ADD EAX, 8
                    JMP NO
                COM9:
                    MUL BX
                    ADD EAX, 9
                    JMP NO
                SPACE:
                    CMP NEGATI, 1
                    JNZ POS
                    NEG EAX
                    SUB NEGATI, 1
                    
                    POS:
                        CMP FIRST, 1
                        JS  GO
                        CMP MIN, EAX
                        JB  GO
                        JMP EX
                        
                        GO:
                            MOV MIN, EAX
                            JMP EX
                            
    NEGAT:
        ADD NEGATI, 1
        JMP CICLE
        
    QUIT: 
        LEA DX, MIN
        MOV AH, 09h
        INT     21h
        
        EXITCODE 0 
 
END START

Коротко о блоках: YES - блок сравнения кода символа с числами; NO - блок продолжения считывания числа; EX - блок, вызываемый в том случае, если мы дошли до конца числа; COM0...9 - блоки соответсвенно присваивания числа к регистру EAX; SPACE/POS/GO - блоки проверок чисел, минимальны-ли они; NEGAT - если попался код минуса, то число отрицательное, и мы делаем некий флаг; ну с QUIT думаю всё понятно

. Заранее спасибо. Я новичок, где-то 2 недели учу его.

ФедосеевПавел · 25.03.2018, 23:53

Вот куда вводили - там символы и находятся - в буфере Buf, но не с самого начала, а по смещению
Смотрите по ссылке формат структуры (записи) буфера http://www.codenet.ru/progr/dos/dos_0018.php

При начале обработки нужно настроить указатели на начало строки
Смотрите описание lodsb https://www.cyberforum.ru/post5516354.html

Такой case для выделения цифры можно не делать. Достаточно убедиться, что al в диапазоне символов '0'...'9' и вычесть из al код символа '0', а потом и умножение со сложением.

@cinekst_207 · 26.03.2018, 00:48 **[ТС]**

Ухты, спасибо, сейчас почитаю (:

@cinekst_207 · 27.03.2018, 21:50 **[ТС]**

Assembler

.model SMALL
.386
 
STACK 100h
 
DATASEG
 
BUF     dB 11         ;Первый байт буфера
ENTERED dB (?)        ;Число введенных символов
STRING  dB 11 dup (?) ;Введенные символы
FIRST   dB 0
MIN     dW ?
NEGATI  dB 0
 
CODESEG 
    START: 
 
STARTUPCODE 
    
    CLD
    LEA DX, BUF ;Адрес буфера - в DX
    MOV AL, 0Ah ;Номер функции - в AL
    INT     21h ;Вызов функции
    MOV CX, 10
    MOV BL, 10
    
    COMPARE:
        LODSB
        CMP AL, '-'
        JZ    NEGAT
        
        CICLE:  
            YES:
                CMP AL, ' '
                JZ SPACE
                
                SUB AL, '0'
                MUL BL
                LODSB
                LOOP YES
                
                EX:
                    JCXZ QUIT
                    LOOP COMPARE
                SPACE:
                    CMP NEGATI, 1
                    JNZ POS
                    NEG AX
                    SUB NEGATI, 1
                    
                    POS:
                        CMP FIRST, 1
                        JS  GO
                        CMP MIN, AX
                        JB  GO
                        JNA NEA
                    
                        GO:
                            MOV MIN, AX
                            JMP EX
                            
                        NEA:
                            JMP EX
                            
    NEGAT:
        ADD NEGATI, 1
        JMP CICLE
        
    QUIT: 
        LEA DX, MIN
        MOV AL, 09h
        INT     21h
        
        EXITCODE 0 
 
END START

___________________________________
Ну хотя-бы строк меньше, но ещё надо что-то подправить... Спасибо кстати.

ФедосеевПавел · 27.03.2018, 22:17

lodsb - согласно непрочтёной документации выполняет 2 операции 1) [ds:si] -> al, 2) si:=si+1
Где в программе настройка si на буфер?

Ну и преобразование символов в число. Где находится текущее число?

Вы бы набрали алгоритм преобразования символов строки в число в виде программы на C/Pascal. И сразу станет легче. Останется лишь преобразовать строки Pascal в ассемблер.

Добавлено через 1 минуту
Номер функции чтения буфера в AH - а не в AL.

@R71MT · 27.03.2018, 22:45

Зачем сохранять в буфер, проверяй на-лету:

Assembler

;fasm-code
;--------------
org   100h
jmp   start
 
m0     db   13,10,'Data: $'
m1     db   13,10,' Min: $'
 
start: mov  ah,9
       mov  dx,m0
       int  21h
       mov  bl,'9'    ;//текущий минимум
@01:   xor  ax,ax
       int  16h
       cmp  al,13     ;//Enter - закончить ввод
       je   @prn
       cmp  al,'0'    ;//фильтр чисел
       jb   @01
       cmp  al,'9'
       ja   @01
       cmp  al,bl     ;//сравнить ввод с текущим мин.
       ja   @02
       mov  bl,al     ;//запомнить, если меньше
@02:   int  29h
       jmp  @01
 
@prn:  mov  ah,9
       mov  dx,m1
       int  21h
       mov  al,bl     ;//вывести мин. на экран
       int  29h
 
       mov  ah,8      ;
       int  21h
       ret            ;//выход!

ФедосеевПавел · 27.03.2018, 22:51

R71MT, если преподаватель ему предлагает ввести строку и обработать её, то выбор "на лету" не даст зачёта.

Другое дело, что "на лету" отличается от обработки строки лишь способом доступа к следующему символу.

@R71MT · 28.03.2018, 06:17

Сообщение от ФедосеевПавел

и обработать её

Сообщение от cinekst_207

Ввести с клавиатуры строку, состоящую из целых чисел, разделенных пробелами. Найти минимальное число и вывести на экран - Assembler/TASM

..что-то не вижу тут слова "обработать"

@cinekst_207 · 28.03.2018, 22:27 **[ТС]**

Assembler

.model SMALL
.386
 
STACK 100h
 
DATASEG
 
BUF     dB 11           ;Первый байт буфера
ENTERED dB(?)           ;Число введенных символов
STRING  dB 11 dup (?)   ;Введенные символы
FIRST   dB 0
MIN     dW ?
NEGATI  dB 0
 
CODESEG 
    START: 
 
STARTUPCODE 
    
    LEA DX, BUF         ;Адрес буфера - в DX
    MOV AH, 0Ah         ;Номер функции - в AH
    INT     21h         ;Вызов функции
    MOV BL, 10
    MOV CX, BUF
    
    CLD
    LEA SI, BUF
    
    COMPARE:
        LODSB
        CMP AL, '-'
        JZ    NEGAT
        
        CICLE:  
            YES:
                CMP AL, ' '
                JZ SPACE
                
                SUB AL, '0'
                MUL BL
                LODSB
                LOOP YES
                
                EX:
                    JCXZ QUIT
                    LODSB
                    LOOP COMPARE
                SPACE:
                    CMP NEGATI, 1
                    JNZ POS
                    NEG AX
                    SUB NEGATI, 1
                    
                    POS:
                        CMP FIRST, 1
                        JS  GO
                        CMP MIN, AX
                        JB  GO
                        JMP EX
                    
                        GO:
                            MOV MIN, AX
                            JMP EX
                            
    NEGAT:
        ADD NEGATI, 1
        JMP CICLE
        
    QUIT: 
        LEA DX, MIN
        MOV AL, 09h
        INT     21h
        
        EXITCODE 0 
 
END START

Вот, что получилось, только вопрос, если символ в AL передаёт, то вот при вводе например "-12 12" у меня в AL ничего на - похожего не находит и дёт дальше

Добавлено через 18 минут
Я исправил LEA SI, BUFER + 2, теперь другая проблема, в общем результат MUL BL по идее должен сохранять в AX, я туда захожу, а там ничего нет

Добавлено через 16 минут
У меня при LODSB изменяет AL и AX.

ФедосеевПавел · 28.03.2018, 22:32

Вы какой язык учили? Pascal?
Структура буфера

Pascal

type
  TKeyBuffer = record
    MaxLen: byte;
    ActualLen: byte;
    Chars: array of char;
  end;
var
  BUF: TKeyBuffer;

И вот при попытке обратиться к первому символу строки вы в si записываете адрес BUF. Вопрос, что загрузит в al самый первый вызов lodsb?

Добавлено через 1 минуту
Пока набирал - вы исправили.

@cinekst_207 · 28.03.2018, 22:34 **[ТС]**

А что с LODSB'ом делать? неужели придётся старыми добрыми адресами пользоваться? или можно как-то исправить?

ФедосеевПавел · 28.03.2018, 22:48

И длину в CX нужно брать по BUF+1. Обнулить CX, загрузить CL из BUF+1

Добавлено через 11 минут

Pascal

si := @(BUF+2);
di := 0; // текущее число
MIN := 0; // минимальное число
FIRST := true;
for cx:=(BUF+1) to 1 do
begin
  al := si^; // lodsb
  inc(si);
 
  if al='-' then
  begin
    NEGATI:=true;
    continue;
  end;
  if al in ['0'..'9'] then
  begin
    al := al- '0';
    di:=di*10;
    di:=di+al;
    continue;
  end;
  if al = ' ' then
  begin
    if FIRST then
      MIN := di
    else
      MIN := min (di, MIN)
  end;
end;

Что-то такое должно получиться. Только учтите, что при умножении ВСЕГДА используется регистр al/ax и dx.

Добавлено через 1 минуту
Единственно, нужно учесть, что по окончанию цикла может остаться необработанное число.

@cinekst_207 · 29.03.2018, 00:17 **[ТС]**

Не могли бы вы просто подправить код? Пожалуйста (: Завтра лаба, а у меня ошибки в DX(он не воспринимает числа 1...2) и вроде всё, все ошибки, ну с выводом я попытаюсь сам справиться:

Assembler

.model SMALL
.386
 
STACK 100h
 
DATASEG
 
BUF     dB 11           ;Первый байт буфера
ENTERED dB(?)           ;Число введенных символов
STRING  dB 11 dup (?)   ;Введенные символы
FIRST   dB 0
MIN     dW ?
NEGATI  dB 0
COMP    dW 0
 
CODESEG 
    START: 
 
STARTUPCODE 
    
    LEA DX, BUF         ;Адрес буфера - в DX
    MOV AH, 0Ah         ;Номер функции - в AH
    INT     21h         ;Вызов функции
    MOV BL, 10
    MOV CL, 10
    
    CLD
    LEA SI, BUF + 2
    
    COMPARE:
        LODSB
        CMP AL, 0Dh
        JZ SPACE
        CMP AL, '-'
        JZ    NEGAT
        
        CICLE:  
            YES:
                CMP AL, 0Dh
                JZ SPACE
                CMP AL, ' '
                JZ SPACE
                
                SUB AL, '0'
                MUL BL
                ADD DX, AX
                LODSB
                LOOP YES
                
                EX:
                    MOV DX, 0
                    LOOP COMPARE
                SPACE:
                    CMP NEGATI, 1
                    JNZ POS
                    NEG DX
                    SUB NEGATI, 1
                    
                    POS:
                        CMP FIRST, 1
                        JS  SUBIK
                        CMP MIN, DX
                        JB  GO
                        JMP EX
                    
                        SUBIK:
                            SUB FIRST, 1
                    
                        GO: 
                            MOV MIN, DX
                            JMP EX
                            
    NEGAT:
        ADD NEGATI, 1
        LODSB
        JMP CICLE
        
    QUIT: 
        LEA DX, MIN
        MOV AL, 09h
        INT     21h
        
        EXITCODE 0 
 
END START

Добавлено через 2 минуты
Я очень туго воспринимаю ассемблер, сразу извинияюсь, что задалбываю так долго, но просто мне нужен конкретный пример, тогда я буду понимать. А вот вы скинули про losdb - более-менее понял

Добавлено через 36 минут
ФедосеевПавел, просто не могу понять, как так умножать, чтоб AX не изменялось. Я DX поставил и туда присваивать начал, но потом понял, что тщетно

ФедосеевПавел · 29.03.2018, 00:25

Дальше самостоятельно

Assembler

LOCALS
 
.model small
 
.stack 100h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
        BUF             db      80           ;Первый байт буфера
        ENTERED         db      (?)           ;Число введенных символов
        STRING          db      80 dup (?)   ;Введенные символы
        FIRST           db      1
        MIN             dw      ?
        NEGATI          db      0
 
 
.code
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;ввод строки
        mov     ah,     0Ah
        lea     dx,     [BUF]
        int     21h
 
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
 
        xor     cx,     cx
        mov     cl,     [ENTERED]
        lea     si,     [STRING]
        cld
 
        mov     di,     0
        mov     bx,     10
        jcxz    @@Exit
        @@For:
                lodsb
        @@case0:
                cmp     al,     '-'
                jne     @@case1
                mov     [NEGATI],       1
                jmp     @@Next
        @@case1:
                cmp     al,     '0'
                jb      @@case2
                cmp     al,     '9'
                ja      @@case2
 
                xor     ah,     ah
                sub     al,     '0'
                xchg    ax,     di
                mul     bx
                add     di,     ax
 
                cmp     cx,     1
                je      @@ReadyNum
                jmp     @@Next
        @@case2:
                cmp     al,     ' '
                jne     @@Next
 
        @@ReadyNum:
                cmp     [NEGATI],       1
                jne     @@1
                neg     di
        @@1:
                cmp     [First],        0
                je      @@2
                mov     [MIN],  di
                mov     [First],        0
        @@2:
                cmp     di,     [MIN]
                jge     @@Prepare
                mov     [MIN],  di
                ;подготовка к новому вводу числа
        @@Prepare:
                mov     di,     0
                mov     [NEGATI],       0
 
        @@Next:
        loop    @@For
 
        ;вывод результата
        mov     ax,     [MIN]
        call    Show_AX
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
@@Exit:
        mov     ax,     4C00h
        int     21h
main    endp
 
NewLine proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
NewLine endp
 
; выводит знаковое 16-разрядное число из регистра AX на экран
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    di
 
        mov     cx,     10
        xor     di,     di      ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax,     ax
        jns     @@Conv
        push    ax
        mov     dx,     '-'
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx,     dx
        div     cx              ; dl = num mod 10
        add     dl,     '0'     ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стек
        or      ax,     ax
        jnz     @@Conv
        ; выводим из стека на экран
@@Show:
        pop     dx              ; dl = очередной выводимый символ
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
 
end     main

@cinekst_207 · 29.03.2018, 00:30 **[ТС]**

Вооооу, сколько строк. Но команды знакомые, попытаюсь понять. Спасибо большое. Чувствую летом меня не только плюсы ждут

ФедосеевПавел · 29.03.2018, 00:32

Вывод с пояснениями в закреплённой теме. Смотрите там.
Если не сохранять регистры - при выводе всего 10 строчек кода.

@cinekst_207 7 / 7 / 5 Регистрация: 25.03.2018 Сообщений: 377
	29.03.2018, 00:30 [ТС]	15
	Вооооу, сколько строк. Но команды знакомые, попытаюсь понять. Спасибо большое. Чувствую летом меня не только плюсы ждут 0

ФедосеевПавел Модератор 8392 / 4268 / 1624 Регистрация: 01.02.2015 Сообщений: 13,289 Записей в блоге: 5
	25.03.2018, 23:53	2
	Вот куда вводили - там символы и находятся - в буфере Buf, но не с самого начала, а по смещению Смотрите по ссылке формат структуры (записи) буфера http://www.codenet.ru/progr/dos/dos_0018.php При начале обработки нужно настроить указатели на начало строки Смотрите описание lodsb https://www.cyberforum.ru/post5516354.html Такой case для выделения цифры можно не делать. Достаточно убедиться, что al в диапазоне символов '0'...'9' и вычесть из al код символа '0', а потом и умножение со сложением. 1

@cinekst_207 7 / 7 / 5 Регистрация: 25.03.2018 Сообщений: 377
	26.03.2018, 00:48 [ТС]	3
	Ухты, спасибо, сейчас почитаю (: 0

ФедосеевПавел Модератор 8392 / 4268 / 1624 Регистрация: 01.02.2015 Сообщений: 13,289 Записей в блоге: 5
	27.03.2018, 22:17	5
	lodsb - согласно непрочтёной документации выполняет 2 операции 1) `[ds:si] -> al`, 2) `si:=si+1` Где в программе настройка si на буфер? Ну и преобразование символов в число. Где находится текущее число? Вы бы набрали алгоритм преобразования символов строки в число в виде программы на C/Pascal. И сразу станет легче. Останется лишь преобразовать строки Pascal в ассемблер. Добавлено через 1 минуту Номер функции чтения буфера в AH - а не в AL. 1

ФедосеевПавел Модератор 8392 / 4268 / 1624 Регистрация: 01.02.2015 Сообщений: 13,289 Записей в блоге: 5
	27.03.2018, 22:51	7
	R71MT, если преподаватель ему предлагает ввести строку и обработать её, то выбор "на лету" не даст зачёта. Другое дело, что "на лету" отличается от обработки строки лишь способом доступа к следующему символу. 1

@R71MT Эксперт Hardware 5750 / 2221 / 381 Регистрация: 29.07.2014 Сообщений: 3,036 Записей в блоге: 4
	28.03.2018, 06:17	8
	Сообщение от ФедосеевПавел и обработать её Сообщение от cinekst_207 Ввести с клавиатуры строку, состоящую из целых чисел, разделенных пробелами. Найти минимальное число и вывести на экран - Assembler/TASM ..что-то не вижу тут слова "обработать" 1

@cinekst_207 7 / 7 / 5 Регистрация: 25.03.2018 Сообщений: 377
	28.03.2018, 22:34 [ТС]	11
	А что с LODSB'ом делать? неужели придётся старыми добрыми адресами пользоваться? или можно как-то исправить? 0

ФедосеевПавел Модератор 8392 / 4268 / 1624 Регистрация: 01.02.2015 Сообщений: 13,289 Записей в блоге: 5
	29.03.2018, 00:32	16
	Вывод с пояснениями в закреплённой теме. Смотрите там. Если не сохранять регистры - при выводе всего 10 строчек кода. 0

Ввести с клавиатуры строку, состоящую из целых чисел, разделенных пробелами. Найти минимальное число и вывести на экран

Решение