Головоломка про 6 лягушек

@Alex_fuse · Регистрация: 27.11.2012

Студворк — интернет-сервис помощи студентам

Нужно поменять всех лягушек местами – коричневых на место зеленых, зеленых, соответственно, на место коричневых. Прыгают обитательницы пруда либо на рядом находящуюся свободную кочку, либо на незанятое место друг через друга.
расположение лягушек К-кориченвые З-зеленые 0-пустое место
ККК0ЗЗЗ
Подскажите в каком направлении двигаться, как описать условия?

@iloveoOz · 15.01.2025, 11:51

Задача интересная.
Визуально попрыгать можно здесь: https://www.min2win.ru/game/ly... olote.html
Вот вариант решения непосредственно от автора языка Гари Райли.

CLIPS (6.4.1 4/8/23)

Lisp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
(deftemplate line
   (slot id (default-dynamic (gensym*)))
   (slot parent (default none))
   (multislot state))
 
(deftemplate solution
   (slot ready (default no))
   (multislot steps))
 
(deffacts start
   (line (id start) (state M M M _ F F F)))
 
(defrule move-male-to-lily
   (line (id ?id) (state $?b M _ $?e))
   =>
   (assert (line (parent ?id) (state ?b _ M ?e))))
 
(defrule move-male-jump-over-to-lily
   (line (id ?id) (state $?b M ?o _ $?e))
   =>
   (assert (line (parent ?id) (state ?b _ ?o M ?e))))
 
(defrule move-female-to-lily
   (line (id ?id) (state $?b _ F $?e))
   =>
   (assert (line (parent ?id) (state ?b F _ ?e))))
 
(defrule move-female-jump-over-to-lily
   (line (id ?id) (state $?b _ ?o F $?e))
   =>
   (assert (line (parent ?id) (state ?b F ?o _ ?e))))
 
(defrule solution-found
   (line (id ?id) (state F F F _ M M M))
   =>
   (println crlf "Solution Found: " crlf)
   (assert (solution (steps ?id))))
  
(defrule add-to-solution
   ?s <- (solution (ready no) (steps ?id $?rest))
   (line (id ?id) (parent ?next))
   =>
   (modify ?s (steps ?next ?id ?rest)))
 
(defrule solution-ready
   ?s <- (solution (ready no) (steps none $?rest))
   =>
   (modify ?s (ready yes) (steps ?rest)))
 
(defrule print-solution
   ?s <- (solution (ready yes) (steps ?id $?rest))
   (line (id ?id) (state $?state))
   =>
   (println (implode$ ?state))
   (modify ?s (steps ?rest)))

CLIPS> (reset)
CLIPS> (run)

Solution Found:

M M M _ F F F
M M _ M F F F
M M F M _ F F
M M F M F _ F
M M F _ F M F
M _ F M F M F
_ M F M F M F
F M _ M F M F
F M F M _ M F
F M F M F M _
F M F M F _ M
F M F _ F M M
F _ F M F M M
F F _ M F M M
F F F M _ M M
F F F _ M M M

Solution Found:

M M M _ F F F
M M M F _ F F
M M _ F M F F
M _ M F M F F
M F M _ M F F
M F M F M _ F
M F M F M F _
M F M F _ F M
M F _ F M F M
_ F M F M F M
F _ M F M F M
F F M _ M F M
F F M F M _ M
F F M F _ M M
F F _ F M M M
F F F _ M M M
CLIPS>

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .
И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .

@Alex_fuse 2 / 2 / 3 Регистрация: 27.11.2012 Сообщений: 42

	Головоломка про 6 лягушек 17.04.2018, 14:57. Показов 4329. Ответов 1 Метки clips, головоломка, задача (Все метки) Нужно поменять всех лягушек местами – коричневых на место зеленых, зеленых, соответственно, на место коричневых. Прыгают обитательницы пруда либо на рядом находящуюся свободную кочку, либо на незанятое место друг через друга. расположение лягушек К-кориченвые З-зеленые 0-пустое место ККК0ЗЗЗ Подскажите в каком направлении двигаться, как описать условия? 0

Головоломка про 6 лягушек

Решение