Вычислить сумму ряда с заданной точностью Е = 0.001

@Sergei_Pavlov · Регистрация: 21.11.2017

Студворк — интернет-сервис помощи студентам

$https://www.cyberforum.ru/cgi-bin/latex.cgi?\sum_{i=1}^{\propto }({(-1)}^{i+1})/{i}^{2}$
Исходные данные вводить с клавиатуры.Решите на масм32

ФедосеевПавел · 25.11.2017, 23:11

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
.486
.model flat, stdcall
option casemap :none
 
        include \masm32\include\windows.inc
 
        include \masm32\include\user32.inc
        include \masm32\include\kernel32.inc
        include \masm32\include\masm32.inc
 
        includelib \masm32\lib\user32.lib
        includelib \masm32\lib\kernel32.lib
        includelib \masm32\lib\masm32.lib
.data
        Eps             dq      0.001
        Result          dq      ?
 
        aszMsgResult    db      'Result: ', 0
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        aszPressLeftAlt db      0Dh, 0Ah, 0Dh, 0Ah, "Press Left Alt to exit", 0
        dwColorRed      dd      FOREGROUND_RED
        dwColorWhite    dd      FOREGROUND_RED + FOREGROUND_GREEN + FOREGROUND_BLUE
        dwCursorPosition        COORD   <20, 10>
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
.code
 
start:
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
        ;очистка экрана
        invoke  ClearScreen
 
        ;вычмсление суммы ряда
        finit
        fld1                            ;(-1)^(i+1)
        fld1                            ;i
        fldz                            ;Sum
        @@repeat:
                fld     st(2)           ;(-1)^(i+1)
 
                fld     st(2)           ;(i*i)
                fmul    st(0),  st(0)
 
                fdivp   st(1),  st(0)   ;(-1)^(i+1)/(i*i)
 
                fadd    st(1),  st(0)
 
                fld1                    ;i=i+1
                faddp   st(3),  st(0)
 
                fld     st(3)           ;
                fchs
                fstp    st(4)
 
                fabs
                fcomp   [Eps]
                fstsw   ax
                sahf
 
        jae     @@repeat
 
        fstp    [Result]
 
        ;вывод результата
        ; - смена цвета
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorRed]
        ; - установка позиции
        invoke  SetConsoleCursorPosition, hConsoleOutput, dword ptr [dwCursorPosition]
        ; - вывод
        invoke  WriteConsole, hConsoleOutput, ADDR aszMsgResult,\
                LENGTHOF aszMsgResult - 1, ADDR BufLen, NULL
        invoke  FloatToStr2, [Result], ADDR Buffer
        invoke  StrLen, ADDR Buffer
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия Left Alt
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorWhite]
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressLeftAlt,\
                LENGTHOF aszPressLeftAlt - 1, ADDR BufLen, NULL
        @@WaitForLAlt:
                invoke  GetAsyncKeyState, VK_LMENU
                and     eax,    8000h
        jz      @@WaitForLAlt
        ;завершение программы
        invoke  ExitProcess, 0
 
end start

Исправил ошибку в коде - тип Eps должен быть "четверное слово"

Новые блоги и статьи Все статьи Все блоги /
Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Символьное дифференцирование igorrr37 13.02.2026 / * Программа принимает математическое выражение в виде строки и выдаёт его производную в виде строки и вычисляет значение производной при заданном х Логарифм записывается как: (x-2)log(x^2+2) -. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.
«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL3_image 8Observer8 10.02.2026 Содержание блога Библиотека SDL3_image содержит инструменты для расширенной работы с изображениями. Пошагово создадим проект для загрузки изображения формата PNG с альфа-каналом (с прозрачным. . .

@Sergei_Pavlov 0 / 0 / 0 Регистрация: 21.11.2017 Сообщений: 2

	Вычислить сумму ряда с заданной точностью Е = 0.001 21.11.2017, 07:27. Показов 695. Ответов 1 Метки нет (Все метки) $https://www.cyberforum.ru/cgi-bin/latex.cgi?\sum_{i=1}^{\propto }({(-1)}^{i+1})/{i}^{2}$ Исходные данные вводить с клавиатуры.Решите на масм32 0