Обработчик прерывания int 21h (по книге Калашникова)

CSEG segment
 org 100h
  Start:
   ;Переходим на метку инициаллизации. Нам нужно будет перехватить прерывание int 21h, а также оставить программу резидентной в памяти
   
   jmp Init
   
   ; Ниже идет код обработки прерывания 21h (он будет резидентный) .После того ,как процедура выйдет , процедура int_21h_proc останется в памяти и будет контроллировать функцию 09 прерывания 21h.
   
   int_21h_proc proc
   cmp ah,9   ;проверим , это функция 09h ?
   je Ok_09
   
   ; Если нет , перейдем  на оригинальный обработчик 21h. На метку Ok_09 программа уже не вернется
   
   jmp dword ptr cs:[int_21h_vect]
   
   Ok_09:
   push ds; сохраняем регистры
   push dx;
   push cs; Адрес строки должен быть в ds:dx
   pop ds
   
   ;выводим нашу строку (my_string), вмето той, которую должна была вывести программа, вызывающая 21h- прерывание
   
   mov dx,offset my_string
   pushf; эта инструкция здесь необходима
   call dword ptr cs:[int_21h_vect] 
   
   pop dx; Восстановим используемые регистры
   pop ds
   iret; продолжим работу, выйдем из  прерывания
   ;программа ,выводящая строку, считает , что на экране было выведено ее сообщение. Но на самом деле это не так
   
   ;переменная для хранения оригинального обработчика 21h
   int_21h_vect dd ?
   
   my_string db ' Perehvat !$'
   int_21h_proc endp
   
   ;Со следующей метки нашей программы уже не будет в памяти (это нерезидентная часть).
   ; она затрется после выхода(после прерывания 27h)
   
   Init:
   ; установим наш обработчик (int_21h_proc) (адрес нашего обработчика) на прерывние 21h
   ;Но прежде нужно запомнить оригинальный адрес этого прерывания . Для этого используется функция 35h прерывания 21h:
   
   ; ah содержит номер функции
   mov ah,35h ; получаем оригинал
   ;al указывает номер прерывания, адрес (вектор) ,которого нужно получить
   
   mov al,21h
   int 21h
   ;теперь в es:bx адрес (вектор) прерывания 21h (es - сегмент bs-смещение):
   
   mov word ptr int_21h_vect,bx; сохраняем в переменную
   mov word ptr int_21h_vect+2,es
   
   ;адрес сохранили, теперь обрабатываем прерывание:
   mov ax,2521h
   mov dx,offset int_21h_proc ;ds:dx  должны указывать на наш обработчик (т.е int_21h_proc)
   int 21h
   
   ;Теперь если какая-то программа вызовет int 21h, то вначале компъютер попадает на обработчик int_21h_proc.
   ;Осталось завершить программу. оставив ее резидентной в памяти (чтобы никто не затер разработчик, иначе комп висанет)
   
   mov dx,offset Init
   int 27h
   
   ;Прерывание int 27h выходит в ДОС (как 20h) , при этом оставив нашу программу резидентной,
   ;dx должен указывать на последний байт, оставшийся в памяти (это как раз метка Init).То есть в памяти
   ;остается от 000h до адреса по которому метка Init
   
   CSEG ends
   end Start

CSEG segment
assume CS:CSEG, DS:CSEG, ES:CSEG, SS:CSEG
org 100h
 
Begin:
    mov ah,9
    mov dx,offset String
    int 21h
         mov ax,10h
         int 16h
    int 20h
 
String db 'Stroka.$'  ;Пробуем вывести это строку
 
CSEG ends
end Begin

CSEG segment
assume cs:CSEG, ds:CSEG, ss:CSEG, es:CSEG
org 100h
 
Begin:
       jmp Init ;На метку инициализации 
 
 
; === Процедура обработки 10h прерывания ===
Int_10h_proc proc
      pushf ;Сохраним флаги в стеке, т.к. они поменяются...
 
      cmp ax,8899h  ;Проверим на повторную загрузку в память (см. ниже)
      jne Next_test ;Если не проверка, то смотрим дальше... 
 
      xchg ah,al    ;Меняем местами AH и AL (признак того, что мы в памяти
            ;что-то вроде ответного сигнала)
      popf  ;Выровним стек
      iret  ;Выйдем из прерывания (вернемся в нашу программу)
            ;AX теперь равен 9988h !!!
 
Next_test:
      cmp ah,88h    ;Это вызов нашей функции?
      jne Go_10h    ;Если нет - уйдем в оригинальный обработчик 10h 
 
      push es       ;Сохраним ES...
 
      mov ax,0B800h ;...и занесем в него сегмент 0-ой страницы дисплея
      mov es,ax
 
      xor di,di     ;Подготвимся к чистке экрана (равносильно mov di,0)
      mov cx,2000   ;Просто "забьем" его пробелами.
      mov ax,0720h  ;Будем заносить: код цвета (07) / символ пробела (20h)
      rep stosw     ;"Забиваем"... Очень быстро...
 
      mov di,1014   ;Будем выводить вот отсюда (примерно центр экрана)
      mov ah,14     ;С такими атрибутами (светло-желтый)
 
Next_sym:
      lodsb     ;Заносим в AL очередной символ (один байт, т.к. lodsB),
            ;Расположенный по адресу DS:SI, увеличив затем SI
            ;на единицу
 
      cmp al,0      ;Конец строки?
      jz Stop_out   ;Да - на выход... 
 
      stosw ;Заносим по адресу ES:DI значение из AX и увеличиваем DI на 2
        ;Здесь заносим слово, т.к. stosW, поэтому на два и
        ;увеличивается значение DI
 
      jmp short Next_sym ;Следующий символ... 
             ;SHORT (короткий) - делает в некоторых случаях
             ;команду jmp на один байт короче.
             ;Работает ТОЛЬКО в том случае, если между меткой
             ;и jmp расстояние не более 127 байт!
 
Stop_out:
      pop es    ;Если достигли конца строки, то восстановим регистры,
      popf  ;выровнив стек...
      iret  ;...и выйдем из прерывания
 
Go_10h:
      popf  ;Выровним стек
      jmp dword ptr cs:[Int_10h_vect]   ;"Прыгаем" на оригинальный обработчик
 
Int_10h_vect dd ? ;Здесь хранится адрес оргинального обработчика
Int_10h_proc endp
 
 
; ===============================================================
; Инициализация (подготовка и настройка резидента)
Init:
       mov ax,8899h ;Проверим, в памяти ли мы уже или еще нет
       int 10h      ;8899h - наш позывной
       cmp ax,9988h ;Отозвался обработчик (AH/AL должены поменяться местами)?
       jne Set_resident
 
       mov ah,9     ;Если в памяти, то выведем соответствующее сообщение
       mov dx,offset In_memory ;Зачем нас двое в памяти?
       int 21h
 
       ret      ;...И вернемся в DOS
 
 
Set_resident:       ;Если нас в памяти нет, то установим резидент
       mov ax,3510h
     int 21h        
[B]; Зачем здесь 21 прерывание ,если идет перехвыт 10го , или ф-я 35h неотъемлема от прерывния 21h для перехвата?[/B]
 
;Получим и сохраним адрес (вектор) 10h прерывания
       mov word ptr Int_10h_vect,bx ;Вначале младшее слово (смещение)
       mov word ptr Int_10h_vect+2,es   ;Затем старшее (сегмент)
 
       mov ax,2510h
       mov dx,offset Int_10h_proc
       int 21h      ;"Повесим" нашу процедуру на 10h прерывание
 
       mov dx,offset Init
       int 27h      ;Оставим программу резидентной в памяти.
 
In_memory db 'Мы уже в памяти!!!!$'
 
CSEG ends
end Begin

 ...
   push ds; сохраняем регистры
   push dx;
   push cs; Адрес строки должен быть в ds:dx
   pop ds
   mov dx,offset my_string
...

CSEG segment
org 100h
Begin:
        
mov ax,3         
int 10h     
 
mov ax,0B800h
mov es,ax   
mov di,0
mov al,1
mov ah,31
mov es:[di],ax
        
mov ah,10h  
int 16h
    
int 20h
 
CSEG ends
end Begin