Создание пользовательского обработчика прерывания, определяющего наименьшее значение в массиве

.386
 
volnistii segment use16
 
 
volnistii ends
 
skajida segment use16
 
assume ds:volnistii,cs:skajida
 
ahahah: mov dx,volnistii
 
    mov ds,dx
 
    
 
    int 6eh
 
skajida ends
 
end ahahah

.386
 
volnistii segment use16
 
mass db 1,-2,34,-40,14,23,-31,0
 
 
 
volnistii ends
 
skajida segment use16
 
assume ds:volnistii,cs:skajida
 
ahahah: mov dx,volnistii
 
    mov ds,dx
 
    
    mov si,0
    mov di,1
 
     m1:mov al,ds:mass[si]          ;до
    cmp ds:mass[di],al
    jl short levii
    mov bh,al
    inc si
    inc di
    cmp si,8
        ja short end
    jmp short m1
 
 
  levii:mov bh,ds:mass[di]
    inc si
    inc di
    cmp si,8
        ja short end
    jmp short m1
 
 
 
 
 
    end:mov ah,4ch
    int 21h

mov ah, 35h
mov al, 6Eh
int 21h

volnistii   segment use16
    mass    dw  1,-2,34,-40,14,23,-31,0
    len dw  ($-mass)/2
volnistii ends
 
skajida     segment use16
 
assume ds:volnistii,cs:skajida
 
ahahah:
    mov dx, volnistii
    mov     ds, dx
 
    lea dx, mass
    mov cx, len
    call    ArrayMin
 
    call    Show_AX
 
 
Exit:
    mov ax, 4c00h
    int     21h
 
;на входе:
;ds:dx - адрес массива
;cx    - длина массива
;на выходе
;ax - минимальный элемент
ArrayMin    proc
    push    bx
    push    cx
    push    dx
    push    si
    push    di
 
    mov ax, 0
    ;если массив пустой - выход
    jcxz    Break
    mov si, dx
    mov ax, [si]    ;Min:=A[0]
    dec cx
    ;если в массиве единственный элемент
    jcxz    Break
 
    add si, 2
 
ForI:               ;for i:=1 to N-1
    cmp ax, [si]    ;  if Min>A[i] then
    jle NextI
    mov ax, [si]    ;    Min:=A[i]
NextI:
    add si, 2
    loop    ForI
 
Break:
    pop di
    pop si
    pop dx
    pop cx
    pop bx
    ret
ArrayMin    endp
 
; выводит знаковое 16-разрядное число из регистра AX на экран
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    di
 
        mov     cx,     10
        xor     di,     di  ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax,     ax
        jns     @@Conv
        push    ax
        mov     dx,     '-'
        mov     ah,     2   ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx,     dx
        div     cx              ; dl = num mod 10
        add     dl,     '0'     ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стек
        or      ax,     ax
        jnz     @@Conv
        ; выводим из стека на экран
@@Show:
        pop     dx              ; dl = очередной выводимый символ
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
 
skajida     ends
end ahahah

volnistii       segment use16
        mass    dw      1,-2,34,-40,14,23,-31,0
        len     dw      ($-mass)/2      ;длина массива
 
        int6Eold        dd      ?       ;адрес исходного вектора 6E
volnistii ends
 
_stack  segment stack
        db      1024 dup(?)
_stack  ends
 
 
skajida         segment use16
 
assume ds:volnistii,cs:skajida
 
ahahah:
        mov     dx,     volnistii
        mov     ds,     dx
 
        ;сохранение исходного вектора прерывания
        mov     ah,     35h     ;функция получения вектора
        mov     al,     6Eh     ;номер вектора
        int     21h
 
        mov     word ptr[int6Eold+2],   es      ;сохраняем сегмент
        mov     word ptr[int6Eold],     bx      ;сохраняем смещение
        ;установка собственного вектора прерывания
        push    ds                      ;сохраняем ds
        mov     dx,     offset ArrayMin ;смещение для процедуры в dx
        mov     ax,     seg ArrayMin
        mov     ds,     ax
        mov     ah,     25h             ;функция установки вектора
        mov     al,     6Eh             ;номер вектора
        int     21h                     ;меняем прерывание
        pop     ds               ;восстанавливаем ds
 
        ;вызов пользовательского прерывания
        lea     dx,     mass
        mov     cx,     len
        int     6Eh
        ;печать результатов
        call    Show_AX
        ;восстановление исходного вектора прерывания
        push    ds                      ;сохраняем ds
        lds     dx,     int6Eold
        mov     ah,     25h             ;функция установки вектора
        mov     al,     6Eh             ;номер вектора
        int     21h                     ;меняем прерывание
        pop     ds                      ;восстанавливаем ds
 
Exit:
        mov     ax,     4c00h
        int     21h
 
;на входе:
;ds:dx - адрес массива
;cx    - длина массива
;на выходе
;ax - минимальный элемент
ArrayMin        proc
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     ax,     0
        ;если массив пустой - выход
        jcxz    Break
        mov     si,     dx
        mov     ax,     [si]    ;Min:=A[0]
        dec     cx
        ;если в массиве единственный элемент
        jcxz    Break
 
        add     si,     2
 
ForI:                           ;for i:=1 to N-1
        cmp     ax,     [si]    ;  if Min>A[i] then
        jle     NextI
        mov     ax,     [si]    ;    Min:=A[i]
NextI:
        add     si,     2
        loop    ForI
 
Break:
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        iret
ArrayMin        endp
 
; выводит знаковое 16-разрядное число из регистра AX на экран
; входные данные:
; ax - число для отображения
Show_AX proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    di
 
        mov     cx,     10
        xor     di,     di      ; di - кол. цифр в числе
 
        ; если число в ax отрицательное, то
        ;1) напечатать '-'
        ;2) сделать ax положительным
        or      ax,     ax
        jns     @@Conv
        push    ax
        mov     dx,     '-'
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        pop     ax
 
        neg     ax
 
@@Conv:
        xor     dx,     dx
        div     cx              ; dl = num mod 10
        add     dl,     '0'     ; перевод в символьный формат
        inc     di
        push    dx              ; складываем в стек
        or      ax,     ax
        jnz     @@Conv
        ; выводим из стека на экран
@@Show:
        pop     dx              ; dl = очередной выводимый символ
        mov     ah,     2       ; ah - функция вывода символа на экран
        int     21h
        dec     di              ; повторяем пока di<>0
        jnz     @@Show
 
        pop     di
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Show_AX endp
 
skajida         ends
end     ahahah