Многозадачность, алгоритм кругового планирования

model   tiny
.code
org 100h
begin:  mov ax,3
    int 10h
    mov ax,351CH
    int 21h
    mov old1Co,bx
    mov old1Cs,es
    mov ax,251Ch
    lea dx,new1C
    int 21h
    mov ax,0B800h
    mov es,ax
@@00:   lea bx,task
    add bx,num
    add bx,num
    mov si,[bx]
    xor di,di
    mov cx,szMes
    mov ah,0Fh
@@01:   lodsb
    Stosw
    loop    @@01
    mov bx,si
    mov ax,[bx]
    inc ax
    mov [bx],ax
    mov cx,5
    mov si,10
@@02:   xor dx,dx
    div si
    or  dx,0f30h
    push    dx
    loop    @@02
    mov cx,-1
@@a:    mul ax
    mul ax
    mul ax
    mul ax
    mul ax
    mul ax
    mul ax
    loop    @@a
    mov cx,5
@@03:   pop ax
    stosw
    loop    @@03
    mov ah,01
    int 16h
    jz  @@00
    mov ax,351Ch
    mov dx,old1Co
    mov ds,old1Cs
    int 21h
    ret
new1C:  push    ax
    push    ds
    push    cs
    pop ds
    mov ax,count
    dec ax
    mov count,ax
    jnz @@04
    mov ax,50
    add ax,num
    add ax,num
    mov count,ax
    mov ax,num
    inc ax
    and ax,03
    mov num,ax
@@04:   pop ds
    pop ax
    db  0EAh    
old1Co  dw  ?
old1Cs  dw  ?
count   dw  20
num dw  0
dw0 db  'system ip:='
szMes   equ $-dw0
    dw  0
szRec   equ $-dw0
dw1 db  'task 1 ip:='
    dw  0
dw2 db  'task 2 ip:='
    dw  0
dw3 db  'task 3 ip:='
    dw  0
 
task    dw  offset dw0
    dw  offset dw1
    dw  offset dw2
    dw  offset dw3
    end begin

.model tiny        ; Программа в формате COM
.code
org 100h
.startup
mov ah,0fh         ; Читаем видеорежим
int 10h
cmp al,12h         ; Мы уже в режиме 12h?
je Do              ; Да - не трогать режим
mov ax,12h         ; Нет - включить режим 12h
int 10h            ; 640x480x16
xor bh,bh          ; Видиостраница 0
Do:
mov ax,0c8fh       ; Попиксельный вывод цвета в режиме XOR
P:mov cx,160       ; Высота полоски - 480/3=160 пикселей
  mov dx,0         ; Счётчик строк
  R:push cx        ; Рисование строки
    xor cx,cx
    C:int 10h      ; Вывод пикселя
      inc cx       ; Переход к следующему пикселю
      cmp cx,640   ; Ширина экрана 640 пикселей
      jne C
    inc dx         ; Переход к следующей строке
    pop cx
    loop R
  jmp P            ; Бесконечное зацикливание
ret     
end

; SuperOS v0.1
; Preemptive multitasking realmode operation system by Konstantin Korotkov
 
; Набор инструкций - 80186, формат - exe
.186
.model small
.stack 100h
.data
OldTmr dw ?,?   ; Исходный вектор таймера
TaskList dw ?,? ; Указатель на начало тасклиста
Task dw 0       ; Номер текущей задачи
N dw 0          ; Кол-во задач
 
.code
Start:
; Возврат лишней памяти в кучу DOS
; DS=ES=PSP
mov bx,ZSEG
mov ax,es
sub bx,ax       ; Определение размера программы
mov ah,4ah
int 21h
; Загрузка задач
xor bh,bh
mov bl,ds:[80h]
mov cx,bx
mov byte ptr[bx+81h],' ' ; Замена терминатора командной строки пробелом
cld
xor dx,dx
mov di,82h      ; Игнорирование начального пробела
mov al,' '
S:jcxz Run      ; Парсинг командной строки
  push di       ; Сохранение адреса начала имени файла в качестве параметра LoadFile
  repne scasb   ; Поиск пробела
  mov byte ptr[di-1],0   ; Нуль-терминирование имени файла
  call LoadFile ; Загрузка задачи
  jc S          ; Загрузка не удалась - продолжить парсинг
  push bx       ; Загрузка удалась - сохранение параметров задачи в тасклист
  push si 
  inc dx        ; Инкремент счётчика задач
  jmp S
; Запуск переключения задач
Run:
test dx,dx      ; Если ни одной задачи нет
jz Quit         ; то сразу выйти
mov ax,@data    ; DS=@data
mov ds,ax
mov N,dx        ; Сохранение счётчика задач
mov TaskList,ss ; Сохранение указателя на тасклист
mov TaskList[2],sp
mov ax,3508h    ; Сохранение вектора прерывания таймера
int 21h
mov OldTmr,bx
mov OldTmr[2],es
mov ax,2508h    ; Подмена прерывания таймера
push ds
push cs
pop ds
mov dx,offset Switch
int 21h
pop ds
jmp NextTask    ; Запуск первой задачи
; Завершение работы ОС
Fin:
push ds         ; Восстановление вектора прерывания таймера
mov ax,2508h
lds dx,dword ptr[OldTmr]
int 21h
pop ds
mov cx,N        ; Освобождение памяти задач
mov ah,49h
F:pop es        ; Извлечение указателя конца стека
  pop es        ; Извлечение адреса загрузки
  int 21h       ; Освобождение памяти
  loop F        ; Для всех задач
Quit:
mov ax,4c00h    ; Выход в DOS
int 21h
 
 
;;;;;;;;;;;;    ФУНКЦИИ   ;;;;;;;;;;;;
; Функуия загрузки задачи
;   Параметры:
; [bp+4] - Адрес имени файла (ASCIIZ)
;   Возвращаемые значения:
; bx - адрез загруженной задачи
; si - вершина стека задачи
LoadFile proc
enter 6,0
push ax
push cx
push dx
; Открытие файла
mov dx,[bp+4]
mov ax,3d00h
int 21h
jc LoadErr      ; Ошибка - ничего не делать
mov [bp-2],ax   ; Файловый описатель
; Получение размера файла
mov bx,ax
xor cx,cx
xor dx,dx
mov ax,4202h
int 21h  
mov [bp-4],ax   ; Реальный размер файла
; Выделение памяти
mov bx,ax
add bx,15       ; Вычисление кол-ва параграфов
shr bx,4
add bx,10h      ; Добавление стека задачи - 100h
mov si,bx
shl si,4
sub si,2        ; Конец стека задачи
mov ah,48h
int 21h
mov [bp-6],ax   ; Адрес загрузки задачи
; Установка указателя на начало файла
mov bx,[bp-2]
xor cx,cx
xor dx,dx
mov ax,4200h
int 21h
; Загрузка образа в память
push ds
mov ds,[bp-6]
mov cx,[bp-4]
mov ah,3fh
int 21h 
; Инициализация контекста задачи
mov [si],si         ; Адрес реальной вершины стека
sub word ptr[si],24
mov [si-2],202h     ; flags (if=1) 
mov [si-4],ds       ; cs
mov [si-6],dx       ; ip=0
mov [si-8],ds       ; es=cs
mov [si-10],ds      ; ds=cs
mov [si-12],dx      ; bp=0
mov [si-14],dx      ; di=0
mov [si-16],dx      ; si=0
mov [si-18],dx      ; dx=0
mov [si-20],dx      ; cx=0
mov [si-22],dx      ; bx=0
mov [si-24],dx      ; ax=0
pop ds
; Закрытие файла
mov bx,[bp-2]
mov ah,3eh
int 21h
mov bx,[bp-6] 
LoadErr:
pop dx 
pop cx
pop ax
leave
ret 2
LoadFile endp
 
; Процедура переключения задач по прерыванию таймера
; Флаги и адрес возврата в прерванную задачу сохранены в стек прерыванием
Switch proc
push es         ; Сохранение контекста текущей задачи в её же стек
push ds
push bp
push di
push si
push dx
push cx
push bx
push ax
mov dx,sp       ; Запоминание sp задачи
mov ax,@data    ; Поиск конца стека задачи через тасклист
mov ds,ax          ; Переключение стека на системный
mov ss,TaskList
mov sp,TaskList[2]
mov bp,sp          ; Вычисление смещения задачи в тасклисте
mov si,Task
shl si,2
les di,[bp+si]
mov es:[di],dx  ; Обновление реальной вершины стека
; Системная обработка прерывания
pushf           ; Вызов системного обработчика
call dword ptr[OldTmr]
mov al,20h      ; Сброс контроллера прерываний
out 20h,al
mov ah,1        ; Проверка нажатия клавиши
int 16h
jz NextTask     ; Не нажата - переключить задачу
xor ah,ah       ; Нажата - извлечь клавишу из очереди
int 16h
jmp Fin         ; и прекратить переключение задач
; Переключение задачи
NextTask:
inc Task        ; Определение номера новой задачи
mov ax,Task   
xor dx,dx
div N           ; через остаток от деления на N
mov Task,dx
mov bp,sp       ; Вычисление смещения задачи в тасклисте
mov si,Task
shl si,2
les si,[bp+si]
mov ax,es       ; Переключение на стек задачи
mov ss,ax
; Восстановление контекста
mov sp,es:[si]  ; Определение реальной вершины стека
pop ax          ; Восстановление регистров
pop bx
pop cx
pop dx
pop si
pop di
pop bp
pop ds
pop es
iret            ; Возобновление задачи
Switch endp
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
; Фиктивный сегмент для определения размера программы
ZSEG segment
ZSEG ends
end Start

; SuperOS v0.1.1
; Preemptive multitasking realmode operation system by Konstantin Korotkov
; 0.1 -> 0.1.1 version update by Jin X ;)))
 
TMR_SPEED_COEF = 8 ; коэффициент увеличения скорости (степень двойки: от 1 до 256) [Jin X]
 
; Набор инструкций - 80186, формат - exe
.186
.model small
.stack 100h
.data
OldTmr dw ?,?   ; Исходный вектор таймера
TaskList dw ?,? ; Указатель на начало тасклиста
Task dw 0       ; Номер текущей задачи
N dw 0          ; Кол-во задач
 
; Счётчик пропусков вызова системного обработчика прерывания по таймеру [Jin X]
if TMR_SPEED_COEF ne 1
TmrSkipCounter db 0
endif
 
.code
Start:
; Возврат лишней памяти в кучу DOS
; DS=ES=PSP
mov bx,ZSEG
mov ax,es
sub bx,ax       ; Определение размера программы
mov ah,4ah
int 21h
; Загрузка задач
xor bh,bh
mov bl,ds:[80h]
mov cx,bx
mov byte ptr[bx+81h],' ' ; Замена терминатора командной строки пробелом
cld
xor dx,dx
mov di,82h      ; Игнорирование начального пробела
mov al,' '
S:jcxz Run      ; Парсинг командной строки
  push di       ; Сохранение адреса начала имени файла в качестве параметра LoadFile
  repne scasb   ; Поиск пробела
  mov byte ptr[di-1],0   ; Нуль-терминирование имени файла
  call LoadFile ; Загрузка задачи
  jc S          ; Загрузка не удалась - продолжить парсинг
  push bx       ; Загрузка удалась - сохранение параметров задачи в тасклист
  push si 
  inc dx        ; Инкремент счётчика задач
  jmp S
; Запуск переключения задач
Run:
test dx,dx      ; Если ни одной задачи нет
jz Quit         ; то сразу выйти
mov ax,@data    ; DS=@data
mov ds,ax
mov N,dx        ; Сохранение счётчика задач
mov TaskList,ss ; Сохранение указателя на тасклист
mov TaskList[2],sp
mov ax,3508h    ; Сохранение вектора прерывания таймера
int 21h
mov OldTmr,bx
mov OldTmr[2],es
mov ax,2508h    ; Подмена прерывания таймера
push ds
push cs
pop ds
mov dx,offset Switch
int 21h
pop ds
 
; Изменения скорости таймера для повышения плавности [Jin X]
if TMR_SPEED_COEF ne 1
mov al,34h
out 43h,al
xor al,al
out 40h,al
mov al,256/TMR_SPEED_COEF
out 40h,al
endif
 
jmp NextTask    ; Запуск первой задачи
; Завершение работы ОС
Fin:
 
; Восстановление скорости таймера [Jin X]
if TMR_SPEED_COEF ne 1
mov al,36h  ; можно и 34h
out 43h,al
xor al,al
out 40h,al
out 40h,al
endif
 
push ds         ; Восстановление вектора прерывания таймера
mov ax,2508h
lds dx,dword ptr[OldTmr]
int 21h
pop ds
mov cx,N        ; Освобождение памяти задач
mov ah,49h
F:pop es        ; Извлечение указателя конца стека
  pop es        ; Извлечение адреса загрузки
  int 21h       ; Освобождение памяти
  loop F        ; Для всех задач
Quit:
mov ax,4c00h    ; Выход в DOS
int 21h
 
 
;;;;;;;;;;;;    ФУНКЦИИ   ;;;;;;;;;;;;
; Функуия загрузки задачи
;   Параметры:
; [bp+4] - Адрес имени файла (ASCIIZ)
;   Возвращаемые значения:
; bx - адрез загруженной задачи
; si - вершина стека задачи
LoadFile proc
enter 6,0
push ax
push cx
push dx
; Открытие файла
mov dx,[bp+4]
mov ax,3d00h
int 21h
jc LoadErr      ; Ошибка - ничего не делать
mov [bp-2],ax   ; Файловый описатель
; Получение размера файла
mov bx,ax
xor cx,cx
xor dx,dx
mov ax,4202h
int 21h  
mov [bp-4],ax   ; Реальный размер файла
; Выделение памяти
mov bx,ax
add bx,15       ; Вычисление кол-ва параграфов
shr bx,4
add bx,10h      ; Добавление стека задачи - 100h
mov si,bx
shl si,4
sub si,2        ; Конец стека задачи
mov ah,48h
int 21h
mov [bp-6],ax   ; Адрес загрузки задачи
; Установка указателя на начало файла
mov bx,[bp-2]
xor cx,cx
xor dx,dx
mov ax,4200h
int 21h
; Загрузка образа в память
push ds
mov ds,[bp-6]
mov cx,[bp-4]
mov ah,3fh
int 21h 
; Инициализация контекста задачи
mov [si],si         ; Адрес реальной вершины стека
sub word ptr[si],24
mov [si-2],202h     ; flags (if=1) 
mov [si-4],ds       ; cs
mov [si-6],dx       ; ip=0
mov [si-8],ds       ; es=cs
mov [si-10],ds      ; ds=cs
mov [si-12],dx      ; bp=0
mov [si-14],dx      ; di=0
mov [si-16],dx      ; si=0
mov [si-18],dx      ; dx=0
mov [si-20],dx      ; cx=0
mov [si-22],dx      ; bx=0
mov [si-24],dx      ; ax=0
pop ds
; Закрытие файла
mov bx,[bp-2]
mov ah,3eh
int 21h
mov bx,[bp-6] 
LoadErr:
pop dx 
pop cx
pop ax
leave
ret 2
LoadFile endp
 
; Процедура переключения задач по прерыванию таймера
; Флаги и адрес возврата в прерванную задачу сохранены в стек прерыванием
Switch proc
push es         ; Сохранение контекста текущей задачи в её же стек
push ds
push bp
push di
push si
push dx
push cx
push bx
push ax
mov dx,sp       ; Запоминание sp задачи
mov ax,@data    ; Поиск конца стека задачи через тасклист
mov ds,ax          ; Переключение стека на системный
mov ss,TaskList
mov sp,TaskList[2]
mov bp,sp          ; Вычисление смещения задачи в тасклисте
mov si,Task
shl si,2
les di,[bp+si]
mov es:[di],dx  ; Обновление реальной вершины стека
; Системная обработка прерывания
 
; Пропуск "лишних" вызовов системного обработчика прерывания по таймеру [Jin X]
if TMR_SPEED_COEF ne 1
dec [TmrSkipCounter]
if TMR_SPEED_COEF ne 256
and [TmrSkipCounter],TMR_SPEED_COEF-1
endif
jnz SkipOldTmr
endif
 
pushf           ; Вызов системного обработчика
call dword ptr[OldTmr]
 
SkipOldTmr:     ; [Jin X]
 
mov al,20h      ; Сброс контроллера прерываний
out 20h,al
mov ah,1        ; Проверка нажатия клавиши
int 16h
jz NextTask     ; Не нажата - переключить задачу
xor ah,ah       ; Нажата - извлечь клавишу из очереди
int 16h
jmp Fin         ; и прекратить переключение задач
; Переключение задачи
NextTask:
inc Task        ; Определение номера новой задачи
mov ax,Task   
xor dx,dx
div N           ; через остаток от деления на N
mov Task,dx
mov bp,sp       ; Вычисление смещения задачи в тасклисте
mov si,Task
shl si,2
les si,[bp+si]
mov ax,es       ; Переключение на стек задачи
mov ss,ax
; Восстановление контекста
mov sp,es:[si]  ; Определение реальной вершины стека
pop ax          ; Восстановление регистров
pop bx
pop cx
pop dx
pop si
pop di
pop bp
pop ds
pop es
iret            ; Возобновление задачи
Switch endp
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
; Фиктивный сегмент для определения размера программы
ZSEG segment
ZSEG ends
end Start