Разделить большой текстовый файл на множество файлов

@echo off
SetLocal EnableExtensions
 
:: Путь и имя исходного файла
set src=text.txt
:: Путь, где создавать разрезанные файлы
set dest=.
 
For /F "UseBackQ Delims=" %%a in ("%src%") do call :SaveText "%%a"
pause
Exit /B
 
:SaveText %1-text
  set "text=%~1"
  if "%text:~,1%"=="*" (set "CurFile=%text:~1%.txt") else (>>"%dest%\%CurFile%" echo %~1)
Exit /B

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
:: Путь и имя исходного файла
set src=text.txt
:: Путь, где создавать разрезанные файлы
set dest=.
 
For /F "UseBackQ Delims=" %%a in ("%src%") do (
  set "text=%%a"
  if "!text:~,1!"=="*" (set "CurFile=!text:~1!.txt") else (>>"%dest%\!CurFile!" echo %%a)
)
pause
Exit /B

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
:: Путь и имя исходного файла
set src=text.txt
:: Путь, где создавать разрезанные файлы
set dest=.
 
chcp 866 >nul 
For /F "UseBackQ Delims=" %%a in ("%src%") do (
  set "text=%%a"
  if "!text:~,1!"=="*" (
    set "Safe_bufer=%%a"
    call :RecodeDosToWin
  ) else (
    >>"!CurFile!" echo %%a
  )
)
pause
Exit /B
 
:RecodeDosToWin
for /f "delims=" %%a in ("!Safe_bufer!") do (
   chcp 1251> nul
   call :convert "%%a" 2>NUL
)
chcp 866 >nul
goto :eof
 
:convert
set "CurFile=%dest%\%~1.txt"

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
:: Путь и имя исходного файла
set src=text.txt
:: Путь, где создавать разрезанные файлы
set dest=.
 
chcp 1251 >nul
For /F "UseBackQ Delims=" %%a in ("%src%") do (
  set "text=%%a"
  if "!text:~,1!"=="*" (
    chcp 866 >NUL
    set cp=
    call :recode "%%a"
  ) else (
    if not Defined cp (chcp 1251 >nul& set cp=true)
    call :append "%%a"
  )
)
chcp 866 >NUL
pause
Exit /B
 
:recode
  set "CurFile=%~1.txt"
  set "CurFile=%dest%\!CurFile:~1!"
exit /B
 
:append
  set "buf=%~1"
  >>"!CurFile!" echo !buf!
exit /B