Определить сумму 5 наименьших значений элементов массива целых чисел А[35]

.model tiny
 
.code
 
        org     100h
main    proc
 
        jmp     start
 
        ;Данные
        CrLf            db      0Dh, 0Ah, '$'
        msgSourceArray  db      'Source array: ', '$'
        msgResult       db      0Dh, 0Ah, 'Result: ', '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        SizeElement     equ     2
        A               dw      17, -5, 3, -12, 24, 78, 61, 73, -9, 13
        N               dw      ($-A)/SizeElement
        Sum             dw      ?
start:
        ;программа
 
        ;исходный массив
        mov     ah,     09h
        lea     dx,     [msgSourceArray]
        int     21h
        mov     cx,     [N]
        lea     dx,     [A]
        call    ShowArray
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        ;обработка массива
        ; - сортировка
        mov     cx,     [N]
        lea     si,     [A]
        call    BubbleSort
        ; - сумма 5 наименьших значений элементов массива
        mov     cx,     5
        lea     si,     [A]
        cld
        xor     bx,     bx
        @@ForSum:                               ;for (i=1; i<n; i++)
                lodsw
                add     bx,     ax              ;  Sum += A[i]
                call    ShowInt16
                mov     ah,     02h
                mov     dl,     ' '
                int     21h
        loop    @@ForSum
        mov     [Sum],  bx
        ;вывод результата
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        mov     ax,     [Sum]
        call    ShowInt16
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
        ;завершение программы
        int     20h
 
main    endp
 
;Сортировка "пузырьком" массива слов
;на входе
;  ds:si - адрес массива слов
;  cx    - длина массива
BubbleSort      proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     bx,     si
        mov     dx,     cx
        dec     dx
        shl     dx,     1               ;приведение dx=N к размерности элементов
        dec     cx                      ;for i:=1 to N-1 do
        mov     si,     0
@@ForI:
        mov     di,     dx              ;  j:=N
@@ForJ:                                 ;  repeat
        mov     ax,     [bx+di-2]       ;    (a[j] < and a[j - 1])
        cmp     ax,     [bx+di]
        jle     @@NextJ                 ;    if r<0 then
        xchg    ax,     [bx+di]         ;      temp:=a[j]
        xchg    ax,     [bx+di-2]       ;      a[j]:=a[j-1]
        xchg    ax,     [bx+di]         ;      a[j-1]:=a[j]
@@NextJ:
        sub     di,     2               ;    dec(j)
        cmp     di,     si              ;  until j<=i;
        ja      @@ForJ
        add     si,     2               ;  end; for i равноценно inc(i)
        loop    @@ForI
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
BubbleSort      endp
 
;Вывод массива слов (word)
;cx - количество выводимых элементов
;ds:dx - адрес массива слов
ShowArray       proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        jcxz    @@saExit        ;если массив пустой - завершить
 
        mov     si,     1       ;индекс элемента массива
        mov     di,     dx      ;адрес текущего элемента массива
        @@saForI:
                mov     ax,     [di]
                call    ShowInt16
                mov     ah,     02h
                mov     dl,     ' '
                int     21h
                ;переход к следующему элементу
                inc     si
                add     di,     SizeElement
        loop    @@saForI
@@saExit:
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
ShowArray       endp
 
ShowInt16       proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
        mov     bx,     10
        xor     cx,     cx      ;символов в модуле числа
        or      ax,     ax
        jns     @@div
                neg     ax
                push    ax
                mov     ah,     02h
                mov     dl,     '-'
                int     21h
                pop     ax
        @@div:
                xor     dx,     dx
                div     bx
                push    dx
                inc     cx      ;количество цифр в числе
                or      ax,     ax
        jnz     @@div
        mov     ah,     02h
        @@store:
                pop     dx
                add     dl,     '0'
                int     21h
        loop    @@store
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
ShowInt16       endp
 
end     main

        N equ 35 ;число элементов в массиве
 
        mov     ax, 32767 ;наибольшее возможное целое
        mov     dx, ax
        mov     si, ax
        mov     di, ax
        mov     bx, offset array
        mov     bp, [bx]
        mov     cx, N-1
cycl:   add     bx, 2
        cmp     [bx], ax
        jge     @@1
        mov     ax, [bx]
        cmp     ax, dx
        jge     @@1
        xchg    ax, dx
        cmp     dx, si
        jge     @@1
        xchg    dx, si
        cmp     si, di
        jge     @@1
        xchg    si, di
        cmp     di, bp
        jge     @@1
        xchg    di, bp
@@1:    loop    cycl
;итого ax dx si di bp - 5 наименьших элементов массива
; , среди которых ax - наибольший, а bp - наименьший
        add     ax, dx
        add     ax, si
        add     ax, di
        add     ax, bp