Кодировка в командной строке

;  Простая программа на ассемблере
 
       TITLE   Primer1    ; Заголовок программы
       PAGE    52,72      ; Размер страницы листинга
       INCLUDE macroio.inc  ; Включение
           ; спецификаций для файлов макроопределений
 
;      Сегмент данных
DATA   SEGMENT
;      Директивы определения данных
cr  equ 13  ; символ возврата каретки
lf  equ 10  ; символ перевода строки
soob    db  'D. Smith передает привет! $'
n   dw  6   ; число элементов массива
ma  dw  -156, 71, 1590, -8261, 12854,-57
str1    db  'Входной массив',cr,lf,'$'
str2    db  'Первый элемент массива - $'
viv db  240 dup(?) ; строка для вывода чисел
DATA   ENDS
 
;      Сегмент команд
PROG   SEGMENT 'CODE'
; Указание ассемблеру планировать по сегментному
; регистру все метки и имена, определяемые в 
; конкретном сегменте
       ASSUME  DS:DATA,ES:DATA,CS:PROG,SS:SPROG
START:                 ; Стартовая точка программы
       MOV     AX,DATA ;Назначение регистрам DS и
       MOV     DS,AX   ;ES адреса сегмента данных
       MOV     ES,AX
;      Команды программы
    @DispStr    soob    ; вывод сообщения
    @DispCh cr lf   ; переход на новую строку
 
; Вывод первого числа массива
    @DispStr    str2
    puti        2,ma,viv
    @DispStr    viv
    @DispCh cr lf
; Вывод всего массива
    @DispStr    str1
    mputi       2,n,ma,viv
    @DispStr    viv
    @DispCh cr lf
 
; Окончание программы, выход в DOC
       @Exit       ; Макрокоманда окончания программы
PROG   ENDS        ; Директива окончания сегмента
 
;      Сегмент стека размером 512 байт
SPROG  SEGMENT STACK   'STACK'
       DB      512 DUP(?)
SPROG  ENDS
       END     START  ; Директива окончания программы

; DOS Interface Macros - Version 1.0 - for Microsoft Macro Assembler 5.0
; (C) Copyright Microsoft Corporation, 1987, 1988.
; (C) Copyright ***, Кафедра ***, 1996.
 
.XCREF
.XLIST
IF1
; Internal
__LdAdr MACRO reg, adr
    IF (.TYPE (adr)) AND 00010000b     ;; Register
        mov     reg, adr
    ELSEIF (.TYPE (adr)) AND 00000100b ;; Constant
        mov     reg, adr
    ELSEIF TYPE (adr) LE 10            ;; Bytes
        mov    reg, OFFSET adr
    ELSEIF TYPE (adr) EQ 0FFFFh        ;; Near pointer
        mov    reg, adr
    ELSEIF TYPE (adr) EQ 0FFFEh        ;; Far pointer
        lds    reg, adr
    ELSE
        .ERR
        %OUT Неправильный аргумент &adr
    ENDIF
ENDM
 
; Internal
__LdSeg MACRO dest, src
    IFIDNI <src>, <es>                 ;; Segment register
        mov     ax, src
        mov     dest, ax
    ELSEIFIDNI <src>, <ss>
        mov     ax, src
        mov     dest, ax
    ELSEIFIDNI <src>, <ds>
        mov     ax, src
        mov     dest, ax
    ELSEIFIDNI <src>, <ds>
        mov     ax, src
        mov     dest, ax
    ELSEIF (.TYPE (src)) AND 00000100b ;; Constant
        mov     ax, src
        mov     dest, ax
    ELSE                               ;; Memory or general register 
        mov     dest, src
    ENDIF
ENDM
 
; 01h, 07h, 08h, 0Ch
@GetKey MACRO echo, cc, clear
    LOCAL   funct, disp
    IFDIF   <echo>, <0>
        IFDIF   <cc>, <0>
            funct   = 01h
        ELSE
            funct   = 07h
            disp    = 02h
        ENDIF
    ELSE
        IFDIF   <cc>, <0>
            funct   = 08h
        ELSE
            funct   = 07h
        ENDIF
    ENDIF
    IFB     <clear>
        mov     ah, funct
    ELSE
        IFIDN   <clear>, <0>
            mov     ah, funct
        ELSE
            mov     ah, 0Ch
            mov     al, funct
        ENDIF
    ENDIF
    int     21h
    IFDEF   disp
        mov     dl, al
        mov     ah, disp
        int     21h
    ENDIF
ENDM
 
; 0Ah
@GetStr MACRO ofset, terminator, limit, segmnt
    __LdAdr dx, <ofset>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 0Ah
    mov     si, dx
    IFNB    <limit>
        mov     BYTE PTR [si], limit
    ENDIF
    int     21h
    inc     si
    mov     bl, [si]
    sub     bh, bh
    inc     si
    IFNB    <terminator>
        mov     BYTE PTR [bx+si], terminator
    ENDIF
ENDM
 
; 02h
@DispCh MACRO ch1, ch2, ch3, ch4, ch5, ch6, ch7, ch8, ch9, ch10
    mov     ah, 02h
    IRP     char, <ch1, ch2, ch3, ch4, ch5, ch6, ch7, ch8, ch9, ch10>
        IFB     <char>
            EXITM
        ENDIF
        mov     dl, char
        int     21h
    ENDM
ENDM
 
 
; 09h
@DispStr MACRO ofset, segmnt
    __LdAdr dx, <ofset>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 9
    int     21h
ENDM
 
; 3Fh
@Read MACRO ofset, bytes, handle, segmnt
    IFNB    <handle>
        mov     bx, handle
    ELSE
        sub     bx, bx
    ENDIF
    mov     cx, bytes
    __LdAdr dx, <ofset>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 3Fh
    int     21h
ENDM
 
; 40h
@Write MACRO ofset, bytes, handle, segmnt
    IFNB    <handle>
        mov     bx, handle
    ELSE
        mov     bx, 1
    ENDIF
    mov     cx, bytes
    __LdAdr dx, <ofset>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 40h
    int     21h
ENDM
 
; 4Ch
@Exit MACRO return
    IFB     <return>
        mov     ah, 4Ch
    ELSE
        mov     ax, 4C00h + (return AND 0FFh)
    ENDIF
    int     21h
ENDM
 
; 25h
@SetInt MACRO interrupt, vector, segmnt
    IF      TYPE (vector) GE 0FFFEh
        mov     dx, OFFSET vector
        mov     ax, SEG vector
        mov     ds, ax
    ELSE
        __LdAdr dx, <vector>
        IFNB    <segmnt>
            __LdSeg ds, <segmnt>
        ENDIF
    ENDIF
    mov     ax, 2500h + (interrupt AND 0FFh)
    int     21h
ENDM
 
; 3Ch
@MakFil MACRO path, atrib, segmnt, kind
    IFB     <atrib>
        sub     cx, cx
    ELSE
        mov     cx, atrib
    ENDIF
    __LdAdr dx, <path>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    IFIDNI  <kind>, <tmp>
        mov     ah, 5Ah
    ELSEIFIDNI <kind>, <new>
        mov    ah, 5Bh
    ELSE
        mov    ah, 3Ch
    ENDIF
    int     21h
ENDM
 
; 3Dh
@OpenFil MACRO path, access, segmnt
    __LdAdr dx, <path>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ax, 3D00h + (access AND 0FFh)
    int     21h
ENDM
 
; 3Eh
@ClosFil MACRO handle
    mov     bx, handle
    mov     ah, 3Eh
    int     21h
ENDM
 
; 41h
@DelFil MACRO path, segmnt
    __LdAdr dx, <path>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 41h
    int     21h
ENDM
 
; 56h
@MoveFil MACRO old, new, segold, segnew
    __LdAdr dx, <old>
    __LdAdr di, <new>
    IFNB    <segold>
        __LdSeg ds, <segold>
    ENDIF
    IFNB    <segnew>
        __LdSeg es, <segnew>
    ENDIF
    mov     ah, 56h
    int     21h
ENDM
 
; 4Eh
@GetFirst MACRO path, atrib, segmnt
    IFNB    <atrib>
        mov     cx, atrib
    ELSE
        sub     cx, cx
    ENDIF
    __LdAdr dx, <path>
    IFNB    <segmnt>
        __LdSeg ds, <segmnt>
    ENDIF
    mov     ah, 4Eh
    int     21h
ENDM
 
; 4Fh
@GetNext MACRO
    mov     ah, 4Fh
    int     21h
ENDM
 
; 42h
@GetFilSz MACRO handle
    mov     bx, handle
    sub     cx, cx
    sub     dx, dx
    mov     ax, 4202h
    int     21h
    push    dx
    push    ax
    sub     dx, dx
    mov     ax, 4200h
    int     21h
    pop     ax
    pop     dx
ENDM
 
; Internal
__LdDub MACRO dub
    IF   TYPE (dub) EQ 2
        sub  cx, cx
        mov  dx, dub
    ELSEIF TYPE (dub) EQ 4
        mov  cx, dub[2]
        mov  dx, dub[0]
    ELSEIF TYPE (dub) EQ 0
        sub     cx, cx
        mov     dx, dub
    ELSE
        .ERR
        %OUT Illegal argument
    ENDIF
ENDM
 
; 42h
@MovePtrAbs MACRO handle, distance
    IFNB    <distance>
        __LdDub <distance>
    ENDIF
    mov     bx, handle
    mov     ax, 4200h
    int     21h
ENDM
 
; 42h
@MovePtrRel MACRO handle, distance
    IFNB    <distance>
        __LdDub <distance>
    ENDIF
    mov     bx, handle
    mov     ax, 4201h
    int     21h
ENDM
 
; 
; Перевод целого числа формата байт в символьную форму
;   extrn   pti1:far
ptb macro   Anum,Astrng,Width,Rad,Sign
    local   osn,shir
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
    IFB <Rad>
    osn =   10
    mov DL,10
    ELSEIFIDN   <Rad>,<10>
    mov DL,10
    osn =   10
    ELSEIFIDN   <Rad>,<16>
    mov DL,16
    osn =   16
    ELSEIFIDN   <Rad>,<2>
    mov DL,2
    osn =   2
    ELSE
       %out 'Неправильное основание &Rad системы счисления'
       .err
    ENDIF
    IFB <Sign>
    mov DH,1
    ELSEIFIDN   <Sign>,<1>
    mov DH,1
    ELSEIFIDN   <Sign>,<0>
    mov DH,0
    ELSE
       %out 'Неправильный признак &Sign знака числа'
       .err
    ENDIF
    IFNB    <Width>
    mov BX,Width
    ELSEIF  (osn EQ 10) OR (osn EQ 16)
    mov BX,5
    ELSEIF  osn EQ 2
    mov BX,10
    ENDIF
    call    far ptr pti1
    endm
 
;
; Перевод массива чисел формата байт в символьную форму
mptb    macro   Many,Anum,Astrng,Width,Rad,Sign
    local   cc
    mov CX,Many
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
cc: ptb SI,DI,Width,Rad,Sign
    loop    cc
    endm
 
;
; Перевод числа формата слово в символьную форму
;   extrn   pti2:far
ptw macro   Anum,Astrng,Width,Rad,Sign
    local   osn,shir
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
    IFB <Rad>
    osn =   10
    mov DL,10
    ELSEIFIDN   <Rad>,<10>
    mov DL,10
    osn =   10
    ELSEIFIDN   <Rad>,<16>
    mov DL,16
    osn =   16
    ELSEIFIDN   <Rad>,<2>
    mov DL,2
    osn =   2
    ELSE
       %out 'Неправильное основание &Rad системы счисления'
       .err
    ENDIF
    IFB <Sign>
    mov DH,1
    ELSEIFIDN   <Sign>,<1>
    mov DH,1
    ELSEIFIDN   <Sign>,<0>
    mov DH,0
    ELSE
       %out 'Неправильный признак &Sign знака числа'
       .err
    ENDIF
    IFNB    <Width>
    mov BX,Width
    ELSEIF  (osn EQ 10) OR (osn EQ 16)
    mov BX,8
    ELSEIF  osn EQ 2
    mov BX,20
    ENDIF
    call    far ptr pti2
    endm
 
;
; Перевод массива чисел формата слово в символьную форму
mptw    macro   Many,Anum,Astrng,Width,Rad,Sign
    local   cc
    mov CX,Many
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
cc: ptw SI,DI,Width,Rad,Sign
    loop    cc
    endm
 
; 
; Перевод числа формата двойное слово в символьную форму
;   extrn   pti4:far
ptd macro   Anum,Astrng,Width,Rad,Sign
    local   osn,shir
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
    IFB <Rad>
    osn =   10
    mov DL,10
    ELSEIFIDN   <Rad>,<10>
    mov DL,10
    osn =   10
    ELSEIFIDN   <Rad>,<16>
    mov DL,16
    osn =   16
    ELSEIFIDN   <Rad>,<2>
    mov DL,2
    osn =   2
    ELSE
       %out 'Неправильное основание &Rad системы счисления'
       .err
    ENDIF
    IFB <Sign>
    mov DH,1
    ELSEIFIDN   <Sign>,<1>
    mov DH,1
    ELSEIFIDN   <Sign>,<0>
    mov DH,0
    ELSE
       %out 'Неправильный признак &Sign знака числа'
       .err
    ENDIF
    IFNB    <Width>
    mov BX,Width
    ELSEIF  (osn EQ 10) OR (osn EQ 16)
    mov BX,16
    ELSEIF  osn EQ 2
    mov BX,40
    ENDIF
    call    far ptr pti4
    endm
 
;
; Перевод массива чисел формата двойное слово в символьную форму
mptd    macro   Many,Anum,Astrng,Width,Rad,Sign
    local   cc
    mov CX,Many
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
cc: ptd SI,DI,Width,Rad,Sign
    loop    cc
    endm
; Вывод одного числа любого формата кода
puti    macro   Fcod,Anum,Astrng,Width,Rad,Sign
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
    IF  (Fcod NE 1) and (Fcod NE 2) and (Fcod NE 4)
    .ERR
    %out    'Неправильный аргумент &Fcod кода числа.'
    %out    'Допустимы значения 1, 2 или 4'
    EXITM
    ENDIF
    extrn   pti&Fcod :far
    IFB <Rad>
    osn =   10
    mov DL,10
    ELSEIFIDN   <Rad>,<10>
    mov DL,10
    osn =   10
    ELSEIFIDN   <Rad>,<16>
    mov DL,16
    osn =   16
    ELSEIFIDN   <Rad>,<2>
    mov DL,2
    osn =   2
    ELSE
       %out 'Неправильный аргумент &Rad основания системы счисления'
       .err
    ENDIF
    IFB <Sign>
    mov DH,1
    ELSEIF  Sign LE 1
    mov DH,Sign
    ELSE
       %out 'Неправильный признак &Sign знака числа'
       .err
    ENDIF
    IFNB    <Width>
    mov BX,Width
    ELSEIF  osn EQ 2
    mov BX,Fcod*10
    ELSE
    mov BX,Fcod*5
    ENDIF
    call    far ptr pti&Fcod
    endm
; Вывод массивом
mputi   macro   Fcod,Many,Anum,Astrng,Width,Rad,Sign
    local   cc
    mov CX,Many
    __LdAdr SI,<Anum>
    __LdAdr DI,<Astrng>
cc: puti    Fcod,SI,DI,Width,Rad,Sign
    loop    cc
    endm
ENDIF   ; Pass 1
.cref
.list

Строка 22:  
%OUT Неправильный аргумент &adr
должна выглядеть так:  
%OUT 'Неправильный аргумент &adr'