Вывести координаты мыши в нижний угол экрана

.model tiny
.code
.startup
 
;переход в графический режим
mov ax,0013h
int 10h
 
;инициализировать мышь
xor ax,ax
int 33h
 
;включить курсор. Пока стандартный.
mov ax,0001h
int 33h
 
;установим позицию курсора
mov dh,1
mov dl,1
call SetPos
 
;печатаем сообщение
mov bl,10       ;Цвет
mov si,offset mes   ;Выводим текст
call OutText
 
;ждем нажатия любой клавиши
xor ah,ah
int 16h
 
;настройка es на ds
push ds
pop es
 
;собственно замена курсора, с которой проблема
;должна произойти до отображения курсора
mov ax,0009h
mov bx,0
mov cx,0
lea dx,mas_1
int 33h
 
mov dh,2
mov dl,1
call SetPos
 
;печатаем сообщение
mov bl,10       ;Цвет
mov si,offset mes2  ;Выводим текст
call OutText
 
;ждем нажатия коавиши
xor ah,ah
int 16h
 
;текстовый режим
mov ax,3
int 10h
 
;выходим нах
int 20h
 
;подпрограмма установки позиции курсора
SetPos:
        mov ah,2
        xor bh,bh
        int 10h
        ret
 
;подпрограмма вывода текста
OutText:
        lodsb
        test al,al
        jz done
        mov ah,0eh
        xor bh,bh
        int 10h
        jmp SHORT OutText
done:       ret
 
;определение маски для изображения
mas_1:
     dw 1011111111111111b
     dw 1001111111111111b
     dw 1000111111111111b
     dw 1000011111111111b
     dw 1000001111111111b
     dw 1000000111111111b
     dw 1000000011111111b
     dw 1000000001111111b
     dw 1000000000111111b
     dw 1000000000011111b
     dw 1000000111111111b
     dw 1000000011111111b
     dw 1011000011111111b
     dw 1111100001111111b
     dw 1111100001111111b
     dw 1111110001111111b
 
     dw 0100000000000000b
     dw 0110000000000000b
     dw 0101000000000000b
     dw 0100100000000000b
     dw 0100010000000000b
     dw 0100001000000000b
     dw 0100000100000000b
     dw 0100000010000000b
     dw 0100000001000000b
     dw 0100000111100000b
     dw 0100111000000000b
     dw 0111100100000000b
     dw 0100100100000000b
     dw 0000010010000000b
     dw 0000010010000000b
     dw 0000001110000000b
mes:
     db 'NORMAL mouse. Press any key...',0
mes2:
     db 'OS/2 mouse. Press any key...',0
END

.286
.MODEL  tiny
.CODE
    ORG 100h
start:
;переход в графический режим
    mov ax,0013h
    int 10h
 
;инициализировать мышь
    xor ax,ax
    int 33h
 
    mov ax, 0fh
    mov cx, 10h
    mov dx, cx
    int 33h
; Обработчик событий
    mov ax, 000Ch
    mov cx, 07Fh    ; флаги событий для вызова п/п
;Bitfields for mouse call mask:
 
;Bit(s) Description 
; 0 call if mouse moves
; 1 call if left button pressed
; 2 call if left button released
; 3 call if right button pressed
; 4 call if right button released
; 5 call if middle button pressed (Mouse Systems/Logitech/Genius mouse)
; 6 call if middle button released (Mouse Systems/Logitech/Genius mouse)
; 7-15  unused
    lea dx, msISR   ; адрес п/п
    int 33h
 
; вызываем п/п для первичной отрисовки шаблончика координат
    call    far ptr msISR
 
;включить курсор. Пока стандартный.
    mov ax,0001h
    int 33h
 
;установим позицию курсора
    mov dh,1
    mov dl,1
    call    SetPos
 
;печатаем сообщение
    mov bl,10           ;Цвет
    mov si,offset mes       ;Выводим текст
    call    OutText
 
;ждем нажатия любой клавиши
    xor ah,ah
    int 16h
 
;настройка es на ds
    push    ds
    pop es
 
;собственно замена курсора, с которой проблема
;должна произойти до отображения курсора
    mov ax,0009h
    mov bx,0
    mov cx,0
    lea dx,mas_1
    int 33h
 
    mov dh,2
    mov dl,1
    call    SetPos
 
;печатаем сообщение
    mov bl,10           ;Цвет
    mov si,offset mes2      ;Выводим текст
    call    OutText
 
;ждем нажатия коавиши
    xor ah,ah
    int 16h
; Отменить обработичк
    mov ax, 000Ch
    mov cx, 0000h
    int 33h
 
;текстовый режим
    mov ax,3
    int 10h
 
;выходим нах
    int 20h
 
;подпрограмма установки позиции курсора
SetPos:
    mov ah,2
    xor bh,bh
    int 10h
    ret
 
;подпрограмма вывода текста
OutText:
    lodsb
    test    al,al
    jz  done
    mov ah,0eh
    xor bh,bh
    int 10h
    jmp SHORT OutText
done:       ret
 
msISR:
    push    ds
    push    es
    push    cs
    pop es
    test    ax, 1   ; перемещение?
    jnz @1
    call    btn
    jmp @2
@1: lea di, y_end   ; хвост шаблончика координат
; чтобы выводить в знакоместах, CX и DX надо делить на 8 -> shr dx, 3
    push    cx
    mov ax,dx
    std     ; писать будем с хвоста, задом наперёд
    mov bx, 10  ; делитель
    call    cnv ; преобразуем Y
    dec di      ; пропускаем ':'
    pop ax
    call    cnv ; преобразуем X
@2: cld
    push    cs
    pop ds
; Вывод координат
 
    mov dl, 0   ; row
    mov dh, 24  ; col
    mov ah, 02h
    int 10h
    std
    mov cx, 11  ; tpt_sz
    mov ah, 0Ah
    lea si, mas_1
    mov bx, 00000011B   ; color: cyan on black
; цикл вывода
disp:
    lodsb
    int 10h
    loop    disp
    cld
    pop es
    pop ds
    retf
; обработка кнопок
btn:    test    ax, 110b    ; левая кнопка?
    jz  @3
    xor cs:_l, 6Ch      ; да, перебрасываем флаг: 20 xor 6Ch = 'L' или пробел
@3: test    ax, 11000b  ; правая кнопка?
    jz  @4
    xor cs:_r, 72h  ; да, перебрасываем флаг: 20 xor 72h = 'R' или пробел
@4: test    bx, 1100000b    ; средняя кнопка?
    jz  @5
    xor cs:_m, 6Dh  ; да, перебрасываем флаг: 20 xor 6Dh = 'M' или пробел
 
@5: ret
; Преобразование числа в строку
;   es:di - endbuf
cnv:    call    @@1
    call    @@1
@@1:    div bl      ; делим на 10.
    xchg    ah, al
    add al, 30h     ; в ASCII
    stosb                   ; сохраняем
    shr ax, 8
    ret
x   db '000:000'        ; шаблончик для вывода
y_end   = $ - 1
_l  db  20h     ;
_m  db  20h
_r  db  20h
tpt_sz  = $ - x
 
;определение маски для изображени
mas_1:
    dw  1011111111111111b
    dw  1001111111111111b
    dw  1000111111111111b
    dw  1000011111111111b
    dw  1000001111111111b
    dw  1000000111111111b
    dw  1000000011111111b
    dw  1000000001111111b
    dw  1000000000111111b
    dw  1000000000011111b
    dw  1000000111111111b
    dw  1000000011111111b
    dw  1011000011111111b
    dw  1111100001111111b
    dw  1111100001111111b
    dw  1111110001111111b
 
    dw  0100000000000000b
    dw  0110000000000000b
    dw  0101000000000000b
    dw  0100100000000000b
    dw  0100010000000000b
    dw  0100001000000000b
    dw  0100000100000000b
    dw  0100000010000000b
    dw  0100000001000000b
    dw  0100000111100000b
    dw  0100111000000000b
    dw  0111100100000000b
    dw  0100100100000000b
    dw  0000010010000000b
    dw  0000010010000000b
    dw  0000001110000000b
mes:
    db  'NORMAL mouse. Press any key...',0
mes2:
    db  'OS/2 mouse. Press any key...',0
    END start

        assume  cs:ddd,ds:ddd
        ddd segment
        org 100h
start:      jmp boot
        db  'Smoothly Mickey Mouse, (#)1992, 2014 by Charles Kludge',26,0
boot:       
; reset mouse
        xor ax,ax
        int 33h
; enable mouse drv
        mov ax,20h
        int 33h
; hide mouse
        mov ax,2
        int 33h
; position 0,0
        xor cx,cx
        xor dx,dx
        mov ax,4
        int 33h
;
        call    init
;
        mov ax,0bh
        int 33h
        mov cx, 07Fh
        mov ax,0ch
        push    cs
        pop es
        mov dx,offset cs:msdrv
        int 33h     ; set mouse ISR
 
        call    save
 
        mov ax,1
        mov si,0
        mov di,0
        call    far ptr cs:msdrv
 
loo:        xor ax,ax
        int 16h
        cmp     ax,4800h        ; up
        jnz ss_1
        cmp word ptr cs:yy,0
        jz  ss_11
        dec word ptr cs:yy
        jmp cmn
ss_11:      mov ax,word ptr cs:bpc
        mov word ptr cs:yy,ax
        jmp cmn
        ;
ss_1:       cmp     ax,5000h                ; dn
        jnz ss_2
        mov ax,word ptr cs:bpc
        cmp word ptr cs:yy,ax
;       jz  ss_21
        inc word ptr cs:yy
        jmp cmn
ss_21:      mov word ptr cs:yy,0
        jmp cmn
 
        ;
ss_2:       cmp     ax,4D00h        ; rt
        jnz ss_3
        cmp word ptr cs:xx,7
;       jz  ss_31
        inc word ptr cs:xx
        jmp cmn
ss_31:      mov word ptr cs:xx,0
        jmp cmn
        ;
ss_3:       cmp     ax,4B00h        ; lf
        jnz ss_4
        cmp word ptr cs:xx,0
        jz  ss_41
        dec word ptr cs:xx
        jmp cmn
ss_41:      mov word ptr cs:xx,7
        jmp cmn
        ;
ss_4:       cmp     al,27           ; esc
        jz  bye
        jmp loo
cmn:        mov si,word ptr cs:xx
        mov di,word ptr cs:yy
        mov ax,1
        call    far ptr cs:msdrv
        jmp loo
 
bye:        call    restore
        xor ax,ax
        int 33h
        mov ax,21h
        int 33h
        ;
        call    rsfnt
        ;
        int 20h
xx:     dw  0
yy:     dw  0
;
init:       xor ax,ax
        mov es,ax
        push    cs
        pop ds
        ;
        mov al,byte ptr es:[484h]
        inc al
        mov byte ptr rows,al    ; rows on screen
        ;
        mov ax,word ptr es:[44Ah]
        shl ax,1
        mov word ptr cols,ax    ; columns on screen
        ;
        mov ax,word ptr es:[485h]
        mov byte ptr bpc,al     ; char height
        ;
        mov ax,0b000h
        mov bx,word ptr es:[463h]
        cmp bx,03B4h
        jz  i_1
        or  ax,800h
i_1:        mov word ptr cs:cptr+2,ax    ; video buffer seg addr
        mov word ptr cs:cptr,0
        ;
i_2:
        ;
        call    svfnt
        ;
        retn
;
svfnt:
        push    si
        push    di
        xor si,si
        mov di,2000h
        call    sv_rs
        call    ope
        mov ax,0A000h
        mov es,ax
        mov ds,ax
        mov cx,40h
        mov di,1600h
        mov si,di
sf_1:       lodsb
        shl al,1
        stosb
        loop    sf_1
        call    clo
        pop di
        pop si
        ret
 
rsfnt:
        push    si
        push    di
 
        xor di,di
        mov si,2000h
 
        call    sv_rs
        pop di
        pop si
        ret
 
sv_rs:      push    es
        push    ds
        cld
        call    ope
 
        mov ax,0A000h
        mov es,ax
        mov ds,ax
        mov cx,1000h
        rep movsw
 
        call    clo
        pop ds
        pop es
        ret
 
;
;Bitfields for mouse call mask:
 
;Bit(s) Description 
; 0 call if mouse moves
; 1 call if left button pressed
; 2 call if left button released
; 3 call if right button pressed
; 4 call if right button released
; 5 call if middle button pressed (Mouse Systems/Logitech/Genius mouse)
; 6 call if middle button released (Mouse Systems/Logitech/Genius mouse)
; 7-15  unused
;       AX = condition mask (same bit assignments as call mask)
;       BX = button state
;       CX = cursor column
;       DX = cursor row
;       SI = horizontal mickey count
;       DI = vertical mickey count
msdrv:
        cli
        push    es
        push    ds
        push    cs
        pop ds
        mov word ptr cs:[xx],cx
        mov word ptr cs:[yy],dx
        ;
        test    ax,1
;       jnz ms_mm0
        call    btn
ms_mm0:     cmp di,0
        jns ms_1
        xor di,di
        ;
ms_1:       mov ax,si
        mov cx,3
        shr ax,cl
        shl ax,1                    ; x mickeys / 4
        mov word ptr cs:xpos,ax
        ;
        and si,07h
        mov word ptr cs:d_x,si
        ;
        mov ax,di
        mov bx,word ptr cs:bpc
        div bl
        mov byte ptr cs:d_y,ah
        xor ah,ah
        mov word ptr cs:ypos,ax
        ;
        cld
        call    restore
        mov ax,word ptr cs:ypos
        mul word ptr cs:cols    ; linear offset in video buffer
        add ax,word ptr cs:xpos
        mov bx,word ptr cs:d_x
        mov word ptr cs:cptr,ax
        call    save
        call    movec
done:       call    coord
        pop ds
        pop es
        sti
        retf
;
restore:    push    cx
        push    dx
        push    di
        push    si
        ;
        les di,dword ptr cs:cptr
        push    cs
        pop ds
        cld
        mov si,offset s1
        movsb
        ;
        inc di
        movsb
        add di,word ptr cs:cols
        sub di,3
        movsb
        ;
        inc di
        movsb
        ;
        pop si
        pop di
        pop dx
        pop cx
        retn
;
save:
        lds si,dword ptr cs:cptr
        push    cs
        pop es
        cld
        lodsb
        mov byte ptr cs:s1,al
        mov byte ptr ds:[si-1],211
        inc si
        ;
        lodsb
        mov byte ptr cs:s2,al
        cmp al,0c0h
        jb  sv_1
        cmp al,0e0h
        ja  sv_1
        mov byte ptr ds:[si-1],216
        mov word ptr cs:mv_chr,0a0h
        jmp sv_2
sv_1:       mov byte ptr ds:[si-1],241
        mov word ptr cs:mv_chr,3c0h
sv_2:       add si,word ptr cs:cols
        sub si,3
        ;
        lodsb
        mov byte ptr cs:s3,al
        mov byte ptr ds:[si-1],209
        inc si
        ;
        lodsb
        mov byte ptr cs:s4,al
        cmp al,0c0h
        jb  sv_3
        cmp al,0e0h
        ja  sv_3
        mov byte ptr ds:[si-1],210
        mov word ptr cs:mv_chr1,20h
        jmp sv_4
sv_3:       mov byte ptr ds:[si-1],242
        mov word ptr cs:mv_chr1,420h
sv_4:
 
        retn
;
movec:
        push    bp
        push    es
        push    ds
        cld
        call    ope
 
        mov bx,offset cs:msk_and
        mov ax,word ptr cs:bpc
        sub ax,word ptr cs:d_y
        mov word ptr cs:y_off,ax
        mov ax,0A000h
        mov es,ax
        mov ds,ax
        xor ax,ax
        mov di,1a60h
        mov al,byte ptr cs:s1
        mov cx,5
        shl ax,cl
        mov si,ax
        xor ax,ax
        mov al,byte ptr cs:s2
        shl ax,cl
        sub ax,si
        dec ax
        mov word ptr cs:chr2,ax
 
        mov bp,16
 
        mov cx,word ptr cs:bpc
mv_1:
        lodsb
        xchg    ah,al
        push    si
        add si,word ptr cs:chr2
        lodsb
        pop si
        cmp cx,word ptr cs:y_off
        ja  mv_2
        cmp bp,0
        jz  mv_2
        push    cx
 
        mov cx,word ptr cs:d_x
        xor dx,dx
        mov dh, byte ptr cs:[bx]
        shr dx,cl
        not dx
        and ax,dx
        xor dx,dx
        mov dh, byte ptr cs:[bx+16]
        shr dx,cl
        or  ax,dx
 
        pop cx
 
        inc bx
        dec bp
 
mv_2:
        mov byte ptr es:[di+03c0h],al
mv_chr      equ $ - 2
        xchg    ah,al
            stosb
        loop    mv_1
 
        xor ax,ax
        mov di,1a20h
        mov al,byte ptr cs:s3
        mov cx,5
        shl ax,cl
        mov si,ax
        xor ax,ax
        mov al,byte ptr cs:s4
        shl ax,cl
        sub ax,si
        dec ax
        mov word ptr cs:chr2,ax
        ;
        mov cx,word ptr cs:bpc
mv_11:
        lodsb
        xchg    ah,al
        push    si
        add si,word ptr cs:chr2
        lodsb
        pop si
 
        cmp bp,0
        jz  mv_21
        push    cx
 
        mov cx,word ptr cs:d_x
        xor dx,dx
        mov dh, byte ptr cs:[bx]
        shr dx,cl
        not dx
        and ax,dx
        xor dx,dx
        mov dh, byte ptr cs:[bx+16]
        shr dx,cl
        or  ax,dx
 
        pop cx
 
        inc bx
        dec bp
 
mv_21:
 
        mov byte ptr es:[di+03c0h],al
mv_chr1     equ $ - 2
        xchg    ah,al
            stosb
        loop    mv_11
 
mv_4:       call    clo
        pop ds
        pop es
        pop bp
        retn
chr2:       dw  ?
y_off:      dw  ?
;
ope:        push    si
        mov si,offset cs:open
        call    prgdev
        call    prgdev
        pop si
        retn
;
clo:        mov si,offset cs:close
        call    prgdev
        call    prgdev
        retn
;
prgdev:     clc
        lods    word ptr cs:[si]
        mov dx, ax
        lods    word ptr cs:[si]
        mov cx, ax
        cli
ll1:        lods    word ptr cs:[si]
        out dx, ax
        loop    ll1
        sti
        retn
 
coord:      lea di, y_end   ; хвост шаблончика координат
; чтобы выводить в знакоместах, CX и DX надо делить на 8 -> shr dx, 3
;   push    cx
;   mov ax,dx
    std     ; писать будем с хвоста, задом наперёд
    mov bx, 10  ; делитель
    mov ax, word ptr cs:[yy]
    call    cnv ; преобразуем Y
    dec di      ; пропускаем ':'
;   pop ax
    mov ax, word ptr cs:[xx]
    call    cnv ; преобразуем X
@2: cld
    push    cs
    pop ds
; Вывод в видеопамять
    mov cx, tpt_sz  ; длина шаблончика
    mov ax, 0B800h  ; видеосегмент
    mov es, ax
    mov di, (80*25-tpt_sz)*2 ;008Ch ; смещение в видеобуффере (80-tpt_sz)*2
    mov ah, 00000011B   ; color: cyan on black
    lea si, x
; цикл вывода
disp:
    lodsb
    stosw
    loop    disp
;   pop es
;   pop ds
    ret
 
; обработка кнопок
btn:    test    ax, 110b    ; левая кнопка?
    jz  @3
    xor cs:_l, 6Ch      ; да, перебрасываем флаг: 20 xor 6Ch = 'L' или пробел
@3: test    ax, 11000b  ; правая кнопка?
    jz  @4
    xor cs:_r, 72h  ; да, перебрасываем флаг: 20 xor 72h = 'R' или пробел
@4: test    bx, 1100000b    ; средняя кнопка?
    jz  @5
    xor cs:_m, 6Dh  ; да, перебрасываем флаг: 20 xor 6Dh = 'M' или пробел
@5: ret
; Преобразование числа в строку
;   es:di - endbuf
cnv:    call    @@1
    call    @@1
@@1:    div bl      ; делим на 10.
    xchg    ah, al
    add al, 30h     ; в ASCII
    stosb                   ; сохраняем
    shr ax, 8
    ret
;
open:       dw  3C4h, 2, 0402h, 0704h, 3CEh, 3, 0204h, 0005, 0006
close:      dw  3C4h, 2, 0302h, 0304h, 3CEh, 3, 0004, 1005h, 0E06h
 
msk_and:
        db  000h,000h,0E0h,0B0h,098h,08Ch,086h,083h,081h,087h,0B2h,0EBh,009h,00Fh,000h,000h; 0D2
        db  000h,000h,000h,040h,060h,070h,078h,07Ch,07Eh,078h,04Ch,004h,006h,000h,000h,000h; 0D3
 
rows:       dw  0       ; rows on screen
cols:       dw  0       ; cols * 2 ( bytes per line )
bpc:        dw  0       ; bytes per chr
d_x:        dw  0       ;
d_y:        dw  0
x   db '000:000'        ; шаблончик для вывода
y_end   = $ - 1
_l  db  20h     ;
_m  db  20h
_r  db  20h
tpt_sz  = $ - x
 
cptr:       dw  0       ; char ptr
        dw  0
 
s1      db  0       ; saved chars
s2      db  0
s3      db  0
s4      db  0
xpos        dw  0
ypos        dw  0
;public scr
;scr:       db  4096 dup(1)
$end$:
ddd ends
    end start

.model tiny
.code
.386
ORG 100h
START:
    mov ax,12h  ;640*480
    int 10h
 
    mov ax,1    ;показать курсор 
    int 33h
m1:
    mov dh,29   ;Y
    mov dl,1    ;X
    mov ah,2    ;установить курсор для строки
    xor bh,bh
    int 10h
 
    mov ax,3    ;получить положение курсора
    int 33h
push dx
    mov ax,cx
    call OutInt ;вывод на экран
    mov al,':'
    int 29h
pop ax
    call OutInt
 
    in al,60h   ; прочитать скан-код последнего символа,
    cmp al,81h  ; если это 81h (отпускание клавиши Esc),
    jnz short m1
 
    mov ax,3    ;текстовый режим
    int 10h
 
    ret     ;завершить программу
 
OutInt:
    mov cx,3
    mov bx,10 ; основание сс. 10 для десятеричной и т.п.
oi2:
    xor dx,dx
    div bx
    push dx
    loop oi2
 
    mov cx,3
oi3:
    pop ax
    add al,'0'
    int 29h
    loop oi3
 
    ret
 
end start