Вычислить сумму ряда с заданной точностью

.486
.model flat, stdcall
option casemap :none
 
        include d:\masm32\include\windows.inc
 
        include d:\masm32\include\user32.inc
        include d:\masm32\include\kernel32.inc
        include d:\masm32\include\masm32.inc
 
        includelib d:\masm32\lib\user32.lib
        includelib d:\masm32\lib\kernel32.lib
        includelib d:\masm32\lib\masm32.lib
.data
        Eps             dq      0.001
        Result          dq      ?
 
        aszPromptEps    db      0Dh, 0Ah, 'Enter the Esc: ', 0
        aszMsgResult    db      0Dh, 0Ah, 'Result: ', 0
        aszPressEnter   db      0Dh, 0Ah, 0Dh, 0Ah, "Press ENTER to exit", 0
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
.code
 
start:
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
 
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
 
        invoke  ClearScreen
        ;ввод Eps
        invoke  WriteConsole, hConsoleOutput, ADDR aszPromptEps,\
                LENGTHOF aszPromptEps - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
        lea     esi,    [Buffer]        ;удаление из буфера
        add     esi,    [BufLen]        ;символов перевода строки
        mov     [esi-2],word ptr 0
        finit
        invoke  StrToFloat, ADDR Buffer, ADDR Eps
        ;вычисление суммы ряда
        finit
        fld1
        fld1
        fldz
        ;st(0) - сумма ряда
        ;st(1) - i
        ;st(2) - 1
        @@repeat:
                fld1                    ;числитель
                fld     st(2)           ;знаменатель i*(i+1)
                fadd    st(0),  st(4)
                fmul    st(0),  st(3)
                fdivp   st(1),  st(0)   ;1/(i*(i+1))
                fadd    st(1),  st(0)   ;Sum:=Sum+1/(i*(i+1))
 
                fld1
                faddp   st(3),  st(0)   ;i=i+1
 
                fabs                    ;if abs(1/(i*(i+1))) < Eps
                fcomp   [Eps]           ;    break;
                fstsw   ax              ;word ptr [FpuSw]
                ;mov     ax,     [FpuSw]
                sahf
 
        jae     @@repeat
 
        fstp    [Result]
        ;очистка FPU
        finit
        ;вывод результата
        invoke  WriteConsole, hConsoleOutput, ADDR aszMsgResult,\
                LENGTHOF aszMsgResult - 1, ADDR BufLen, NULL
        invoke  FloatToStr2, [Result], ADDR Buffer
        invoke  StrLen, ADDR Buffer
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия ENTER
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressEnter,\
                LENGTHOF aszPressEnter - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
 
        invoke  ExitProcess, 0
 
end start