Необходимо оставить в папке самые старые файлы и два самых новых

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
set src=c:\papka
 
set c=0
For /F "Delims=" %%a in ('dir /TC /OD /B /A-D "%src%\*" 2^>NUL ^| more +3') do set /A c+=1& set "file.!c!=%%a"
if %c%==0 exit /B
set /A c-=2
 
For /L %%n in (1,1,%c%) do del /F /Q "%src%\!file.%%n!"

@echo off
setlocal enabledelayedexpansion
 
set tt=%date:~6,4%%date:~3,2%%date:~0,2%
:: дата минус два дня
set /a tt1=%tt%-2
 
:: сортируем файлы по дате от ранних к поздним, пропускаем первые три даты (три самых старых файла)
for /f "skip=3 delims=" %%a in ('dir /b /s /a-d /od "c:\1\CMDEXE_HELP\*"') do (
set dt=%%~ta
set dt1=!dt:~6,4!!dt:~3,2!!dt:~0,2!
if !dt1! LSS %tt1% echo del /q "%%a"
)
pause
exit /b

@echo off
setlocal enabledelayedexpansion
 
:: считаем по календарю два дня назад (чтобы не удалять двухдневные файлы)
set d=%date:~0,2%
set m=%date:~3,2%
set y=%date:~6,4%
 
if %d:~0,1%==0 set d=%d:~1%
if %m:~0,1%==0 set m=%m:~1%
 
set /a feb=y%%4
if %feb%==0 (set feb=29) else (set feb=28)
 
set /a tok=m-1
if %tok%==0 set tok=12
for /f "tokens=%tok%" %%i in ("31 %feb% 31 30 31 30 31 31 30 31 30 31") do (
   set /a d-=2
    if !d!==0 (
        set d=%%i
        set m=%tok%
        if !m!==12 set /a y-=1
    )
)
 
set d=0%d%
set m=0%m%
set tt=%d:~-2%.%m:~-2%.%y%
:: меняем представление даты
set tt1=%tt:~6,4%%tt:~3,2%%tt:~0,2%
 
:: сортируем файлы по дате от ранних к поздним, пропускаем первые три даты (файла)
for /f "skip=3 delims=" %%a in ('dir /b /s /a-d /od "c:\1\CMDEXE_HELP\*"') do (
set dt=%%~ta
set dt1=!dt:~6,4!!dt:~3,2!!dt:~0,2!
if !dt1! LSS %tt1% echo del /q "%%a"
)
pause
exit /b