Графический режим в ассемблере. Создание эллипсоидной спирали

TITLE SPIRAL
;Программа построения спирали Архимеда
include pixels.inc ;подключить макросы вывода точки, осей и символа
.model small
.stack 100h
.data
fi dd 0.0 ;Начальное значение переменной угла.
delta dd 0.001 ;Шаг изменения угла.
xdiv2 dw 320 ;Координаты центра экрана по X.
ydiv2 dw 240 ;Координаты центра экрана по Y.
K dd 5.0 ;Коэффициент шага спирали.
xr dw 0 ;Координата выводимой точки по X.
yr dw 0 ;Координата выводимой точки по Y.
forcolor DB 00000010b ;Цвет спирали
Variant db 'Spiral_2_7_vitkov', '$' ;Поясняющая надпись.
.code
.486 ;Используем расширенную систему команд
;---------------Вывод пиксела---------------------------------------------
;CX-координата X (столбец), DX-координата Y (строка),
;AL-цвет пиксела
POINT PROC 
pusha
mov CX,xr ;Вычисляем координату х
add CX, xdiv2 ;в регистре CX.
mov DX, ydiv2 ;Вычисляем координату y
sub DX, yr ;в регистре DX.
mov AL, forcolor ;Задать цвет спирали.
mov BH, 0
mov AH,12 ;Вывести пиксел
int 10h ;средствами BIOS.
popa
ret
POINT ENDP
;-----------Закрашивание экрана цветом фона---------------------
;CX-координата X (столбец), DX-координата Y (строка),
;AL-цвет пиксела
FON PROC
pusha
mov CX, 0
mov DX, 0
mov AL, 00000001b ;Цвет фона.
mov BH, 0 ;Номер страницы.
c_1: mov AH, 12 ;Вывести пиксел
int 10h ;средствами BIOS.
inc CX 
cmp CX, 639
jne c_1
xor CX, CX
inc DX
cmp DX, 479
jne c_1
popa 
ret
FON ENDP
;===========Основная программа====================
start:
mov ax,@DATA
mov ds,ax 
xor ax,ax
mov CX, 43960 ;Количество итераций цикла
;(определяет число витков).
;----------------------------------------------------------------------------------
mov ah,0h ;Инициализация графического
mov al,12h ;режима 640х480.
int 10h
call FON ;Вызов процедуры закрашивания фона.
;-------Вывод строки Variant-------------------------------------------------
pusha
mov cx,17
mov bx,0
l3:
mov al,Variant[bx]
inc bx
OutCharG bl, 02h, 03h, al ;Вызов макроса. 
loop l3
popa
;---------рисуем оси-----------------------------------------------------------
AxleX ;Вызов макроса.
AxleY ;Вызов макроса.
;------Вычисляем формулу x=round(fi*K*cos(fi))----------------------
finit ;Инициализация сопроцессора. 
l1:
fld fi ;Загрузить угол fi в стек FPU.
fcos ;Вычислить cos(fi).
fld fi ;Загрузить угол fi в стек FPU. 
fmul K ;ST(0):=K*(ST(0))
fmul ;ST()):=(ST(0))*(ST(1))
frndint ;ST(0):=round(ST(0)) 
fistp word ptr xr ;Заносим X в переменную для вывода ;на экран
;------Вычисляем формулу y=round(fi*K*sin(fi))-----------------------
fld fi
fsin
fld fi
fmul K
fmul 
frndint
fistp word ptr yr ;Заносим Y в переменную для вывода ;на экран. 
call POINT
;---------Вычисляем новое значение угла fi----------------------------- 
fld delta
fld fi
fadd
fstp fi
loop l1 ;Повторить цикл пока (СХ) не равно 0.
;-----------------------------------------------------------------------------------
mov ah,1h ;Ожидание нажатия клавиши. 
int 21h
;-----------------------------------------------------------------------------------
mov ah,0h ;Перевод в Text Mode.
mov al,03h
int 10h
;-----------------------------------------------------------------------------------
exit:
mov ax,4C00h ;Стандартный выход.
int 21h 
END start