Отправка уведомления на почту при создании или изменении элементов справочника

Процедура УведомитьОСозданииНовогоСклада()   
    // Создаем запрос для получения email пользователя
    Запрос = Новый Запрос;
    Запрос.Текст =
            "ВЫБРАТЬ
            |   КонтактнаяИнформация.АдресЭП КАК АдресЭП
            |ИЗ
            |   Справочник.Пользователи.КонтактнаяИнформация КАК КонтактнаяИнформация
            |ГДЕ
            |   КонтактнаяИнформация.Ссылка = &Адресат";
    Запрос.УстановитьПараметр("Адресат", Справочники.Пользователи.НайтиПоНаименованию("ЗавСклад")); 
    Результат = Запрос.Выполнить().Выбрать();    
    Если Результат.Следующий() Тогда
        Письмо = Новый ИнтернетПочтовоеСообщение;
        Письмо.Тема = "Уведомление о создании нового склада";
        Письмо.Тексты.Добавить("Создан новый склад «" + ЭтотОбъект.Наименование + "»");
        Письмо.Получатели.Добавить(Результат.АдресЭП);
        РаботаСПочтовымиСообщениями.ОтправитьПисьмо(
            Справочники.УчетныеЗаписиЭлектроннойПочты.СистемнаяУчетнаяЗаписьЭлектроннойПочты,
            Письмо
        ); 
    КонецЕсли;     
КонецПроцедуры

Процедура УведомитьОСменеНаименованияСклада()
    // Создаем запрос для получения данных
    Запрос = Новый Запрос;
    Запрос.Текст = 
        "ВЫБРАТЬ
        |   ПользователиКонтактнаяИнформация.АдресЭП КАК АдресЭП
        |ПОМЕСТИТЬ ВТ_Пользователь
        |ИЗ
        |   Справочник.Пользователи.КонтактнаяИнформация КАК ПользователиКонтактнаяИнформация
        |ГДЕ
        |   ПользователиКонтактнаяИнформация.Ссылка = &Адресат
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |   Склады.Наименование КАК Наименование, 
        |   ВТ_Пользователь.АдресЭП КАК АдресЭП 
        |ИЗ
        |   Справочник.Склады КАК Склады,
        |   ВТ_Пользователь КАК ВТ_Пользователь
        |ГДЕ
        |   Склады.Ссылка = &Склад";   
    Запрос.УстановитьПараметр("Адресат", Справочники.Пользователи.НайтиПоНаименованию("ЗавСклад"));
    Запрос.УстановитьПараметр("Склад", ЭтотОбъект.Ссылка);
    РезультатЗапроса = Запрос.Выполнить();
    Выборка = РезультатЗапроса.Выбрать();
    Пока Выборка.Следующий() Цикл   
        // Проверка на предмет изменения наименования склада 
        Если Выборка.Наименование <> ЭтотОбъект.Наименование Тогда      
            Письмо = Новый ИнтернетПочтовоеСообщение;        
            Письмо.Тема = "Уведомление о смене наименования склада";       
            Письмо.Тексты.Добавить("Наименование склада «" + Выборка.Наименование + "» изменено на «" + ЭтотОбъект.Наименование + "»");        
            Письмо.Получатели.Добавить(Выборка.АдресЭП);              
            РаботаСПочтовымиСообщениями.ОтправитьПисьмо(
                Справочники.УчетныеЗаписиЭлектроннойПочты.СистемнаяУчетнаяЗаписьЭлектроннойПочты, 
                Письмо
            );        
        КонецЕсли;     
    КонецЦикла;
КонецПроцедуры

Процедура ПередЗаписью(Отказ)
    ...
    // Проверка на предмет изменения наименования и создания нового склада
    Если ЭтоНовый() Тогда
        УведомитьОСозданииНовогоСклада();
    Иначе  
        УведомитьОСменеНаименованияСклада();
    КонецЕсли;
КонецПроцедуры