Вычислить выражение, ввод и вывод на дисплей

; Написать код программы на TASM так, чтобы:
; a. Расчёт выражения происходил в отдельной процедуре.
; b. Ввод и вывод происходил в других отдельных процедурах. Выражение
; (переменные вводятся с клавиатуры): (a*b–c*d)*(a+b); Тип вводимых
; переменных: a, b – define byte, c, d – define word
 
    .model small
    .code
vara    db 0
varb    db 0
varc    dw 0
vard    dw 0
tmplo   dw 0
tmphi   dw 0
resultlo dw 0
resulthi dw 0
modebyte db 0  ; флаг "вводится байт со знаком" 
buf1    db 6+1 ; буфер ввода текста (макс - 6 символов)
len1    db 0  ; возвр длина строки
string1 db 6+1 dup (0) ; буфер строки
vsign   db 0 ; флаг "вводится отрицательное число"
 
; вычисление результата по формуле Результат сохраняется в resulthi:resultlo
findresult proc
    mov ax,varc  ; tmp=c*d
    imul vard
    mov tmplo,ax
    mov tmphi,dx
    mov al,vara ; (int)a*(int)b
    cbw
    mov bx,ax
    mov al,varb
    cbw
    imul bx
    sub ax,tmplo
    sbb dx,tmphi
    mov tmplo,ax
    mov tmphi,dx
    mov al,vara ; (int)a+(int)b
    cbw
    mov bx,ax
    mov al,varb
    cbw
    add bx,ax
    mov ax,tmplo ; ()*(a+b)
    imul bx
    mov resultlo,ax
    mov resulthi,dx
    ret
findresult endp
 
; вывод числа al со знаком на дисплей
printbyte proc
    cbw
    call printint
    ret
printbyte endp
 
; вывод числа ax со знаком на дисплей
printint proc
    cwd ; расширить ax в dx:ax со знаком
    call printlong
    ret
printint endp
 
; вывод числа dx:ax на дисплей как числа со знаком
printlong proc
    push si
    push di
    mov si,dx     ; занести dx:ax в si:di
    mov di,ax
    test si,8000h ; проверить знак числа
    jz oi1
    mov dl,"-" ; если число отриц, напечатать "-" и изм число на положительное
    mov ah,2
    int 21h
    xor si,-1
    xor di,-1
    add di,1
    adc si,0
oi1:    xor     cx, cx
        mov     bx, 10 ; 10 ичная система счисления
oi2:    xor     dx,dx  ; находим остаток от деления si:di на 10
    mov     ax,si
        div     bx ; ax=ax/10, dx=ax mod 10
    mov     si,ax
    mov     ax,di
    div bx
    mov di,ax
        push    dx ; занести цифру в стек
        inc     cx ; увеличить счётчик цифр
    mov     ax,si ; si:di=0 ?
        or      ax,di
        jnz     oi2 ; если нет, то продолжить
        mov     ah, 02h ; ah=код функции "печать символа dl"
oi3:    pop     dx  ; вытащить цифры из стека и напечатать
        add     dl, '0'
        int     21h
        loop    oi3
    pop di
    pop si
    ret
printlong endp
 
; макро - вывод текста txt
print   macro txt
    local u1,u2
    jmp u2
u1  db 13,10,txt,"$"
u2: push ax
    push dx
    mov dx,offset u1
    mov ah,9
    int 21h
    pop dx
    pop ax
    endm
 
; ввод числа (байта со знаком или целого со знаком)
; значение возвращается в ax
iv1:    jmp exdos
inputval:
    mov dx,offset buf1 ; ввод строки
    mov ah,10
    int 21h
    mov cl,len1 ; если длина строки=0 то выход в Дос
    mov ch,0
    jcxz iv1
    lea si,string1
    mov vsign,0
    cmp byte ptr [si],"-" ; если стоит знак "-" то число отрицательное
    jnz iv2
    mov vsign,1
    inc si
iv2:    call atoi   ; преобразовать цифры в число ax
    cmp vsign,0
    jz iv3
    neg ax
iv3:    call checkov ; проверка ввода на переполнение
    ret 
 
; прочитать очередное число ax в строке
atoi    proc
    sub ax,ax
    sub cx,cx
    mov bx,10 ; основание системы счисления
atoi1:  mov cl,[si]
    inc si
    cmp cl,"0"
    jb atoi2 ; если не цифра, то завершить преобразование
    cmp cl,"9"
    ja atoi2
    sub cl,"0" ; cl - цифра
    mul bx ; ax=ax*10+cx
    add ax,cx
    jmp atoi1
atoi2:  ret
atoi    endp
 
; проверка выхода ax за диапазон
checkov proc
    cmp modebyte,0 ; если флаг установлен, проверить умещается ли число в байт
    jnz checkbyteov
    clc
    ret 
checkbyteov:
    cmp ax,-128; проверка выхода за диапазон
    jl err1
    cmp ax, 127
    jg err1
    CLC
    ret
err1:   print "Value out of range (-128..127)"
    STC ; установить флаг ошибки
    RET
checkov endp
 
; основная программа
start:  mov ax,cs
    mov ds,ax
    mov es,ax
    mov modebyte,1 ; уст флаг "ввод байта"
retry1: print "byte a="
    call inputval
    jc retry1 ; повторный ввод при ошибке
    mov vara,al
retry2: print "byte b="
    call inputval
    jc retry2 ; повторный ввод при ошибке
    mov varb,al
    mov modebyte,0 ; ввод слова
    print "word c="
    call inputval
    mov varc,ax
    print "word d="
    call inputval
    mov vard,ax
    call findresult ; вычисление по формуле
    print "(a*b-c*d)*(a+b)="
    mov ax,resultlo ; печать результата как signed long
    mov dx,resulthi
    call printlong
exdos:  mov ax,4C00h ; выход в Дос
    int 21h
    end start