Аналог DIR

.286
.model tiny
.code
org     100h
start:  mov ah,4Ah      ;модифицируем назначенную память
        mov bx,100h     ;новый размер блока в параграфах
        int 21h         
        or bx,-1        ;требуемое число параметров для выполнения
        mov ah,48h      ;вделить блок памяти
        int 21h         ;возвращает в bx размер наибольшего доступного блока 
;памяти в параграфах
        mov ah,48h      ;вделить блок памяти, в bx действительно доступная память
        int 21h         ;возвращает в ах сегментный адрес выделенного блока
        mov es,ax       ;es:=new PSP
        mov ss,ax       ;ss:=new PSP
        xchg dx,ax      ;dx:=new PSP
        mov ah,26h      ;создать новый префикс программного сегмента
        int 21h         
        mov dx,offset filename
        mov di,80h      ;указатель на командную строку
        mov cx,(N+1)/2  ;копируем по два байта за раз, N округлен в большую 
;сторону к числу кратному два, поэтому добавочный movsb не нужен
        mov si,offset command_line
        rep movsw       ;создаем командную строку для запуска command.com
        mov ax,3D00h    ;открыть command.com на чтение
        int 21h
        xchg bx,ax      ;дескриптор файла в bx
        xor cx,cx       ;cx=dx=0
        xor dx,dx
        mov ax,4202h    ;установить файловый указатель на конец файла
        int 21h
        push ax         ;сохраним в стеке длину файла command.com
        mov ax,4200h    ;установить файловый указатель на начало файла
        int 21h
        mov dx,es       ;пересчитываем чему должен быть равен dx из расчета,
        add dx,10h      ;что cs*10h+dx=es*10h+100h
        mov cx,cs
        sub dx,cx
        shl dx,4        ;в dx адрес буфера, куда будет скопирован command.com
        pop cx          ;в сх число байтов для чтения 
        mov ah,3Fh      ;читаем command.com в буфер
        int 21h
        mov ah,3Eh      ;закрыть файл command.com
        int 21h
        mov ax,es       ;ds:=new PSP
        mov ds,ax       ;при старте СОМ-файла cs=ds=es=ss=PSP ip=100h
        push es         ;новое значение cs:=new PSP
        push 100h       ;новое значение ip:=100h
        retf            ;запускаем command.com для создания файла myfile.txt
filename db 'c:\windows\system32\cmd.exe',0;полный путь к command.com
command_line db N-1,'/c DIR',0Dh
N = $ - command_line
db 0; если N нечетное, то скопируется и добавочный нулевой символ 
end     start

; FASM code // dir emu
org  100h
jmp  start
 
crlf    db  13,10, '$'           ;
newDTA  db  45 dup('$')          ; область DTA
fName   db  '*.*',0              ; ищем все файлы
noFile  db  13,10,'-----------------------------------'
        db  13,10,'All file printed! Press any key...$'
 
start:
      mov   ah,1ah               ; создать DTA
      mov   dx,newDTA            ;
      int   21h                  ;
 
      mov   ah,4eh               ; искать файлы,
      mov   cx,10h               ;    ..включая папки.
      mov   dx,fName             ; маска для поиска
      int   21h                  ;
      jc    stop                 ; ошибка?
      call  printName            ; выводим имя на экран
 
find: mov   ah,4fh               ; искать сл.файл
      mov   dx,newDTA            ;
      int   21h                  ;
      jc    stop                 ;
      call  printName            ;
      jmp   find                 ;
 
stop: mov   ah,9                 ; нет больше файлов!
      mov   dx,noFile            ;
      int   21h                  ;
 
exit:                            ;
      xor   ax,ax                ; выход по клавише
      int   16h                  ;
      int   20h                  ;
 
;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
printName:                       ;
      mov   ah,9                 ;
      mov   dx,newDTA+30         ; в DTA+30 хранится имя файла
      int   21h                  ; выводим его на экран
      mov   dx,crlf              ; перевод строки
      int   21h                  ;
      mov   al,'$'               ; очищаем DTA для сл.имени
      mov   cx,13                ; 13 символов
      mov   di,newDTA+30         ;    ..от начала области имени
      rep   stosb                ; записываем маркеры конца для fn(9)
ret                              ;