В матрице поменять местами строку, содержащую минимальный элемент, со строкой, содержащей максимальный элемент

@r0m1e · Регистрация: 26.09.2018

Студворк — интернет-сервис помощи студентам

В произвольной матрице [Aij] i=1, M , j=1, N поменять местами строку, содержащую минимальный элемент, со строкой, содержащей максимальный элемент.

Моя программа работает верно с матрицей 3*3 именно такой
1 2 3
4 5 6
7 8 9
->
7 8 9
4 5 6
1 2 3

Если пытаться подставлять числа в эту матрицу в другом порядке, возможно, выведет не то, что надо
Также программа не работает с другими матрицами 2*3 4*6 и так далее

Помогите, пожалуйста
Уже не знаю даже, что делать..

Assembler

title   laba
        assume  cs:c, ds:d, ss:s
 
s       segment stack
        dw      256 dup (?)
s       ends
 
        ;символы возврата каретки и перевода строки
        cr = 0dh
        lf = 0ah
 
d       segment
;A      dw      100 dup (?)
A       dw  9 dup (?)
N       dw      ?
M       dw      ?
mass    dw      9 dup (?)
 
msgarr  db      'Enter elements matrix: $'
msga    db      'Matrix A:', cr, lf, '$'
msgn    db      'Enter N: $'
msgm    db      'Enter M: $'
crlf    db      cr, lf, '$'
space   db      ' $'
;описываем данные процедуры ввода числа
string  db      255, 0, 255 dup (?)
errmsg1 db      'Invalid character, you can use '
        db      'the first character can be '
        db      'mark + or -', cr, lf, '$'
errmsg2 db      'Invalid character, you can use '
        db      'only numbers', cr, lf, '$'
errmsg3 db      'Overflow detected! '
        db      'Please try again.', cr, lf, '$'
negflag dw      ?
d       ends
 
;описываем макрокоманду вывода текстовой строки
PRINT   macro   STR
        push    ax
        push    dx
        mov     ah,9
        lea     dx,STR
        int     21h
        pop     dx
        pop     ax
        endm
 
c       segment
;описываем процедуру ввода целого числа в регистр ax
IntegerIn       proc
im:             push    bx
                push    dx
                push    si
                mov     ah, 0ah
                lea     dx, string
                int     21h
                xor     ax, ax
                lea     si, string+2
                mov     negflag, ax
                cmp     byte ptr [si], '-'
                jne     im2
                not     negflag
                inc     si
                jmp     im1
im2:            cmp     byte ptr [si], '+'
                jne     im1
                inc     si
im1:            cmp     byte ptr [si], cr
                je      iex1
                cmp     byte ptr [si], '0'
                jb      ierr1
                cmp     byte ptr [si], '9'
                ja      ierr1
                mov     bx, 10
                mul     bx
                jc      ierr2;
                sub     byte ptr [si], '0'
                add     al, [si]
                adc     ah,0
                inc     si
                jmp     im1
ierr1:          print   crlf
                print   errmsg1
                jmp     im
ierr2:          print   crlf
                print   errmsg3
                jmp     im
iex1:           cmp     negflag, 0
                jne     cmp1
                cmp     ax,32767
                ja      ierr2
                jmp     iex
cmp1:           cmp     ax,32768
                ja      ierr2
                neg     ax
iex:            pop     si
                pop     dx
                pop     bx
                ret
IntegerIn       endp
 
;описываем процедуру ввода беззнакового числа в регистр ax
UnsignedIn      proc
um:             push    bx
                push    dx
                push    si
                mov     ah,0ah
                lea     dx,string
                int     21h
                xor     ax,ax
                lea     si,string+2
um1:            cmp     byte ptr [si],cr
                je      uex
                cmp     byte ptr [si], '0'
                jb      uerr1
                cmp     byte ptr [si], '9'
                ja      uerr1
                mov     bx,10
                mul     bx
                jc      uerr2
                sub     byte ptr [si], '0'
                add     al, [si]
                adc     ah,0
                inc     si
                jmp     um1
uerr1:          print   crlf
                print   errmsg2
                jmp     um
uerr2:          print   crlf
                print   errmsg3
                jmp     um
uex:            pop     si
                pop     dx
                pop     bx
                ret
UnsignedIn      endp
 
;описываем процедуру вывода целого числа из регистра ax
IntegerOut      proc
                push    ax
                push    bx
                push    cx
                push    dx
                push    si
                push    di
                xor     cx, cx
                mov     bx, 10
                cmp     ax, 0
                jge     om
                neg     ax
                push    ax
                mov     ah, 2
                mov     dl, '-'
                int     21h
                pop     ax
om:             inc     cx
                xor     dx, dx
                div     bx
                push    dx
                or      ax, ax
                jnz     om
om1:            pop     dx
                add     dx, '0'
                mov     ah, 2
                int     21h
                loop    om1
                pop     di
                pop     si
                pop     dx
                pop     cx
                pop     bx
                pop     ax
                ret
IntegerOut      endp
 
start:          mov     ax,d
                mov     ds,ax
 r:             print   crlf
                 print   msgm
                 call   UnsignedIn
                 cmp    ax,0
                 je     r
                 mov    M,ax
 r1:            print   crlf
                 print  msgn
                 call   UnsignedIn
                 cmp    ax,1
                 jbe    r1
                 mov    N,ax
                 print  crlf
                 print  msgarr
                 print  crlf
 
                 mov    cx,M
                 xor    bx,bx
 sm:            push    cx
                 mov    cx,N
                 xor    si,si
 sm1:           push    si
                 push   cx
                 push   bx
                 call   IntegerIn
                 pop    bx
                 pop    cx
                 pop    si
                 mov    A[bx+si],ax
                 add    si,2
                 print  crlf
                 loop   sm1
                 pop    cx
                 mov ax,M
                 mov dx,2
                 mul dx
                 add    bx,ax
                 loop   sm
 
                print   msga
                mov     cx,M
                xor     bx,bx
 
sm2:            push    cx
                mov     cx,N
                xor     si,si
sm3:            mov     ax,A[bx][si]
                call    IntegerOut
                print   space
                add     si,2
                loop    sm3
                pop     cx
                mov     ax,M
                mov     dx,2
                mul     dx
                add bx, ax
                print   crlf
                loop    sm2
 
 
        lea bx, A
        xor ax, ax
        mov     ax,N
        mov     dx,M
        mul     ax
        mov     cx,ax
        xor     dx,dx
        mov     si,0
        mov     ax,a[bx][0]
 
 
u1:
         cmp ax,a[si]
         ja u2
         mov ax,a[si]
         inc dx
 
u2:
         add si,2
         loop u1
 ;call IntegerOut
;print space
dec dx
mov ax,dx
mov bx,M
;cwd
;div bx
;call IntegerOut
push ax
;print space
 
lea bx, A
        xor     ax, ax
        mov     ax,N
        mov     dx,M
        mul     ax
        mov     cx,ax
        xor     dx,dx
        mov     si,0
        mov     ax,a[bx][0]
        xor     dx,dx
 
qu1:
         cmp ax,a[si]
         jb qu2
         mov ax,a[si]
         inc dx
 
qu2:
         add si,2
         loop qu1
;call IntegerOut
;print space
dec dx
mov ax,dx
mov bx,M
;cwd
;div bx
;call IntegerOut
;print space
;print crlf
 
;ax = 0
 
mov si,0
mov cx,N
mov bx,ax
mov di,bx
metka1000: ; в промежуточный записываем строку с минимальным элементом
        mov dx,a[bx][di] ; dx = 1
        mov mass[si], dx ;
        add si,2
        add di,2
        loop metka1000
 
mov si,0
mov bx,M
mov ax,N
mul bx
;mov cx,ax
; metka100: ; выводим промежуточный
        ; mov ax,mass[si]
        ; print space
        ; call IntegerOut
        ; add si,2
        ; loop metka100
 
mov cx,N
mov si,0
mov bx,M
;print crlf ; индекс максимального элемента превращаем в номер его строки
pop ax
mov bx,M
div bx; ax = 2
mov bx,2; razmer
mul bx
mov bx,M
mul bx
mov bx,ax; 12
 
mov di,0
mov ax,a[bx][di] ; 8+0
print crlf
;call IntegerOut
 
metka101: ; меняем местами
        mov dx,a[bx][di];
        mov ax,mass[si] ;
        mov a[bx][di],ax;
        mov a[0][di], dx
        add si,2
        add di,2
        loop metka101
mov si,0
mov bx,M
mov ax,N
mul bx
mov cx,ax
xor dx,dx
print crlf
mov cx,M
        xor si,si
metka103:
        push cx
        mov cx,N
metka102: ; просто выводим
        mov ax,a[si]
        print space
        call IntegerOut
        add si,2
        loop metka102
        pop cx
        print crlf
        loop metka103
ex:             mov     ah,4ch
                int     21H
c               ends
                end     start

ФедосеевПавел · 26.09.2018, 17:10

А каких размеров может быть матрица, исходя из данного кода и строки 14 в частности?

Как вариант, предлагаю выполнить отладку без ввода матрицы, задав её значения в коде.

Добавлено через 1 минуту
И комментариев нет. На 300+ строк. Вы, как для врага это набирали.

Добавлено через 7 минут
Строка 246 какая-то ошибка адресации, т.к. в bx адрес матрицы A. Т.е. в ax помещается по сути значение по адресу ADDR(A)+ADDR(A)+0 Это может быть что угодно, и даже элемент матрицы.

@r0m1e · 26.09.2018, 18:15 **[ТС]**

Там в 14 строке указал 9, так как проверял
А так, конечно, матрица неограниченного объема

Думаю правильным будет написать все заново и уже правильно это сделать
Как это лучше всего реализовать

Не понимаю просто как верно с учетом заданных M и N менять местами строки содержащие эти элементы

ФедосеевПавел · 26.09.2018, 18:23

А как бы делали это в C/Pascal?

C

for(j=0; j<N; j++)
{
  temp=A[Imin, j];
  A[Imin, j]=A[Imax, j];
  A[Imax, j]=temp;
}

Всё то же самое

Добавлено через 1 минуту

Assembler

        ;пусть в si и di адреса строк матрицы.
        ;нужен цикл по строке и обмен значениями
        mov     cx,     [N]
        @@exForJ:
                mov     ax,     [si]
                mov     bx,     [di]
                mov     [si],   bx
                mov     [di],   ax
                add     si,     2
                add     di,     2
        loop    @@exForJ

@r0m1e · 26.09.2018, 18:29 **[ТС]**

Дело в том, что в ассемблере двумерный массив реализован как одномерный
Из за этого сложности при переносе
Нам нужен номер элемента и из него получить номер строки
Закинуть строки с минимальным и максимальным элементом во временных массив и потом из него заменять
Это и реализовано в моем коде, но он не работает для неквадратных матриц

ФедосеевПавел · 26.09.2018, 18:54

Этот трюк с представлением матрицы как массива используется часто и в языках высокого уровня.
В цикле поиска минимального, максимального элементов и их строк запоминайте номера этих строк.

Ну и просто представьте. Вот адрес, равный метке A. По нему располагается элемент A[0,0]. По адресу A+2 - A[0,1], по адресу (A+4) - A[0,2]. И т.д.
По адресу (A+2*N) - A[1,0]...
И наоборот, смещение однозначно определяет номер строки.

По известному номеру строки с минимальным элементом можно вычислить адрес начала этой строки. Он равен (A+Imin*N)

Добавлено через 17 минут
Поправлюсь,
По известному номеру строки с минимальным элементом можно вычислить адрес начала этой строки. Он равен (A+Imin*N*2). Множитель 2 это размер элемента матрицы в байтах.

ФедосеевПавел · 30.09.2018, 20:31

Assembler

title   laba
        assume  cs:c, ds:d, ss:s
 
s       segment stack
        dw      256 dup (?)
s       ends
 
        ;символы возврата каретки и перевода строки
        cr = 0dh
        lf = 0ah
 
d       segment
N       dw      7
M       dw      5
A       dw      1507, 3110, 2860, -342, 9753, 6895, 1102
        dw      3626, 5003, 6393, 5870, -577, 2704, 3581
        dw      1681, 2355, 6146, 1641, 5176, 4572, 4294
        dw      4529, 7828, 1437, -876, 3802, 4577, 5432
        dw      2286, -768, 8294, 8331, 7883, 7421,  803
Imin    dw      ?
Imax    dw      ?
msgarr  db      'Enter elements matrix: $'
msga    db      'Matrix A:', cr, lf, '$'
msgn    db      'Enter N: $'
msgm    db      'Enter M: $'
crlf    db      cr, lf, '$'
space   db      ' $'
;описываем данные процедуры ввода числа
string  db      255, 0, 255 dup (?)
errmsg1 db      'Invalid character, you can use '
        db      'the first character can be '
        db      'mark + or -', cr, lf, '$'
errmsg2 db      'Invalid character, you can use '
        db      'only numbers', cr, lf, '$'
errmsg3 db      'Overflow detected! '
        db      'Please try again.', cr, lf, '$'
negflag dw      ?
d       ends
 
;описываем макрокоманду вывода текстовой строки
PRINT   macro   STR
        push    ax
        push    dx
        mov     ah,9
        lea     dx,STR
        int     21h
        pop     dx
        pop     ax
        endm
 
c       segment
;описываем процедуру ввода целого числа в регистр ax
IntegerIn       proc
im:             push    bx
                push    dx
                push    si
                mov     ah, 0ah
                lea     dx, string
                int     21h
                xor     ax, ax
                lea     si, string+2
                mov     negflag, ax
                cmp     byte ptr [si], '-'
                jne     im2
                not     negflag
                inc     si
                jmp     im1
im2:            cmp     byte ptr [si], '+'
                jne     im1
                inc     si
im1:            cmp     byte ptr [si], cr
                je      iex1
                cmp     byte ptr [si], '0'
                jb      ierr1
                cmp     byte ptr [si], '9'
                ja      ierr1
                mov     bx, 10
                mul     bx
                jc      ierr2;
                sub     byte ptr [si], '0'
                add     al, [si]
                adc     ah,0
                inc     si
                jmp     im1
ierr1:          print   crlf
                print   errmsg1
                jmp     im
ierr2:          print   crlf
                print   errmsg3
                jmp     im
iex1:           cmp     negflag, 0
                jne     cmp1
                cmp     ax,32767
                ja      ierr2
                jmp     iex
cmp1:           cmp     ax,32768
                ja      ierr2
                neg     ax
iex:            pop     si
                pop     dx
                pop     bx
                ret
IntegerIn       endp
 
;описываем процедуру ввода беззнакового числа в регистр ax
UnsignedIn      proc
um:             push    bx
                push    dx
                push    si
                mov     ah,0ah
                lea     dx,string
                int     21h
                xor     ax,ax
                lea     si,string+2
um1:            cmp     byte ptr [si],cr
                je      uex
                cmp     byte ptr [si], '0'
                jb      uerr1
                cmp     byte ptr [si], '9'
                ja      uerr1
                mov     bx,10
                mul     bx
                jc      uerr2
                sub     byte ptr [si], '0'
                add     al, [si]
                adc     ah,0
                inc     si
                jmp     um1
uerr1:          print   crlf
                print   errmsg2
                jmp     um
uerr2:          print   crlf
                print   errmsg3
                jmp     um
uex:            pop     si
                pop     dx
                pop     bx
                ret
UnsignedIn      endp
 
;описываем процедуру вывода целого числа из регистра ax
IntegerOut      proc
                push    ax
                push    bx
                push    cx
                push    dx
                push    si
                push    di
                xor     cx, cx
                mov     bx, 10
                cmp     ax, 0
                jge     om
                neg     ax
                push    ax
                mov     ah, 2
                mov     dl, '-'
                int     21h
                pop     ax
om:             inc     cx
                xor     dx, dx
                div     bx
                push    dx
                or      ax, ax
                jnz     om
om1:            pop     dx
                add     dx, '0'
                mov     ah, 2
                int     21h
                loop    om1
                pop     di
                pop     si
                pop     dx
                pop     cx
                pop     bx
                pop     ax
                ret
IntegerOut      endp
 
;Вывод на экран матрицы слов
;на входе:
;  ds:dx - адрес матрицы
;  bx    - количество столбцов в матрице
;  cx    - количество строк в матрице
;на входе:
;  -
ShowMatrix      proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
        pushf
 
        jcxz    @@smExit
        or      bx,     bx
        jz      @@smExit
 
        cld
        mov     cx,     cx
        mov     si,     dx
        @@smForI:
                push    cx
                push    bx
                mov     cx,     bx
                @@smForJ:
                        lodsw
                        call    IntegerOut
                        mov     ah,     02h
                        mov     dl,     ' '
                        int     21h
                loop    @@smForJ
                mov     ah,     09h
                lea     dx,     [CrLf]
                int     21h
                pop     bx
                pop     cx
        loop    @@smForI
 
@@smExit:
        popf
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
ShowMatrix      endp
 
start:          mov     ax,d
                mov     ds,ax
 
                lea     dx,     [A]
                mov     bx,     [N]
                mov     cx,     [M]
                call    ShowMatrix
 
        ;поиск номеров строк с минимальным и максимальным элементами
        lea     si,     [A]
        mov     cx,     [M]
        mov     bx,     [si]    ;min
        mov     dx,     [si]    ;max
        mov     [Imin], 0
        mov     [Imax], 0
        mov     di,     0       ;текущий номер строки
        cld
        @@ForI:
                push    cx
                mov     cx,     [N]
                @@ForJ:
 
                        lodsw
                @@TestMin:
                        cmp     ax,     bx
                        jl      @@TestMax
                        mov     bx,     ax
                        mov     [Imin], di
                @@TestMax:
                        cmp     ax,     dx
                        jg      @@Next
                        mov     dx,     ax
                        mov     [Imax], di
                @@Next:
                loop    @@ForJ
                pop     cx
                inc     di
        loop    @@ForI
        ;контрольный вывод номеров строк (от 0)
        mov     ax,     [Imin]
        call    IntegerOut
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        mov     ax,     [Imax]
        call    IntegerOut
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
 
        ;обмен строк
        mov     ax,     [Imin]
        cmp     ax,     [Imax]
        je      @@ShowResult
        ;вычисление адресов
        mul     word ptr [N]
        lea     si,     [A]
        mov     di,     si
        add     si,     ax
        add     si,     ax
        mov     ax,     [Imax]
        mul     [N]
        add     di,     ax
        add     di,     ax
        ;теперь в si и di адреса строк матрицы.
        ;нужен цикл по строке и обмен значениями
        mov     cx,     [N]
        @@exForJ:
                mov     ax,     [si]
                mov     bx,     [di]
                mov     [si],   bx
                mov     [di],   ax
                add     si,     2
                add     di,     2
        loop    @@exForJ
 
@@ShowResult:
                lea     dx,     [A]
                mov     bx,     [N]
                mov     cx,     [M]
                call    ShowMatrix
 
ex:             mov     ah,4ch
                int     21H
c               ends
                end     start

ФедосеевПавел Модератор 8381 / 4263 / 1618 Регистрация: 01.02.2015 Сообщений: 13,269 Записей в блоге: 5
	26.09.2018, 17:10	2
	А каких размеров может быть матрица, исходя из данного кода и строки 14 в частности? Как вариант, предлагаю выполнить отладку без ввода матрицы, задав её значения в коде. Добавлено через 1 минуту И комментариев нет. На 300+ строк. Вы, как для врага это набирали. Добавлено через 7 минут Строка 246 какая-то ошибка адресации, т.к. в bx адрес матрицы A. Т.е. в ax помещается по сути значение по адресу `ADDR(A)+ADDR(A)+0` Это может быть что угодно, и даже элемент матрицы. 0

@r0m1e 0 / 0 / 0 Регистрация: 26.09.2018 Сообщений: 3
	26.09.2018, 18:15 [ТС]	3
	Там в 14 строке указал 9, так как проверял А так, конечно, матрица неограниченного объема Думаю правильным будет написать все заново и уже правильно это сделать Как это лучше всего реализовать Не понимаю просто как верно с учетом заданных M и N менять местами строки содержащие эти элементы 0

@r0m1e 0 / 0 / 0 Регистрация: 26.09.2018 Сообщений: 3
	26.09.2018, 18:29 [ТС]	5
	Дело в том, что в ассемблере двумерный массив реализован как одномерный Из за этого сложности при переносе Нам нужен номер элемента и из него получить номер строки Закинуть строки с минимальным и максимальным элементом во временных массив и потом из него заменять Это и реализовано в моем коде, но он не работает для неквадратных матриц 0

ФедосеевПавел Модератор 8381 / 4263 / 1618 Регистрация: 01.02.2015 Сообщений: 13,269 Записей в блоге: 5
	26.09.2018, 18:54	6
	Этот трюк с представлением матрицы как массива используется часто и в языках высокого уровня. В цикле поиска минимального, максимального элементов и их строк запоминайте номера этих строк. Ну и просто представьте. Вот адрес, равный метке A. По нему располагается элемент A[0,0]. По адресу A+2 - A[0,1], по адресу (A+4) - A[0,2]. И т.д. По адресу (A+2N) - A[1,0]... И наоборот, смещение однозначно определяет номер строки. По известному номеру строки с минимальным элементом можно вычислить адрес начала этой строки. Он равен (A+IminN) Добавлено через 17 минут Поправлюсь, По известному номеру строки с минимальным элементом можно вычислить адрес начала этой строки. Он равен (A+IminN2). Множитель 2 это размер элемента матрицы в байтах. 0

	30.09.2018, 20:31

Опции темы