Рисование прямой, параллельной одной из осей координат, при помощи мыши

.model small, Pascal
 
.stack 100h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgPressAnyKey  db      'Press any key to exit...', '$'
        ;Параметры курсоров мыши
        ;Курсор - перекрестие
        MouseCursor_Cross               dw      0FFFFh, 0FFFFh, 0FFFFh, 0FFFFh  ;screen mask (AND mask)
                                        dw      0FFFFh, 0FFFFh, 0FFFFh, 0FFFFh
                                        dw      0FFFFh, 0FFFFh, 0FFFFh, 0FFFFh
                                        dw      0FFFFh, 0FFFFh, 0FFFFh, 0FFFFh
                                        dw      00100h, 00100h, 00100h, 00000h  ;cursor mask (XOR mask)
                                        dw      00100h, 00100h, 00000h, 0ED6Eh
                                        dw      00000h, 00100h, 00100h, 00000h
                                        dw      00100h, 00100h, 00100h, 00000h
                                        dw      7                               ;column of cursor hot spot in bitmap (-16 to 16)
                                        dw      7                               ;row of cursor hot spot (-16 to 16)
 
        MouseInitOk                     equ     0FFFFh  ;инициализация мыши - успешна
        MouseInitFault                  equ     0000h   ;инициализация мыши - мышь или драйвер мыши не установлены
 
        MouseButtons_Any                equ     0000h   ;количество кнопок у мыши - отлично от 2 и 3
        MouseButtons_2                  equ     0002h   ;количество кнопок у мыши - 2
        MouseButtons_2_                 equ     0FFFFh  ;количество кнопок у мыши - 2
        MouseButtons_3                  equ     0003h   ;количество кнопок у мыши - 3
 
        ;сообщения программы
        msgMouseFault                   db      'The mouse or mouse driver was not detected.', 13, 10, '$'
        ;
        LineColor                       dw      4
;.data?
        Xbegin                          dw      ?
        Ybegin                          dw      ?
        Xfinish                         dw      ?
        Yfinish                         dw      ?
 
.code
 
;----------------------------------------------
;вызовы функций работы с мышью обернуты в макросы
;----------------------------------------------
;Инициализация работы с "мышью"
;Выполняется аппаратный и программный сброс мыши и драйвера
;вход
; - нет
;выход
;ax - результат инициализации
;   - 0000h, если мышь или драйвер мыши не установлены
;   - FFFFh, если драйвер и мышь установлены
;bx - число кнопок
;   - 0002 или FFFF - две
;   - 0003 - три
;   - 0000 - другое количество
MouseInit       macro
        mov     ax,     0000h
        int     33h
endm
 
;Показать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseShowCursor macro
        push    ax
        mov     ax,     0001h
        int     33h
        pop     ax
endm
 
;Спрятать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseHideCursor macro
        push    ax
        mov     ax,     0002h
        int     33h
        pop     ax
endm
 
;установить курсор мыши в графическом режиме
;Определение курсора мыши в графическом режиме
;int 33h ax=0009h:
;BX = column of cursor hot spot in bitmap (-16 to 16)
;CX = row of cursor hot spot (-16 to 16)
;ES:DX -> mask bitmap
;Format of mouse mask bitmap:
;Offset Size            Description
;00h    16 WORDs        screen mask
;10h    16 WORDs        cursor mask
;Note: Each word defines the sixteen pixels of a row, low bit rightmost
MouseSetCursor  macro   Cursor
        push    ax
        push    bx
        push    cx
        push    es
 
        mov     bx,     word ptr [Cursor+64]
        mov     cx,     word ptr [Cursor+66]
        mov     ax,     seg Cursor
        mov     es,     ax
        mov     dx,     offset [Cursor]
        mov     ax,     0009h
        int     33h
 
        pop     es
        pop     cx
        pop     bx
        pop     ax
endm
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;попытка инициализации мыши
        MouseInit
        cmp     ax,     MouseInitOk
        je      @@MouseInitOk
        ;если инициализация не удалась - вывести сообщение
        ;и завершить программу
        mov     ah,     09h
        lea     dx,     msgMouseFault
        int     21h
        jmp     @@Exit
 
@@MouseInitOk:
        ;установка графического режима
        mov     ax,     0013h
        int     10h
        ;установка формы курсора в графическом режиме
        MouseSetCursor  MouseCursor_Cross
        ;показать курсор
        MouseShowCursor
@@WaitForStartPoint:
        mov     ax,     0003h   ;RETURN POSITION AND BUTTON STATUS
        int     33h
        and     bx,     0001h   ;проверка нажатия ЛКМ
        jz      @@WaitForStartPoint
        ;для графического видеорежима 13h нужно
        ;разделить на 2 координату X курсора
        shr     cx,     1
        mov     [Xbegin],       cx
        mov     [Ybegin],       dx
 
        MouseHideCursor
        mov     ah,     0Ch
        mov     al,     byte ptr [LineColor]
        mov     bh,     0
        mov     cx,     [Xbegin]
        mov     dx,     [Ybegin]
        int     10h
        MouseShowCursor
 
@@WaitForReleaseButton:
        mov     ax,     0003h   ;RETURN POSITION AND BUTTON STATUS
        int     33h
        and     bx,     0001h   ;проверка нажатия ЛКМ
        jnz     @@WaitForReleaseButton
 
@@WaitForFinishPoint:
        mov     ax,     0003h   ;RETURN POSITION AND BUTTON STATUS
        int     33h
        and     bx,     0001h   ;проверка нажатия ЛКМ
        jz      @@WaitForFinishPoint
        ;для графического видеорежима 13h нужно
        ;разделить на 2 координату X курсора
        shr     cx,     1
        mov     [Xfinish],      cx
        mov     [Yfinish],      dx
 
        ;спрятать курсор
        MouseHideCursor
 
        ;нарисовать линию
        push    word ptr [Xbegin]
        push    word ptr [Ybegin]
        push    word ptr [Xfinish]
        push    word ptr [Yfinish]
        push    word ptr [LineColor]
        call    DrawLine
        ;Завершение программы
@@Exit:
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
DrawLine        proc
        arg xStart:WORD, yStart:WORD, xEnd:WORD, yEnd:WORD, Color:WORD
        ;начало отрезка
        ;конец отрезка
        ;цвет отрезка
 
        ;LOCAL  a, b:WORD       ;  // displacements in x and y
        ;di LOCAL       d:WORD          ;  // decision variable
        LOCAL   diag_inc:WORD   ;  // d's increment for diagonal steps
        LOCAL   dx_diag:WORD    ;  // diagonal x step for next pixel
        LOCAL   dx_nondiag:WORD ;  // nondiagonal x step for next pixel
        LOCAL   dy_diag:WORD    ;  // diagonal y step for next pixel
        LOCAL   dy_nondiag:WORD ;  // nondiagonal y step for next pixel
        ;LOCAL  i:WORD          ;  // loop index
        LOCAL   nondiag_inc:WORD;  // d's increment for nondiagonal steps
        ;swap       :  integer;  // temporary variable for swap
        ;si, dx x,y        :  integer;  // current x and y coordinates
        ;// line starting point
        mov     si,     [xStart]        ;x := xStart;
        mov     dx,     [yStart]        ;y := yStart;
        ;// Determine drawing direction and step to the next pixel.
        ;// difference in x dimension
        mov     ax,     [xEnd]          ;a := xEnd - xStart;
        sub     ax,     [xStart]
        ;// Determine whether end point lies to right or left of start point.
        mov     [dx_diag],      1
        jns     @@StoreA                ;if a < 0 then // drawing towards smaller x values?
                                        ;begin
                neg     ax              ;   a := -a;   // make 'a' positive
                                        ;   dx_diag := -1
                mov     [dx_diag],      -1
                                        ;end
                                        ;else
                                        ;   dx_diag := 1;
        @@StoreA:
        ;// difference in y dimension
        mov     bx,     [yEnd]          ;b := yEnd - yStart;
        sub     bx,     [yStart]
        ;// Determine whether end point lies above or below start point.
        mov     [dy_diag],      1
        jns     @@StoreB                ;if b < 0 then // drawing towards smaller y values?
                                        ;begin
                neg     bx              ;   b := -b;   // make 'b' positive
                                        ;   dy_diag := -1
                mov     [dy_diag],      -1
                                        ;end
                                        ;else
                                        ;   dy_diag := 1;
        @@StoreB:
                                        ;// Identify octant containing end point.
        cmp     ax,     bx              ;if a < b then
        jae     @@A_ge_B                ;begin
                mov     cx,     ax      ;   swap := a;
                mov     ax,     bx      ;   a := b;
                mov     bx,     cx      ;   b := swap;
                mov     [dx_nondiag],0  ;   dx_nondiag := 0;
                mov     cx,[dy_diag]    ;   dy_nondiag := dy_diag
                mov     [dy_nondiag],cx
                jmp     @@Init          ;end
        @@A_ge_B:                       ;else
                                        ;begin
                mov     cx,[dx_diag]    ;   dx_nondiag := dx_diag;
                mov     [dx_nondiag],cx
                mov     [dy_nondiag],0  ;   dy_nondiag := 0
                                        ;end;
        @@Init:
                add     bx,bx
                mov     [nondiag_inc],bx;nondiag_inc := b + b;     // set initial d increment values
                sub     bx,     ax
                mov     di,     bx      ;d := b + b - a;           // initial value for d is 2*b - a
                sub     bx,     ax      ;diag_inc    := b + b - a - a;
                mov     [diag_inc],     bx
        mov     cx,     ax              ;for i := 0 to a do
        inc     cx
        @@ForI:                         ;begin   /// draw the a+1 pixels
                push    cx
                mov     ah,     0Ch     ;   drawPixel (bitmap, x, y, color);
                mov     al,     byte ptr [Color]
                mov     bh,     0
                mov     cx,     si
                ;mov     dx,     dx
                int     10h
                cmp     di,     0       ;   if d < 0 then            // is midpoint above the line?
                jge     @@ByDiagonal    ;   begin                 // step nondiagonally
                        add     si,[dx_nondiag] ;      x := x + dx_nondiag;
                        add     dx,[dy_nondiag] ;      y := y + dy_nondiag;
                        add     di,[nondiag_inc];      d := d + nondiag_inc  // update decision variable
                        jmp     @@NextP ;   end
                @@ByDiagonal:           ;   else
                                        ;   begin                 // midpoint is above the line; step diagonally}
                        add     si,[dx_diag]    ;      x := x + dx_diag;
                        add     dx,[dy_diag]    ;      y := y + dy_diag;
                        add     di,[diag_inc]   ;      d := d + diag_inc
                @@NextP:                        ;   end;
                pop     cx
        loop    @@ForI                  ;end;
        ret
DrawLine        endp
 
end     main

.model tiny  
org 100h 
.data
    x1 dw ?
    x2 dw ?
    y  dw ? 
    firstpos dw ?
    secondpos dw ?
    divconst dw 2h
    const dw 140h
.code
 
 
 
start:  
    mov ax,13h
    int 10h
    push 0A000h
    pop es  
    call GetDrawing
   
    
    
    X1Higer:
    mov ax,firstpos
    sub ax,secondpos
    mov cx,ax
   
    add ax,x1
    mov di,firstpos
    mov al,0Fh; öâåò ëèíèé    
   
    diminus:
        dec di
        dec di
        stosb
        loop diminus
       
    call GetDrawing
    retn;
    
    GetMouseClick:
    mov bx,1
    call GetMouseState
    and bx, 00000001b
    jz GetMouseClick
    ret
    
    GetMouseState:
    mov ax,3
    int 33h
    ret    
    
    
    
    GetDrawing:
    call GetMouseClick
    mov x1,cx
    mov cx,2h
    mov ax,x1 
    mov y, dx
    div cl
    mov x1,ax 
    
    mov ax, y
    mul const
    add ax,x1
    mov firstpos,ax
    call GetMouseClick
    mov x2,cx
    mov cx,2h
    mov ax,x2
    
    div cl
    mov x2,ax
    mov ax,y
    mul const
    add ax,x2
    mov secondpos,ax
    mov ax,secondpos
    cmp ax,firstpos
    jg X2Higher
    call X1Higer    
    
    X2Higher:
    mov ax,secondpos
    sub ax,firstpos
    mov cx,ax
    add ax,x1
    mov di,firstpos
    mov al,0Fh
    rep stosb
    ;int 16h
    ;mov ax,3
    ;int 10h
    call GetDrawing
    retn
    
end start