Поиск в реестре параметра и замена его значения

@echo off
SetLocal EnableExtensions
 
set root=HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles
set param=Leave on Server
set value=0xe0002
 
For /F "delims=" %%a in ('reg query "%root%" /f "%param%" /s ^| find /i "%root%"') do (
  echo Found: %%a
  reg add "%%a" /v "%param%" /t REG_DWORD /d %value% /f
)
 
pause

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
set root=HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles
set param=Leave on Server
set value=0xe0002
 
call :RegEnum "%root%" "%param%"
if errorlevel 1 For /L %%C in (1,1,%errorlevel%) do (
  echo "!return.%%C!"
  reg add "!return.%%C!" /v "%param%" /t REG_DWORD /d %value% /f
)
pause
exit /B
 
:RegEnum %1-key %2-parameter
  :: Поиск параметра в разделe %1 и всех его подразделах (совместимо с reg.exe ver.3,4,5)
  :: код возврата - кол-во ключей в словаре Return.
  set return=0
  reg query "%~1" /v "%~2" >NUL 2>&1 && (set "return.1=%~1"& set return=1)
  call :RegEnumEx "%~1" "%~2"
Exit /B %return%
 
:RegEnumEx
  :: выход сразу, если в подразделах параметра нет
  reg query "%~1" /s |>NUL find /i "%~2" || exit /B
  For /F "delims=" %%k in ('reg query "%~1" /s ^| find /i "%~1"') do (
    if /i "%%k" neq "%~1" (
      reg query "%%k" /v "%~2" >NUL 2>&1 && (
        set /A return+=1
        set "return.!return!=%%k"
      )
      rem Вглубь
      call :RegEnumEx "%%k" "%~2"
    )
  )
Exit /B

:RegEnum %1-key %2-parameter
  :: Поиск параметра в разделe %1 и всех его подразделах (совместимо с reg.exe ver.3,4,5)
  :: код возврата - кол-во ключей в словаре Return.
  set LastHKEY=& set return=0& set Total=0& set C=0& set HKEYs=0
  For /F "tokens=1* delims=[]" %%a in ('reg query "%~1" /s ^| find /i /n "%~1"') do set "HKEYs.%%a=%%b"& set "HKEYs=%%a"
  For /F "tokens=1* delims=[]" %%a in ('reg query "%~1" /s ^| find /i /n "%~2"') do set /a Total+=1& set "PARAMs.!Total!=%%a"
  if %Total%==0 goto RegEnum_Exit
  :Reg_Enum_Params
  set /a C+=1
  set "nHKEY=!PARAMs.%C%!"
  :Reg_Find_HKEY
  if not Defined HKEYS.%nHKEY% (set /a nHKEY-=1& goto Reg_Find_HKEY)
  set "currHKEY=!HKEYS.%nHKEY%!"
  if "%currHKEY%" neq "%LastHKEY%" (
    set "LastHKEY=%currHKEY%"
    reg query "%currHKEY%" /v "%~2" >NUL 2>&1 && (set /a return+=1& set "return.!return!=%currHKEY%")
  )
  if %C% LSS %Total% goto Reg_Enum_Params
  :RegEnum_Exit
  For /L %%C in (1,1,%HKEYs%) do set "HKEYs.%%C="
  For /L %%C in (1,1,%Total%) do set "PARAMs.%%C="
  set Total=& set C=& set HKEYs=& set LastHKEY=& set currHKEY=& set "nHKEY="
Exit /B %return%