Нажимая на левую кнопку мышки очистить нечетные колонки экрана, а при нажатии на правую кнопку - чётные колонки экрана

code segment
assume cs:code
jmp begin
 
action macro  itr, chr, sign, kf
mov cx, itr
    mov ah,03h
    mov al, chr
sign:
    mov word ptr es:[di],ax
    add di,kf
loop sign
endm
 
begin:     
mov ax, 3
int 10h
mov    ax,0B800h
mov    es,ax
xor di,di
action  2000, '+',sign1, 2
mov ax, 0   
int 33h
mov ax, 1
int 33h
mov ax,000ch
mov cx,00001010b
mov dx, offset mouse
int 33h
mov ah,0
int 16h
mov ax,000ch    
mov cx,0000h
int 33h
mov ax,3    
int 10h 
mov ah,4ch
int 21h
 
mouse:
xor ax,ax
start:
test bx, 00000010b ;нажата ли правая клавиша
jz  parn
xor di,di   ; для нечетных значений (прямое обращение к видеопамяти)
jmp continue
parn:
mov di, 2
continue:
cmp ax, 1   ;клавиша нажата дважды
jz final
mov ax, 1
action 1000, ' ', sign2, 4 
jmp start
final:
action 1000, '+', sign3, 4 
retf
 
code ends
end begin

mymacro macro count
  local @@for
  mov cx, count
  @@for:
    add ax, bx
  loop @@for
endm

;Заполнить 0-ю страницу видеопамяти произвольным текстом.
;Нажимая на левую кнопку мышки очистить нечетные колонки экрана,
;а при нажатии на правую кнопку - парные колонки экрана.
;При повторном нажатии на кнопку содержание соответствующей
;части экрана должно восстанавливаться.
 
.model small
 
.stack 100h
 
.data
        ;коды клавиш
        KeyCode_Esc                     equ     1Bh     ;Esc
 
        ;Константы событий "мыши"
        MouseEvent_None                 equ     0000h   ;Удалить пользовательский обработчик
        MouseEvent_Move                 equ     0001h   ;любое перемещение
        MouseEvent_PressLeftButton      equ     0002h   ;нажатие левой кнопки
        MouseEvent_ReleaseLeftButton    equ     0004h   ;отпускание левой кнопки
        MouseEvent_PressRightButton     equ     0008h   ;нажатие правой кнопки
        MouseEvent_ReleaseRightButton   equ     0010h   ;отпускание правой кнопки
        MouseEvent_PressMiddleButton    equ     0020h   ;нажатие средней кнопки
        MouseEvent_ReleaseMiddleButton  equ     0040h   ;отпускание средней кнопки
 
        MouseInitOk                     equ     0FFFFh  ;инициализация мыши - успешна
        MouseInitFault                  equ     0000h   ;инициализация мыши - мышь или драйвер мыши не установлены
 
        MouseButtons_Any                equ     0000h   ;количество кнопок у мыши - отлично от 2 и 3
        MouseButtons_2                  equ     0002h   ;количество кнопок у мыши - 2
        MouseButtons_2_                 equ     0FFFFh  ;количество кнопок у мыши - 2
        MouseButtons_3                  equ     0003h   ;количество кнопок у мыши - 3
 
        ;сообщения программы
        msgMouseFault                   db      'The mouse or mouse driver was not detected.', 13, 10, '$'
        ;условие вызова пользовательского обработчика прерывания
        MouseEvent                      equ     MouseEvent_PressLeftButton OR MouseEvent_PressRightButton
.data?
        ScreeBufferSize                 equ     80*25*2
        ScreenBuffer                    db      ScreeBufferSize dup (?)
.code
 
;Ожидание нажатия клавиши на клавиатуре
;вход
; - нет
;выход
;ax - al - ASCII код нажатой клавиши, ah - скан-код
ReadKey         macro
        mov     ah,     00h
        int     16h
endm
 
;Инициализация работы с "мышью"
;Выполняется аппаратный и программный сброс мыши и драйвера
;вход
; - нет
;выход
;ax - результат инициализации
;   - 0000h, если мышь или драйвер мыши не установлены
;   - FFFFh, если драйвер и мышь установлены
;bx - число кнопок
;   - 0002 или FFFF - две
;   - 0003 - три
;   - 0000 - другое количество
MouseInit       macro
        mov     ax,     0000h
        int     33h
endm
 
;Показать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseShowCursor macro
        mov     ax,     0001h
        int     33h
endm
 
;Спрятать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseHideCursor macro
        mov     ax,     0002h
        int     33h
endm
 
;Обработчик событий "мыши"
;вход
;АХ содержит условие вызова,
;ВХ - состояние кнопок,
;СХ, DX - X- и Y-координаты курсора,
;SI, DI - счетчики последнего перемещения по горизонтали и вертикали
;      (единицы измерения для этих счетчиков - мики, 1/200 дюйма),
;DS - сегмент данных драйвера мыши.
;выход
; - нет
MyMouseHandler  proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
        push    es
        push    ds
 
        push    ax
        ;настройка сегментных регистров
        mov     ax,     0B800h
        mov     es,     ax
        mov     ax,     @data
        mov     ds,     ax
        xor     di,     di
        lea     si,     [ScreenBuffer]
        ;спрятать курсор мыши
        MouseHideCursor
        pop     ax
        ;если обработчик вызван по нажатию ЛКМ - сразу
        ;обменять содержимое буфера и экрана
@@IsLeftButton:
        test    ax,     MouseEvent_PressLeftButton
        jne     @@mmhAction
        ;если обработчик вызван по нажатию ПКМ - сместить указатели
        ;на буфер и на экран на одно знакоместо, а потом
        ;обменять содержимое буфера и экрана
@@IsRightButton:
        test    ax,     MouseEvent_PressRightButton
        je      @@mmhExit
        add     si,     2
        add     di,     2
        ;обмен содержимого буфера и экрана
@@mmhAction:
        mov     cx,     ScreeBufferSize/4
        @@mmhFor:
                push    [si]
                push    es:[di]
                pop     [si]
                pop     es:[di]
                add     si,     4
                add     di,     4
        loop    @@mmhFor
@@mmhExit:
        ;показать курсор
        MouseShowCursor
        pop     ds
        pop     es
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        retf
MyMouseHandler  endp
 
;Заполнение экрана символами
FillScreen      proc
        mov     ax,     0B800h
        mov     es,     ax
        xor     di,     di
        mov     bl,     0       ;символ
        mov     bh,     0       ;цвет
        mov     cx,     25*80   ;количество знакомест на экране
        mov     dl,     'A'     ;некоторое смещение, чтобы буквы были разными
        @@ForFill:
                and     bx,     0F0Fh
                mov     ax,     bx
                add     al,     dl
                add     ah,     3       ;цвет фона делаем отличным от цвета символа
                and     ah,     07h
                shl     ah,     1
                shl     ah,     1
                shl     ah,     1
                shl     ah,     1
                or      ah,     bh      ;к цвету фона добавляем цвет символа
                stosw                   ;записываем символ и его атрибут (цвета)
                                        ;переходим к следующему адресу символа на экране
                add     bx,     0101h   ;изменяем цвет и номер выводимого символа
                inc     dl
                cmp     dl,     'Z'-16
                jb      @@Skip
                mov     dl,     'A'
                @@Skip:
        loop    @@ForFill
        ret
FillScreen      endp
 
;основная программа
main            proc
        mov     ax,     @data
        mov     ds,     ax
        ;попытка инициализации мыши
        MouseInit
        cmp     ax,     MouseInitOk
        je      @@MouseInitOk
        ;если инициализация не удалась - вывести сообщение
        ;и завершить программу
        mov     ah,     09h
        lea     dx,     [msgMouseFault]
        int     21h
        jmp     @@Exit
 
@@MouseInitOk:
        ;заполнение экрана
        call    FillScreen
        ;очистить буфер экрана
        mov     ax,     ds
        mov     es,     ax
        lea     di,     [ScreenBuffer]
        mov     cx,     ScreeBufferSize/2
        xor     ax,     ax
        rep     stosw
        ;установить пользовательский обработчик событий "мыши"
        mov     ax,     seg MyMouseHandler      ;ES:DX = адрес обработчика
        mov     es,     ax
        mov     dx,     offset  MyMouseHandler
        mov     cx,     MouseEvent              ;CX = условие вызова
        mov     ax,     000Ch
        int     33h
        ;показать курсор
        MouseShowCursor
        ;цикл ожидания нажатия кнопки ESC
        ;в цикле проверяется работа обработчика мыши
        @@WaitEscapePressed:
                ReadKey
                cmp     al,     KeyCode_Esc
        jne     @@WaitEscapePressed
        ;завершение работы с "мышью"
        ; - спрятать курсор
        MouseHideCursor
        ; - удалить пользовательский обработчик прерывания
        mov     cx,     MouseEvent_None
        mov     ax,     000Ch
        int     33h
 
@@Exit:
        mov     ax,     4C00h
        int     21h
main            endp
 
end     main