Переключение видеостраниц при нажатии левой кнопки мыши

mov         ah, 01h ; ввести символ с клавиатуры
int     21h     ; вызов функции DOS 
jmp     exit

;Заполнить страницу видеопамяти символом xi ((x0 =’a’, x1 =’b’ и тд)
;с разными атрибутами на каждой странице. Обеспечить переключение
;видеостраниц при нажатии левой кнопки мыши.
LOCALS
 
.model small
 
.stack 100h
 
.data
        BufSize                         equ     80*25
        clBlue                          equ     01h
        clRed                           equ     04h
        clWhite                         equ     07h
        ;буфер экрана
        ScreenBuffer                    db      80*25 dup (?)
        ;сообщения программы
        CrLf                            db      0Dh, 0Ah, '$'
        msgPressAnyKey                  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        msgErrorFileOpen                db      'File open error.', '$'
        msgErrorFileRead                db      'File read error.', '$'
        msgMouseFault                   db      'The mouse or mouse driver was not detected.', 13, 10, '$'
 
        ;Константы событий "мыши"
        MouseEvent_None                 equ     0000h   ;Удалить пользовательский обработчик
        MouseEvent_Move                 equ     0001h   ;любое перемещение
        MouseEvent_PressLeftButton      equ     0002h   ;нажатие левой кнопки
        MouseEvent_ReleaseLeftButton    equ     0004h   ;отпускание левой кнопки
        MouseEvent_PressRightButton     equ     0008h   ;нажатие правой кнопки
        MouseEvent_ReleaseRightButton   equ     0010h   ;отпускание правой кнопки
        MouseEvent_PressMiddleButton    equ     0020h   ;нажатие средней кнопки
        MouseEvent_ReleaseMiddleButton  equ     0040h   ;отпускание средней кнопки
 
        MouseInitOk                     equ     0FFFFh  ;инициализация мыши - успешна
        MouseInitFault                  equ     0000h   ;инициализация мыши - мышь или драйвер мыши не установлены
 
        MouseButtons_Any                equ     0000h   ;количество кнопок у мыши - отлично от 2 и 3
        MouseButtons_2                  equ     0002h   ;количество кнопок у мыши - 2
        MouseButtons_2_                 equ     0FFFFh  ;количество кнопок у мыши - 2
        MouseButtons_3                  equ     0003h   ;количество кнопок у мыши - 3
 
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
 
        ;заполнение текста для видеостраниц
        mov     cx,     80*25
        lea     si,     ScreenBuffer
@@StartChar:
        mov     al,     'a'
@@FillBuffer:
        cmp     al,     'z'
        ja      @@StartChar
        mov     [si],   al
        inc     si
        inc     al
        loop    @@FillBuffer
        ;заполнение видеостраниц
        mov     cx,     4
@@FillPages:
        push    cx
        mov     ax,     1300h
        mov     bh,     cl
        dec     bh
        mov     bl,     cl
        mov     dx,     0000h
        lea     bp,     ds:ScreenBuffer
        push    ds
        pop     es
        mov     cx,     80*25-1
        int     10h
        pop     cx
        loop    @@FillPages
        ;попытка инициализации мыши
        call    MouseInit
        cmp     ax,     MouseInitOk
        je      @@MouseInitOk
        ;если инициализация не удалась - вывести сообщение
        ;и завершить программу
        mov     ah,     09h
        lea     dx,     msgMouseFault
        int     21h
        jmp     @@Exit
 
@@MouseInitOk:
        ;установить пользовательский обработчик событий "мыши"
        push    es
        mov     ax,     seg MyMouseHandler
        mov     es,     ax
        mov     dx,     offset  MyMouseHandler
        mov     cx,     MouseEvent_PressLeftButton
        call    MouseSetHandler
        pop     es
 
        call    MouseShowCursor
 
 
@@WaitKeyPressed:
        mov     ah,     00h
        int     16h
 
        ;завершение работы с "мышью"
        ;спрятать курсор
        call    MouseHideCursor
        ;удалить пользовательский обработчик прерывания
        mov     cx,     MouseEvent_None
        call    MouseSetHandler
 
        mov     ah,     0
        mov     al,     03h
        int     10h
 
@@Exit:
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
;Инициализация работы с "мышью"
;Выполняется аппаратный и программный сброс мыши и драйвера
;вход
; - нет
;выход
;ax - результат инициализации
;   - 0000h, если мышь или драйвер мыши не установлены
;   - FFFFh, если драйвер и мышь установлены
;bx - число кнопок
;   - 0002 или FFFF - две
;   - 0003 - три
;   - 0000 - другое количество
MouseInit       proc
        mov     ax,     0000h
        int     33h
        ret
MouseInit       endp
 
;Показать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseShowCursor proc
        push    ax
        mov     ax,     0001h
        int     33h
        pop     ax
        ret
MouseShowCursor endp
 
;Спрятать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseHideCursor proc
        push    ax
        mov     ax,     0002h
        int     33h
        pop     ax
        ret
MouseHideCursor endp
 
;Определение курсора мыши в текстовом режиме
;вход
;BX = hardware/software text cursor
;     0000h software ( (char/attr AND CX) XOR DX)
;       CX = screen mask
;       DX = cursor mask
;     0001h hardware
;       CX = start scan line
;       DX = end scan line
;выход
; - нет
MouseDefineTextCursor   proc
        push    ax
        mov     ax,     000Ah
        int     33h
        pop     ax
        ret
MouseDefineTextCursor   endp
 
;Установить/удалить обработчик событий от "мыши"
;вход
;ES:DX = адрес обработчика
;СХ = условие вызова
;   бит 0 — любое перемещение мыши
;   бит 1 — нажатие левой кнопки
;   бит 2 — отпускание левой кнопки
;   бит 3 — нажатие правой кнопки
;   бит 4 — отпускание правой кнопки
;   бит 5 — нажатие средней кнопки
;   бит 6 — отпускание средней кнопки
;СХ = 0000h — отменить обработчик;выход
;выход
; - нет
MouseSetHandler proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    es
 
        mov     ax,     000Ch
        int     33h
 
        pop     es
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
MouseSetHandler endp
 
;Обработчик событий "мыши"
;вход
;АХ содержит условие вызова,
;ВХ - состояние кнопок,
;СХ, DX - X- и Y-координаты курсора,
;SI, DI - счетчики последнего перемещения по горизонтали и вертикали
;      (единицы измерения для этих счетчиков - мики, 1/200 дюйма),
;DS - сегмент данных драйвера мыши.
;выход
; - нет
MyMouseHandler  proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
        push    es
 
        ;спрятать курсор
        call    MouseHideCursor
 
        ;получение информации о видеорежиме
        mov     ah,     0Fh
        int     10h
        ;изменение видеостраницы
        inc     bh
        and     bh,     011b
        mov     ah,     05h
        mov     al,     bh
        int     10h
        ;показать курсор
        call    MouseShowCursor
 
@@Exit:
        pop     es
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        retf
MyMouseHandler  endp
 
end     main