Генератор паролей (вариант №2)

&НаКлиенте
Процедура Сгенерировать(Команда)
    СгенерироватьНаСервере();
КонецПроцедуры
 
&НаСервере
Процедура СгенерироватьНаСервере()
    ОбъектОбработки = РеквизитФормыВЗначение("Объект");
    
    Длина = ОбъектОбработки.ДлинаПароля;
    Количество = ОбъектОбработки.КоличествоПаролей;
    
    Если Длина < 8 Тогда
        ВызватьИсключение "Минимальная длина пароля не может быть меньше 8 знаков!";
    КонецЕсли;  
    
    Если Длина > 50 Тогда
        ВызватьИсключение "Максимальная длина пароля не может быть больше 50 знаков!";
    КонецЕсли;             
          
    Если Количество <= 0 Тогда
        ВызватьИсключение "Количество паролей должно быть больше 0!";
    КонецЕсли;
    
    Алфавит = "";
    
    Если ОбъектОбработки.Буквы Тогда
        Алфавит = Алфавит + "ABCDEFGHJKLMNOPQRSTUVWXYZabcdefghijkmnopqrstuvwxyz";
    КонецЕсли;
    
    Если ОбъектОбработки.Цифры Тогда
        Алфавит = Алфавит + "023456789";
    КонецЕсли;
    
    Если ОбъектОбработки.Символы Тогда
        Алфавит = Алфавит + "!@#$%^&*()-_=+[]{};:,.<>?";
    КонецЕсли;
    
    Если ПустаяСтрока(Алфавит) Тогда
        ВызватьИсключение "Нужно выбрать хотя бы один тип символов (Буквы, Цифры или Символы)!";
    КонецЕсли;
    
    ОбъектОбработки.Пароли.Очистить();
    
    Для Н = 1 По Количество Цикл
        НовыйПароль = СгенерироватьПароль(Длина, Алфавит);
        НоваяСтрока = ОбъектОбработки.Пароли.Добавить();
        НоваяСтрока.Пароль = НовыйПароль;
    КонецЦикла;
    
    ЗначениеВРеквизитФормы(ОбъектОбработки, "Объект");
КонецПроцедуры
 
&НаСервере
Функция СгенерироватьПароль(Длина, Алфавит)
    Результат = "";
    Генератор = Новый ГенераторСлучайныхЧисел();
    МаксИндекс = СтрДлина(Алфавит) - 1;
    
    Для Н = 1 По Длина Цикл
        Индекс = Генератор.СлучайноеЧисло(0, МаксИндекс);
        Результат = Результат + Сред(Алфавит, Индекс + 1, 1);
    КонецЦикла;
    
    Возврат Результат;
КонецФункции
 
&НаСервере
Процедура ПриОткрытииНаСервере()
    Объект.ДлинаПароля = 8;
    Объект.КоличествоПаролей = 1; 
    Объект.Буквы = Истина;
    Объект.Цифры = Истина;
    Объект.Символы = Истина;
КонецПроцедуры
 
&НаКлиенте
Процедура ПриОткрытии(Отказ)
    ПриОткрытииНаСервере();
КонецПроцедуры