Составить программу тестирования параллельного порта, к которому подключен матричный принтер

; Fasm code.........
org 100h
jmp start
 
mes0    db  13,10,' SCAN LPT DEVICE ----- [S:scan | Q:quit] ---'
        db  13,10,' ===========================================',13,10,' $'
mes1    db  13,10,'  LPT-1: $'
mes2    db  13,10,' -----------------------------'
        db  13,10,' Status: $'
mes3    db  13
        db  10,10,'    Bit: 7 - Busy      0=Error'
        db  13,10,'         6 - Return    0=OK'
        db  13,10,'         5 - Paper     0=OK'
        db  13,10,'         4 - On-line   0=Error'
        db  13,10,'         3 - Device    0=Error'
        db  13,10,'         2 - Reserved  0'
        db  13,10,'         1 - Reserved  0'
        db  13,10,'         0 - TimeOut   0=OK$'
 
mes4    db  13
        db  10,10,' Print Test-Page? y/n ...$'
string  db  13,10,' This is "TEST-PAGE'
        db  13,10,' ************************'
        db  13,10,' ABCDEF....0123456789','$'
len     =   $ - string           ; длина строки для печати
 
start:  mov   dx,mes0            ;
        call  message            ;
@cmd1:  xor   ax,ax              ; ждём команду юзера..
        int   16h                ;
        cmp   al,'Q'             ; Q - выход
        je    exit               ;
        cmp   al,'S'             ; S - поиск активных портов
        jne   @cmd1              ; игнор остальных клавиш
 
        mov   cx,3               ; всего LPT-портов в системе
        xor   bx,bx              ; начинаем с нулевого (LPT1)
@find:  mov   dx,mes1            ; мессага
        call  message            ;
        mov   dx,bx              ; DX - номер порта
        mov   ah,2               ; дать статус!
        int   17h                ;
        test  ah,1000b           ; проверим бит ошибки
        jnz   @okey              ; ОК - если бит не нуль (порт найден)
        mov   al,'0'             ; иначе: ошибка (выводим нуль)
        int   29h                ;
        inc   bx                 ; сл.порт..
        inc   byte[mes1+8]       ; меняем в мессаге № порта
        loop  @find              ; мотаем цикл СХ-раз..
        jmp   @begin             ; ошибка поиска! Обработаем её..
 
@okey:  call  PrintPage          ; порт нашёлся!
                                 ; Распечатываем тестовую страницу
@begin: push  ax                 ; в AH лежит статус порта. Запомним его..
        mov   dx,mes2            ;
        call  message            ;
        pop   bx                 ; выводим статус на экран в виде маски
        mov   cx,8               ; всего битов для вывода
@code:  xor   ax,ax              ;
        shld  ax,bx,1            ;
        or    al,30h             ;
        int   29h                ; выводим очередной бит на экран
        shl   bx,1               ; следующий бит..
        loop  @code              ; мотаем цикл СХ-раз..
 
        mov   dx,mes3            ; выводим описание битовой маски
        call  message            ;
 
exit:   xor   ax,ax              ;
        int   16h                ;
        int   20h                ; на выход!
 
:-----------------------------------------------------------------------
;ннннннннннннннннннн П Р О Ц Е Д У Р Ы ннннннннннннннннннннннннннннннннн
message: mov  ah,9               ;
         int  21h                ;
         ret                     ;
;---------------------------------------------------------------
PrintPage:                       ; Печать тестовой станицы
        push  ax                 ; запомним возвращённый статус порта
        mov   al,'1'             ; метка найденного принтера
        int   29h                ;
        mov   dx,mes4            ;
        call  message            ;
@cmd2:  xor   ax,ax              ; распечатать страницу?
        int   16h                ; yes/no
        cmp   al,'n'             ;
        je    @fuck              ; нет - молча выходим
        cmp   al,'y'             ;
        jne   @cmd2              ;
        xor   ax,ax              ; да - fn(0) INT-17h
        mov   si,string          ; адрес строки
        mov   cx,len             ; её длина
@prn:   lodsb                    ;
        int   17h                ; выводим строку по-символьно!
        loop  @prn               ;
@fuck:  pop   ax                 ; возвращаем статус порта
        ret                      ;