График функции в оконном приложении

{$mode objfpc}{$H+}
{$smartlink on}
{$APPTYPE GUI}
 
{
Sine Wave using Polyline
(c) Charlie Petzold, 1996
 
Ported on FPC by !!FPA!! 21/01/2009
}
 
PROGRAM SineWave;
USES
  Windows;
CONST
  Num     = 1000;
  TwoPi   = 2*Pi;
 
FUNCTION WndProc (v_hWnd, v_iMsg : LongWord;
                  v_wParam, v_lParam : LongInt):LongInt; stdcall;
CONST
  cxClient    : Integer   = 0;
  cyClient    : Integer   = 0;
VAR
  v_hDC       : HDC;
  i           : Integer;
  ps          : PAINTSTRUCT;
  pt          : array [0..NUM-1] of POINT;
BEGIN
  case v_iMsg of
    WM_SIZE     :
      begin
        cxClient:=Lo(v_lParam);
        cyClient:=Hi(v_lParam);
 
        Result:=0;
        Exit;
      end;
    WM_PAINT    :
      begin
        v_hDC:=BeginPaint(v_hWnd, ps);
 
        MoveToEx(v_hDC, 0       , cyClient div 2, nil);
        LineTo  (v_hDC, cxClient, cyClient div 2);
 
        for i:=0 to NUM-1 do begin
          pt[i].x:=(i*cxClient) div Num;
          pt[i].y:=Round((cyClient div 2)*(1-sin(TwoPi*i/Num)));
        end;
        Polyline(v_hDC, pt, Num);
 
        EndPaint(v_hWnd, ps);           // !!FPA!! 21/01/2009
                                        // was absent on original
        Result:=0;
        Exit;
      end;
    WM_DESTROY  :
      begin
        PostQuitMessage(0);
        Result:=0;
        Exit;
      end;
  end;
  Result:=DefWindowProc(v_hWnd, v_iMsg, v_wParam, v_lParam);
END;
 
 
 
CONST
  szAppName   : String = 'SineWave';
VAR
  v_hWnd      : HWND;
  v_Msg       : MSG;
  v_WndClass  : WNDCLASSEX;
 
  v_hInstance : HWND;                   // !!FPA!! 21/01/2009
  v_iCmdShow  : LongInt;                // !!FPA!! 21/01/2009
 
BEGIN
  v_hinstance:=GetModuleHandle(nil);
  with v_WndClass do begin
    cbSize        := SizeOf(v_WndClass);
    Style         := CS_HREDRAW OR CS_VREDRAW;
    lpfnWndProc   := @WndProc;
    cbClsExtra    := 0;
    cbWndExtra    := 0;
    hInstance     := v_hInstance;
    hIcon         := LoadIcon(0, IDI_APPLICATION);
    hCursor       := LoadCursor(0, IDC_ARROW);
    hbrBackground := HBRUSH( GetStockObject(WHITE_BRUSH) );
    lpszMenuName  := nil;
    lpszClassName := PChar(szAppName);
    hIconSm       := LoadIcon(0, IDI_APPLICATION);
  end;
 
  RegisterClassEx(v_WndClass);
 
  v_hWnd:=CreateWindow(
    PChar(szAppName),
    'Sine Wave Using Polyline',
    WS_OVERLAPPEDWINDOW,
    CW_USEDEFAULT,
    CW_USEDEFAULT,
    CW_USEDEFAULT,
    CW_USEDEFAULT,
    0,
    0,
    v_hInstance,
    nil
  );
 
  v_iCmdShow:=SW_SHOW;
  ShowWindow(v_hWnd, v_iCmdShow);
  UpdateWindow(v_hWnd);
 
  while GetMessage(v_Msg, 0, 0, 0) do begin
    TranslateMessage(v_Msg);
    DispatchMessage (v_Msg);
  end;
  Halt(v_Msg.wParam);
END.