Определить размер файла А, если файл пуст то удалить его, иначе вывести 100 байтов содержимого на экран

.model small
 
.stack 100h
 
.data
        InFileName      db      'a.txt', 0
 
        errFileOpen     db      'File open error', '$'
        errFileRead     db      'File read error', '$'
        errFileClose    db      'File close error', '$'
        _STDOUT_        =       1
        CrLf            db      0Dh, 0Ah, '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
.data?
        BufSize         =       100
        Buffer          db      BufSize dup(?)
        InFileHandler   dw      ?
 
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
 
        ;открытие файла
        mov     ax,     3D00h           ;открыть для чтения
        lea     dx,     [InFileName]
        int     21h
        jnc     @@InFileOpenOk
        mov     ah,     09h
        lea     dx,     [errFileOpen]
        int     21h
        jmp     @@Exit
@@InFileOpenOk:
        mov     [InFileHandler],        ax
 
        ;выяснение длины открытого файла
        mov     ax,     4202h
        mov     bx,     [InFileHandler]
        xor     cx,     cx
        mov     dx,     cx
        int     21h
 
        or      ax,     dx
        jz      @@CloseInFileAndExit
 
        ;установить логический указатель на начало файла
        mov     ax,     4200h
        mov     bx,     [InFileHandler]
        xor     cx,     cx
        mov     dx,     cx
        int     21h
        ;считать 100 байт из файла
        mov     ah,     3Fh
        mov     bx,     [InFileHandler]
        lea     dx,     [Buffer]
        mov     cx,     BufSize
        int     21h
        jnc     @@InFileReadOk
        mov     ah,     09h
        lea     dx,     [errFileRead]
        int     21h
        jmp     @@CloseInFileAndExit
@@InFileReadOk:
        ;вывод буфера на экран
        mov     cx,     ax
        mov     ah,     40h
        mov     bx,     _STDOUT_
        lea     dx,     [Buffer]
        int     21h
        ;закрытие файла
@@CloseInFileAndExit:
        mov     ah,     3Eh
        mov     bx,     [InFileHandler]
        int     21h
        jnc     @@Exit
        mov     ah,     09h
        lea     dx,     [errFileClose]
        int     21h
@@Exit:
 
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        xor     ah,     ah
        int     16h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main