Заменить заданное слово в строке на другое заданное слово

; Заменить заданное слово в строке на другое заданное слово
    .model small
    .code
maxsiz=24+1
EOT=13 ; признак конца текста
    org 100h
start:  jmp beg
; буфер ввода строки "поиск"
strfind db maxsiz
strfindL db 0
strfind2 db maxsiz dup (0)
; буфер ввода строки "замена"
strrepl db maxsiz
strreplL db 0
strrepl2 db maxsiz dup (0)
; буфер ввода строки "текст"
strtext db 255
strtextL db 0
strtext2 db 255 dup (0)
; буфер текста результата
outtext db 512 dup (0)
; длина строки поиска (слово)
sfindL dw 0
; длина строки замены (слово)
sreplL dw 0
; подказки
mfind db 13,10,"Find>$" ; поиск
mrepl db 13,10,"Repl>$" ; замена
mtext db 13,10,"Text>$" ; текст, в котором происходит замена
crlf    db 13,10,"$"    ; перевод строки
; макро - вывести строку
print macro txt
    mov dx,offset txt
    mov ah,9
    int 21h
    endm
; макро - читать строку
input macro buf
    mov dx,offset buf
    mov ah,10
    int 21h
    endm
; основная программа
beg:    mov ax,cs
    mov ds,ax
    mov es,ax
; ввод данных
    print mfind
    input strfind  ; ввод "поиск"
    cmp strfindL,0 ; если введена пустая строка, то выход в Дос
    jz exit
    mov al,strfindL
    mov ah,0
        mov sfindL,ax
    print mrepl
    input strrepl ; ввод "замена"
    cmp strreplL,0
    jz exit
    mov al,strreplL
    mov ah,0
    mov sreplL,ax
    print mtext
    input strtext ; ввод "текст"
    cmp strtextL,0
    jz exit
    cld
    mov si,offset strtext2 ; si=исходный текст
    mov di,offset outtext  ; di=текст результата
m0: lodsb
    stosb
    cmp al,EOT  ; это конец текста ?
    jz outprint ; да, переход к печати результата
    call find   ; найти слово 
    jnz m0      ; слово не найдено - конец цикла
    call replace ; слово найдено - сделать замену
    jmp m0       ; конец цикла
; вывод результата
outprint: print crlf
    mov si,offset outtext   ; si=текст результата
m1: lodsb        ; считать символ
    cmp al,EOT   ; если конец текста, то выход
    jz exit
    mov dl,al    ; печатать символ
    mov ah,2
    int 21h
    jmp m1       ; конец цикла
exit:   mov ax,4C00h ; выход в Дос
    int 21h
 
find:   push si  ; поиск слова
    push di
    mov cx,sfindL ; сдвинуть указатель текста на длину искомого слова
    sub si,cx
    cmp si,offset strtext2 ; указатель меньше адреса начала текста ?
    jc  return_no ; да, возвратить "не найдено"
    mov di,offset strfind2 ; нет, сравнить со словом поиска
    repe cmpsb
    pop di
    pop si
    ret         ; возвращается флаг Z, если слово найдено
return_no:          ; возвращается флаг NZ - "слово не найдено"
    mov dl,1
    or dl,dl
    pop di
    pop si
    ret
 
replace:push si ; замена слова
    sub di,sfindL ; стираем исходное слово в выходном тексте
    mov cx,sreplL ; заменяем на новое слово (при этом DI продвигается по тексту)
    mov si,offset strrepl2
    rep movsb
    pop si
    ret
    end start