При нажатии на F1 очистить правую половину экрана, а при нажатии на F2 - левую половину

;===========================================================================
;Програма буде виконувати зафарбовування супроводжуючого тексту червоним та синім кольором при натисненні клавіш F1 та F2 відповідно та забезпечувати вихід з програми за 
 
допомогою клавіші Esc
;===========================================================================
 
 
.386
esc_key equ 01h         ;скан-код клавіші Esc
 F1_key equ 3bh;02h     ;клавіша 1
 F2_key equ 3ch;03h     ;клавіша 2
 
 RED        equ     0Ach        ;коди кольорів
 BLUE       equ     0F9h
 GREEN  equ     0E5h
 
 
 
_ST SEGMENT para    STACK 'stack' use16
    dw  32000 dup (?)
_ST         ENDS
 
 
_DATA   SEGMENT para 'DATA'     use16
 msg        db  'Press:',10,13              ;текст повідомлення
        db  'ESC - for exit.',10,13
        db  'F1 - fill by red color.',10,13
        db  'F2 - fill by blue color.',10,13,'$'
_DATA ENDS
 
 
_TEXT    SEGMENT    para 'CODE' use16
ASSUME  CS:_TEXT,DS:_DATA,SS:_ST
int9ptr dw 2 dup (?)
setint9 PROC
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
; процедура "перехоплення" переривання від клавіатури і встановлення вектора ; переривань прикладного обробника 
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    MOV AH,35H      ;отримати вектор переривання
    MOV AL,9            ;переривання від клавіатури (9) N=9
    INT 21H             ;значення, що повертається:
                    ;es:bx - вказівник на системну процедуру
                    ;обробки переривання від клавіатури
 
    mov cs:int9ptr,bx       ; зберегти в сегменті кодів вказівник 
    mov cs:int9ptr+2,es         ; на системну процедуру
 
    mov dx,offset userint9
    push ds
    push cs         ;ds:dx - вказівник на процедуру користувача  
    pop ds          ;оброб. переривання від клавіатури
 
    MOV AH,25H      ; встановити вектор "перехоплення"
    MOV AL,9            ; переривання від клавіатури (9) N=9
    INT 21H 
    pop ds
 
    ret
 ; int9ptr  dw 2 dup (?)
 
setint9 ENDP
 
retint9 PROC
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;  процедура відновлення попереднього (системного)
;  вектора переривання від клавіатури
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    push ds
    push dx
    mov dx,cs:int9ptr   ; ds:dx - вказівник на початкову (системну)
    mov ax,cs:int9ptr+2 ; процедуру обробки переривання від
    mov ds,ax           ; клавіатури
    
 
    MOV AH,25H  ; встановити вектор системної процедури
    MOV AL,9        ; обробки переривання від клавіатури
    INT 21H     ; 
 
    pop dx
    pop ds
 
    ret
retint9 ENDP
 
userint9    proc    far
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
; Процедура обробки переривань від клавіатури,
; викликається при будь-якому натисканні або відтисканні клавіш клавіатури,
; здійснює повернення в MS-DOS після натискання клавіші Esc
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    pushf
    call    dword ptr cs:int9ptr    ;виклик основного обработчика
                        ;преривання клавіатури
                        ;(для занесення символу в буфер)  
    pushad
                        ; читання порту клавіатури
    in  al,60h          ;введення скан-коду клавіші - розряди 0-6
    mov ah,al               ;7-ий розряд дорівнює 0 при натисканні
 
    push    ax              ;скан-код клавіші
    push    3832                ;позиція виводу
    call    show                ;виведення скан-коду на екран
    
    cmp ah,esc_key          ;якщо натиснутий Еsc
    je  short ui9020        ;вихід з програми
 
    cmp ah,F1_key           ;натиснута 1
    je  short ui_F1
 
    cmp ah,F2_key           ;натиснута 2
    je  short ui_F2
 
    jmp ui9040
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ui9020:
    call    retint9         ;повернення системного вектора переривання
    mov     ax,4c00h            ;вихід з програми
    int     21h      
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ui_F1:      ; виводення для контролю посередині екрану ; ASCII коду символів
    push    '01'                ; ASCII коду символів
    push    2000                ; у 16-вому коді
    call    show
    
    push    RED             ; фарбування відповідно екрану і тексту
    call    fill
    jmp short ui9040
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ui_F2:                  ; виводення для контролю посередині екрану
    push    '02'                ; ASCII коду символів
    push    2160                ; букви "F" та цифри "1"
    call    show                ; у 16-вому коді
    
    push    BLUE                ; фарбування відповідно екрану і тексту
    call    fill
 
 
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ui9040:
    popad
    iret                    ; закінчення обробки переривання
userint9    endp 
show    proc    near        
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;процедура виводу числового значення натиснутої клавіші.
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
 
    push    bp
    mov     bp,sp
    pusha
    push    es
    mov     ax,0b800h       ;константа віеопам'яті
    mov     es,ax
 
    std             ;запис відбудеться справа-наліво
ls20:
    mov     di,[bp+4]       ;точка виводу
    mov     bx,[bp+6]       ;те, що ми виводимо в 16-му коді
    mov     cx,4
    mov     ah,0ah      ;зелений колір символу,чорний - фону
ls40:
    mov     al,bl           ;обробка молодшого байту символу
    and     al,00001111b    ;виділили молодшу тетраду(число від 0 до 15)
    cmp     al,10           ;чи число більше за 10
    jl  ls100           ;якщо менше – просто виводимо
    add     al,7            ;якщо літера то виводимо як символ літери
ls100:
    add     al,30h      ;тому що скан-коди цифр починаються з 30h
    stosw               ;зберігаємо за адресою es:di значення ax
    shr     bx,4            ;наступна тетрада
    loop    ls40
 
    pop     es
    popa
    pop     bp
    ret     4
show  endp
 
fill    proc    near        
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;процедура зміни атрибутів кольору тексту на екрані
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    push    bp
    mov     bp,sp
    pushad
    push    es
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
    push    0b800h
    pop es
    
    mov     ax,[bp+4]   ;атрибути кольору
    cld             ;заповнення атрибутів йде зліва-направо
    xor di,di
 @go:   
    inc     di
    stosb               ;запис за адресою es:di значення al
    cmp     di,2000     ;доки не опрацьовано весь екран=80*25*2
    jl      @go
 
    pop     es
    popad
    pop     bp
    ret 2
fill    endp
cont db ?
 
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;Процедура, що виводить на екран символьне позначення клавіш (окрім ;функціональних)
;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
print_text  proc    near    
 printing:  
    mov ah,10h      ;зчитування скан-коду натиснутої клавіші
    int 16h
        or  al,al           ;якщо символ функціональний, то не обробляємо
    je printing         ;його цією процедурою
    
    mov dl,al           ;якщо це літера, цифра, тощо
    mov ah,02h      ;виводимо символ
    int 21h
    jmp printing
 @exit:
    ret
print_text  endp
 
 
;- - - - - - - - - - - - - Початок роботи програми - - - - - - - - - - - - - 
begin:
    mov     ax,_data
    mov     ds,ax
 
    mov     ax,3            ;задати текстовий режим 80 на 25
    int     10h
 
    mov     ah,10h      ;відключити режим миготіння
    mov     al,3
    mov     bl,0
    int     10h
 
 
    mov ah,09h      ;вивести повідомлення msg
    mov dx,offset msg   
    int 21h
 
    cli             ; заборона переривань
    call    setint9     ;"перехоплення" int9
    sti             ;дозвіл переривань
    push    GREEN           ;початкові установки вигляду екрану
    call    fill
    call    print_text          ;запуск фонової процедури(див. нижче)
    cli
    call    retint9     ;відновлення системного вектора переривань
    sti 
    mov     ax,4c00h        ;вихід з програми
    int     21h
 
_TEXT ENDS
    end  begin

.386
 esc_key equ 01h         
 F1_key  equ 3Bh 
 F2_key  equ 3Ch
 
 red     equ 0C9h       
 blue    equ 09Ah
 green   equ 02Fh
 
 
 
_st segment para stack 'stack' use16
         dw  32000 dup (?)
_st ends
 
 
_data segment para 'data' use16
 msg    db  'Press:',10,13            
        db  'ESC - for exit.',10,13
        db  'F1 - fill by red color.',10,13
        db  'F2 - fill by blue color.',10,13,'$'
_data ends
 
 
_text segment para 'code' use16
assume  cs:_text,ds:_data,ss:_st
 
int9ptr dw 2 dup (?)
 
setint9 proc
    mov ah,35h      
    mov al,09h           
    int 21h                         
 
    mov cs:int9ptr,bx       
    mov cs:int9ptr+2,es        
 
    mov dx,offset userint9
    
    push ds
    push cs         
    pop ds         
 
    mov ah,25h     
    mov al,09h        
    int 21h 
    
    pop ds
 
    ret
setint9 endp
 
retint9 PROC
    push ds
    push dx
    
    mov dx,cs:int9ptr   
    mov ax,cs:int9ptr+2
    mov ds,ax
    
    mov ah,25h 
    mov al,09h        
    int 21h    
    
    pop dx
    pop ds
 
    ret
retint9 ENDP
 
userint9 proc far
    pushf
    call dword ptr cs:int9ptr    
    
    pushad
                        
    in al,60h          
    mov ah,al        
    
    push ax        
    push 3832               
    call show         
    
    cmp ah,esc_key     
    je short ui9020
 
    cmp ah,F1_key           
    je short ui_F1
 
    cmp ah,F2_key          
    je short ui_F2
 
    jmp ui9040
 
ui9020:
    call retint9     
    mov ah,4Ch
    mov al,00h         
    int 21h      
 
ui_F1:      
    push red         
    call fill_left
 
    push '01'                
    push 2002       
    call show
    
    jmp short ui9040
 
ui_F2:
    push blue
    call fill_right
             
    push '02'                
    push 2162                
    call show            
 
    ui9040:
    popad
    iret               
userint9 endp
 
show proc near        
 
    push bp
    mov bp,sp
    
    pusha
    
    push es
    mov ax,0B800h     
    mov es,ax
 
    std            
    
    ls20:
    mov di,[bp+4]
    mov bx,[bp+6]    
    mov cx,4
    mov ah,0Ah 
    
    ls40:
    mov al,bl       
    and al,00001111b   
    cmp al,10         
    jl ls100        
    add al,7
    
    ls100:
    add al,30h     
    stosw             
    shr bx,4       
    loop ls40
 
    pop es
    
    popa
    
    pop bp
    ret 4
    
show  endp
 
fill_left proc near        
    push bp
    mov bp,sp
    pushad
    push es
    
    push 0B800h
    pop es
    
    mov ax,[bp+4]
    cld
    xor di,di
    
    push cx
    mov cx,25
    @go1:
        push cx
        mov cx,40
        color1:
        inc di
        stosb
        loop color1
        add di,80
        pop cx
    loop @go1
    pop cx
 
    pop es
    popad
    pop bp
    ret 2
fill_left endp
 
fill_right proc near        
    push bp
    mov bp,sp
    pushad
    push es
 
    push 0B800h
    pop es
    
    mov ax,[bp+4]
    cld
    mov di,80
    
    push cx
    mov cx,25
    @go2:
        push cx
        mov cx,40
        color2:
        inc di
        stosb
        loop color2
        add di,80
        pop cx
    loop @go2
    pop cx
 
    pop es
    popad
    pop bp
    ret 2
fill_right endp
 
cont db ?
 
print_text proc near    
 printing:  
    mov ah,10h
    int 16h
    
    or al,al
    je printing
    
    mov dl,al
    mov ah,02h
    int 21h
    jmp printing
 
    @exit:
    ret
print_text endp
 
begin:
    mov ax,_data
    mov ds,ax
 
    mov ah,00h
    mov al,03h
    int 10h
 
    mov ah,10h 
    mov al,03h
    mov bl,00h
    int 10h
 
    mov ah,09h
    mov dx,offset msg   
    int 21h
    
    cli            
    call setint9     
    sti  
    
    push green           
    call fill_left
    
    push green
    call fill_right
    
    call print_text 
    
    cli
    call retint9    
    sti 
    
    mov ax,4Ch
    mov al,00h      
    int 21h
 
_text ends
    end  begin