Вывести на экран график функции

;прога выводит график y=tg(x)-(1/x) 
version m510 ;делаем доступными макрометки @B и @F
include pixels.inc ;содержит макросы вывода точки, осей и символа
N=32000 ;кол-во итераций цикла
.model small
.stack 100h
.data
zero    dd 0.001    ;Порог нечувствительности при приближении к нулю, поскольку присутствует деление на x
gx dd 203.0 ;масштабные коэффициенты
cycleX dd -1.57 ;изменяющаяся переменная 
delta dd 0.0001;величина изменения
xdiv2 dd 320.0 ;середина по X и Y
ydiv2 dd 240.0
xr dw 0 ;координаты выводимой точки
yr dw 0
func db 'y = tg(x)-1/x'
lenfunc=$-func
 
.code
.486
start:
mov ax,@DATA    ;настраиваем сегментный регистр
mov ds,ax
mov cx,N ;количество итераций цикла - 30000 ((15+15)/0.001)
;------------------------------------------------------------------
mov ah,0h ;инициализация графического режима 640х480
mov al,12h
int 10h
;-----------------------------------------------------------------
pusha ;вывод названия ф-ции
mov cx,lenfunc
mov bx,0
l3:
 mov al,func[bx]
 inc bx
 OutCharG bl,02h,03h,al
loop l3
popa
;-----------------------------------------------------------------
AxleX ;рисуем оси
AxleY
    finit ;инициализация сопроцессора
 
l1:
    fld cycleX      ;изменяющаяся переменная х
    fabs            ;|x|
    fcomp zero      ;|x| сравнить с порогом нуля
    fstsw   ax      ;записать флаги сопроцессора в ах
    sahf            ;перенести их в флаги процессора
    jb skip         ;если очередной х близок к 0, не расчитывать эту точку
    fld cycleX      ;х        
    fptan           ;частичный тангенс x
    fdiv            ;tg(x)
    fld1            ;1
    fdiv cycleX     ;1/x
    fsub            ;tg(x)-1/x
    fchs            ;сменить знак 
    fadd ydiv2      ;перевернуть по y, поскольку экранная ось y направлена вниз
    fistp yr        ;сохранить расчитанный y
    fld cycleX      ;x
    fmul gx         ;умножить на коэффициент по х
    fadd xdiv2      ;переместить относительно середины экрана
    fistp xr        ;сохранить расчитанный х
    
 PutPixel xr,yr,0ah ;выводим точку зеленым цветом
skip:
    fld cycleX      ;х
    fadd delta      ;x+delta
    fstp cycleX     ;x=x+delta
loop l1 ;цикл по cx
;--------------------------------------------------------------------
mov ah,1h ;ожидание нажатия клавиши 
int 21h
;--------------------------------------------------------------------
mov ah,0h ;перевод обратно в TextMode
mov al,03h
int 10h
;--------------------------------------------------------------------
exit:
mov ax,4C00h ;стандартный выход
int 21h
END start