Вычислить сумму ряда с заданной точностью

@Nik_olala · Регистрация: 26.11.2017

Студворк — интернет-сервис помощи студентам

Здравствуйте,обращаюсь к вам первый раз за помощью,так как новичок и очень нужна помощь. Нужно найти сумму элементов заданного ряда,если задана формула которая выражает каждый член последовательности через предыдущие члены(так называемая рекуррентная формула).

ФедосеевПавел · 26.11.2017, 21:21

Попробуйте адаптировать под собственное условие одну из тем с названием "Вычислить сумму ряда с заданной точностью".

ФедосеевПавел · 01.12.2017, 20:36

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
.486
.model flat, stdcall
option casemap :none
 
        include \masm32\include\windows.inc
 
        include \masm32\include\user32.inc
        include \masm32\include\kernel32.inc
        include \masm32\include\masm32.inc
 
        includelib \masm32\lib\user32.lib
        includelib \masm32\lib\kernel32.lib
        includelib \masm32\lib\masm32.lib
.data
        aszPromptZ      db      0Dh, 0Ah, 'Enter the Z (-1; +1): ', 0
        aszPromptEps    db      0Dh, 0Ah, 'Enter the Eps: ', 0
        aszMsgResultCom db      'The computed solution: ', 0
        aszMsgResultExa db      'The exact solution   : ', 0
        aszPressLeftAlt db      0Dh, 0Ah, 0Dh, 0Ah, "Press Left Alt to exit", 0
        dwColorComput   dd      FOREGROUND_RED
        dwColorExact    dd      FOREGROUND_GREEN
        dwColorWhite    dd      FOREGROUND_RED + FOREGROUND_GREEN + FOREGROUND_BLUE
        dwCursorPositionComput  COORD   <20, 10>
        dwCursorPositionExact   COORD   <20, 11>
.data?
        Eps             dq      ?
        Z               dq      ?
        ResultComput    dq      ?
        ResultExact     dq      ?
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
 
.code
 
start:
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
        ;очистка экрана
        invoke  ClearScreen
        ;ввод X
        invoke  WriteConsole, hConsoleOutput, ADDR aszPromptZ,\
                LENGTHOF aszPromptZ - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
        lea     esi,    [Buffer]        ;удаление из буфера
        add     esi,    [BufLen]        ;символов перевода строки
        mov     [esi-2],word ptr 0
        finit
        invoke  StrToFloat, ADDR Buffer, ADDR Z
        ;ввод Eps
        invoke  WriteConsole, hConsoleOutput, ADDR aszPromptEps,\
                LENGTHOF aszPromptEps - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
        lea     esi,    [Buffer]        ;удаление из буфера
        add     esi,    [BufLen]        ;символов перевода строки
        mov     [esi-2],word ptr 0
        finit
        invoke  StrToFloat, ADDR Buffer, ADDR Eps
 
        ;вычисление суммы ряда
        finit
        fld     [Z]                     ;st(3) Z
        fld1                            ;st(2) K=1
        fld1                            ;st(1) Uk=1
        fld1                            ;st(0) Sum=1
        @@repeat:
                fld     st(2)           ;2K, (2K-1)
                fadd    st(0),  st(0)
                fld     st(0)
                fld1
                fsubp   st(1),  st(0)
 
                fmul    st(0),  st(5)   ;(2K-1)*(Z)
                fmul    st(0),  st(3)   ;(2K-1)*(Z)*Uk
 
                fxch    st(1)
                fdivp   st(1),  st(0)   ;(2K-1)*(Z)*Uk/(2K)
                fchs                    ;-(2K-1)*(Z)*Uk/(2K)
 
                fst     st(2)           ;сохранить в Uk
 
                fadd    st(1),  st(0)   ;Sum=Sum+Uk
 
                fld1                    ;K=K+1
                faddp   st(4),  st(0)
 
                fabs                    ;if abs(Uk) < Eps
                fcomp   [Eps]           ;    break;
                fstsw   ax
                sahf
 
        jae     @@repeat
 
        fstp    [ResultComput]
 
        ;вычисление точного значения
        finit
        fld1                    ;числитель
        fld1                    ;знаменатель
        fld     [Z]
        faddp   st(1),  st(0)
        fsqrt
        fdivp   st(1),  st(0)
        fstp    [ResultExact]
 
        ;вывод результата вычисления ряда
        ; - смена цвета
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorComput]
        ; - установка позиции
        invoke  SetConsoleCursorPosition, hConsoleOutput, dword ptr [dwCursorPositionComput]
        ; - вывод
        invoke  WriteConsole, hConsoleOutput, ADDR aszMsgResultCom,\
                LENGTHOF aszMsgResultCom - 1, ADDR BufLen, NULL
        invoke  FloatToStr2, [ResultComput], ADDR Buffer
        invoke  StrLen, ADDR Buffer
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
        ;вывод результата вычисления точного значения
        ; - смена цвета
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorExact]
        ; - установка позиции
        invoke  SetConsoleCursorPosition, hConsoleOutput, dword ptr [dwCursorPositionExact]
        ; - вывод
        invoke  WriteConsole, hConsoleOutput, ADDR aszMsgResultExa,\
                LENGTHOF aszMsgResultExa - 1, ADDR BufLen, NULL
        invoke  FloatToStr2, [ResultExact], ADDR Buffer
        invoke  StrLen, ADDR Buffer
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия Left Alt
        invoke  SetConsoleTextAttribute, hConsoleOutput, [dwColorWhite]
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressLeftAlt,\
                LENGTHOF aszPressLeftAlt - 1, ADDR BufLen, NULL
        @@WaitForLAlt:
                invoke  GetAsyncKeyState, VK_LMENU
                and     eax,    8000h
        jz      @@WaitForLAlt
        ;завершение программы
        invoke  ExitProcess, 0
 
end start

Новые блоги и статьи Все статьи Все блоги /
Символьное дифференцирование igorrr37 13.02.2026 / * Логарифм записывается как: (x-2)log(x^2+2) - означает логарифм (x^2+2) по основанию (x-2). Унарный минус обозначается как ! */ #include <iostream> #include <stack> #include <cctype>. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»
SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL3_image 8Observer8 10.02.2026 Содержание блога Библиотека SDL3_image содержит инструменты для расширенной работы с изображениями. Пошагово создадим проект для загрузки изображения формата PNG с альфа-каналом (с прозрачным. . .	Установка Qt-версии Lazarus IDE в Debian Trixie Xfce volvo 10.02.2026 В общем, достали меня глюки IDE Лазаруса, собранной с использованием набора виджетов Gtk2 (конкретно: если набирать текст в редакторе и вызвать подсказку через Ctrl+Space, то после закрытия окошка. . .

@Nik_olala 0 / 0 / 0 Регистрация: 26.11.2017 Сообщений: 1

	Вычислить сумму ряда с заданной точностью 26.11.2017, 21:11. Показов 1072. Ответов 2 Метки нет (Все метки) Здравствуйте,обращаюсь к вам первый раз за помощью,так как новичок и очень нужна помощь. Нужно найти сумму элементов заданного ряда,если задана формула которая выражает каждый член последовательности через предыдущие члены(так называемая рекуррентная формула). Миниатюры 0

ФедосеевПавел Модератор 8655 / 4491 / 1669 Регистрация: 01.02.2015 Сообщений: 13,900 Записей в блоге: 12
	26.11.2017, 21:21
	Попробуйте адаптировать под собственное условие одну из тем с названием "Вычислить сумму ряда с заданной точностью". 0