На ASP страничку вставить кусок HTML кода

<%
Function DownloadTextBlock()
    Const SOURCE_URL     = "http://...."
    Const KEY_LASTUPDATE = "BlockLastUpdate"
    Const KEY_CONTENT    = "BlockContent"
    Dim objHttp, strText
    strText = ""
    If ""<>Application(KEY_LASTUPDATE) And ""<>Application(KEY_CONTENT) Then
        Dim lastUpdate
        lastUpdate = CDate(Application(KEY_LASTUPDATE))
        If DateDiff("n", lastUpdate, Now)<20 Then
            ' Последнее обновление данных было меньше 20 минут назад
            ' Берем текст из кеша
            strText = Application(KEY_CONTENT)
        End If
    End If
    If 0=Len(strText) Then
        Set objHttp = Server.CreateObject("MSXML2.ServerXMLHTTP")
        objHttp.Open "GET", SOURCE_URL, False
        objHttp.Send
        If 200=objHttp.status Then
            ' Вырезаем нужный кусок текста
            Dim pos1, pos2
            pos1 = InStr(1, objHttp.responseText, "<p>") + 3
            pos2 = InStr(pos1, objHttp.responseText, "</p>")
            strText = Mid(objHttp.responseText, pos1, pos2-pos1)
            ' Кешируем его
            Application(KEY_LASTUPDATE) = Now
            Application(KEY_CONTENT) = strText
        ElseIf ""<>Application(KEY_CONTENT) Then
            strText = Application(KEY_CONTENT)
        End If
        Set objHttp = Nothing
    End If
    DownloadTextBlock = strText
End Function
Response.Write DownloadTextBlock()
%>