Резидентный обработчик прерывания 21h (по книге Калашникова)

CSEG segment
assume cs: CSEG, ds: CSEG, es: CSEG, ss: CSEG
org 100h
    Begin:      
        jmp Init
        Int_21h_proc proc
            cmp ah, 9h
            je Ok_09h
            jmp dword ptr cs:[Int_21h_vect]
            Ok_09h:
                push ds
                push dx
                push cs
                pop ds
                mov dx, offset String_1
                pushf
                call dword ptr cs:[Int_21h_vect]
                pop dx
                pop ds
            iret
            Int_21h_vect dd ?
            String_1 db 'No!!! This is MY string!!!$'
        Int_21h_proc endp
 
        
        Init:
            mov ah, 35h
            mov al, 21h
            int 21h
            mov word ptr Int_21h_vect, bx
            mov word ptr Int_21h_vect + 2, es
            mov ah, 25h
            mov al, 21h
            mov dx, offset Int_21h_proc
            int 21h
            mov dx, offset Init
            int 27h
        CSEG ends
    end Begin

.286
CSEG segment
assume cs: CSEG, ds: CSEG, es: CSEG, ss: CSEG
org 100h
     Begin:
        push 0
        pop es
        mov bx, es: [21h*4]
        mov es, es: [21h*4+2]
        mov word ptr cs: [Int_21h_vect], bx
        mov word ptr cs: [Int_21h_vect+2], es
        mov ah, 9
        mov dx, offset String
        pushf
        call dword ptr [Int_21h_vect]
        int 21h
        int 20h
        
        Int_21h_vect dd ?
        String db 'My string!!!', 0Ah, 0Dh, '$'
        CSEG ends
    end Begin

CSEG segment
assume cs:CSEG, ds:CSEG, es:CSEG, ss:CSEG
org 100h
 
Start:
    jmp Init
Int_21h_proc proc
    cmp ah,9        ;Проверим: это функция 09h?
    je Ok_09                ;Если так, то на метку Ok_09 
    jmp dword ptr cs:[Int_21h_vect]
Ok_09:
    push ds         ;Сохраним регистры
    push dx
    push cs         ;Адрес строки должен быть в DS:DX
    pop ds
    mov dx,offset My_string
    pushf           ;Так надо! Позже рассмотрим
    call dword ptr cs:[Int_21h_vect]
    pop dx          ;Восстановим использованные регистры
    pop ds
    iret            ;Продолжим работу (выйдем из прерывания)
Int_21h_vect dd ?
My_string db 'My string!$'
int_21h_proc endp
Init:
    mov ah,35h  ;AH содержит номер функции (это понятно)
    mov al,21h  ;AL указывает номер прерывания, адрес (или вектор)
    int 21h     ;Теперь в ES:BX адрес (вектор) 21h прерывания
    mov word ptr Int_21h_vect,bx
    mov word ptr Int_21h_vect+2,es  ;! Обратите внимание на форму записи
    mov ax,2521h
    mov dx,offset Int_21h_proc  ;DX должен указывать на наш
    int 21h
    mov dx,offset Init
    int 27h
CSEG ends
end Start

.286
CSEG segment
assume cs: CSEG, ds: CSEG, es: CSEG, ss: CSEG
org 100h
     Begin:
        push dx
        push ax
        
        mov dx, 050Fh
        xor ax, ax
        xchg dh, al
        mov di, ax
        shl ax, 6
        shl di, 4
        add di, ax
        add di, dx
        shl di, 1
        
        push 0B800h
        pop es
        mov si, offset String
        mov cx, offset Finish - offset String
        mov ah, 0Eh
        Metka:
            lodsb 
            stosw
            dec cx
            cmp cx, 0
        jne Metka
        
        pop ax
        pop dx
        int 20h
        
        String db 'Hello!!!'
        Finish equ $
        CSEG ends
    end Begin