Перехватив прерывание от таймера, вывести на экран последовательность степеней числа 2

code segment
assume CS:code,DS:data
main proc
mov AX,data ; Инициализация сегментного
mov DS,AX ; регистра DS
;Сохраним исходный вектор
mov AH,35h ; Функция получения вектора
mov AL,08h ; Номер вектора
int 21h
mov word ptr old_08,BX ; Смещение исходного обработчика
mov word ptr old_08+2,ES ; Сегмент исходного обработчика
;Установим наш обработчик
mov AH,25h ;Функция заполнения вектора
mov AL,08h ; Номер вектора
mov DX,offset my_08 ; Смещение нашего обработчика
push DS ; Сохраним DS=data
push CS ; Перепишем CS в DS
pop DS ; через стек. DS:DX->new_08
int 21h
pop DS ; Восстановим DS=data/Перед завершением программы восстановим исходный вектор
Lds DX ,old_08 ; Заполним DS:DX из old_08
mov AH,25h ; Функция заполнения вектора
mov AL,08h ; Номер вектора
int 21h
mov AX,4C00h ;Функция завершения программы
int 21h
main endp
;Процедура обработчика прерываний от таймера
my_08 proc
push AX ;Сохраним исходное значение AX
mov ax,2
a1: mul 2
JC a2
push ax ;Cохраним число
push -1 ;Сохраним признак конца числа
mov cx,10 ;Делим на 10
l: mov dx,0 ;Очистим регистр dx (xor dx,dx - оптимальнее)
div cx ;Делим
push dx ;Сохраним цифру
cmp ax,0 ;Остался 0? (оптимальнее or ax,ax)
jne l ;нет -> продолжим
mov ah,2h
l2: pop dx ;Восстановим цифру
cmp dx,-1 ;Дошли до конца -> выход {оптимальнее: or dx,dx jl ex}
je ex
add dl,'0' ;Преобразуем число в цифру
int 21h ;Выведем цифру на экран
jmp l2 ;И продолжим
ex: mov ax,4c00h ;Выход
int 21h
 
pop ax ;Восстановим число
Loop a1
a2: mov AL,20h ;Разблокировка прерываний
out 20h,AL ;в контроллере прерываний
pop AX ;Восстановим AX
iret ;Возврат в прерванную программу
my_08 endp
code ends
data segment
old_08 db 0 ;Ячейка для хранения исходного вектора
data ends
stk segment stack
db 256 dup(0)
stk ends
end main

old_08 dd 0 ;Ячейка для хранения исходного вектора

a1: mul 2

; В Windows XP стабильно идёт в эмуляторе DosBox
; и не очень хорошо в консоли XP (экран не очищается при CLS)
    .286
    .model small
    .code
start:  jmp beg
; вектор старого прерывания
old8int label dword
old8ip  dw  0
old8cs  dw  0
; адрес видеопамяти символа
vaddr   dw  0
; позиция курсора
x   db  0
y   db  0
; степени 2
power2  dw  1
; счётчик прерываний
intcnt  db  0
; видео атрибут символа (белый на синем)
attrib  db  16*1+15
beg:    push cs
    pop  ds
    cld
    call cls ; выводится "Hel" чтобы проверить 
    mov al,"H" ; работает ли программа вообще
    call putchar
    mov al,"e"
    call putchar
    mov al,"l"
    call putchar
    mov x,0   ; курсор в позицию 1,0
    mov y,1
    call at
    mov ax,3508h ; получаем вектор старого прерывания
    int 21h
    mov old8ip,bx
    mov old8cs,es
    mov dx,offset new8int ; устанавливаем новый вектор
    push cs
    pop  ds
    mov ax,2508h ; set new interrupt
    int 21h
wt: cmp intcnt,16 ; дождаться пока пройдёт 16 прерываний
    jnz wt
    lds dx,old8int ; DS:DX=старый вектор прерывания
    mov ax,2508h ; set old interrupt
    int 21h
    mov x,0   ; курсор в позицию 20,0
    mov y,20
    call at
    mov ax,4C00h ; выход в DOS
    int 21h
 
new8int:pushf ; вызываем старое прерывание
    call old8int
    push ds ; важно - сохраняем все регистры, иначе система рухнет
    push es
    pusha
    call intcall ; вызываем нашу подпрограмму обработки
    popa    ; восстанавливаем регистры
    pop  es
    pop  ds
    iret
 
intcall:cmp intcnt,16 ; если счётчик достиг 16, ничего не делать
    jnc ic1
        mov x,0 ; установить курсор
        call at
    mov  ax,power2 ; вывести значение power2
    call printdigit
    mov  ax,power2 ; power2=power2*2
    add  ax,ax
    mov power2,ax
    inc y  ; увеличить номер строки
    inc intcnt ; увеличить счётчик прерываний
ic1:    ret
 
printdigit: ; вывод слова AX в десятичном виде
    push ax
    push bx
    push cx
    push dx
    mov cx,0
nextdig:mov dx,0
    mov bx,10
    div bx
    push dx
    inc  cx
    cmp ax,0
    jnz nextdig
    jcxz m1
m0: pop  ax
    add  al,"0"
    call putchar
    loop m0
m1:     pop  dx
    pop  cx 
    pop  bx
    pop  ax
    ret
 
cls:    push es ; очистить экран цветом attrib
    push ax
    push cx
    push di
    mov  di,0B800h ; сегмент видеопамяти DOS
    mov es,di
    mov di,0
    mov cx,80*25  ; размер текстового экрана
    mov al,20h
    mov ah,attrib
    rep stosw     ; собственно стирание
    mov x,0       ; курсор в позицию 0,0
    mov y,0
    call at
    pop  di
    pop  cx
    pop  ax
    pop  es
    ret
 
at: push ax ; установка курсора
    push bx
    push dx
    mov  al,y ; vaddr=(80*y+x)*2
    mov ah,80
    mul ah
    mov bl,x
    mov bh,0
    add ax,bx
    add ax,ax
    mov vaddr,ax
    mov bh,0 ; bios set cursor
        mov dh,y
    mov dl,x
    mov ah,2
    int 10h
    pop dx
    pop bx
    pop ax
    ret
 
putchar:push es ; вывод символа AL цветом attrib на экран
    push ax
    push di
    mov  di,0B800h
    mov es,di
    mov di,vaddr
    mov ah,attrib
    stosw ; собственно вывод
    mov vaddr,di
    pop  di
    pop  ax
    pop  es
    ret
        
    end start

cls:    push ax ; очистить экран цветом attrib
    push bx
    push cx
    push dx
    mov  cx,0 ; верхний левый угол
    mov  dx,24*256+79 ; нижний правый угол
    mov  bh,attrib
    mov  ax,0600h ; стереть прямоугольник
    int  10h
    mov x,0       ; курсор в позицию 0,0
    mov y,0
    call at
    pop  dx
    pop  cx
    pop  bx
    pop  ax
    ret
 
 
putchar: push ax
    mov ah,0Eh
    int 10h
    pop ax  
    ret

wt: cmp intcnt,16
    jnz wt