Выделить из текстового файла n-ую строку (использовать find /n и for)

@echo off
set text_file=example.txt
echo Enter the number.
echo.
set /p n=
cls
for /f "delims=" %%i in ('
 ^<"%text_file%" find /n /v ""
') do (
 for /f "delims=]" %%j in ("%%i") do (
  if %%j==[%n% (
   set "string=%%i"
  )
 )
)
if defined string (
 set "string=%string:*]=%"
) else (
 echo Absent string.
 pause>nul
 goto:eof
)
if defined string (
 for /f "delims=" %%i in ("%string%") do (
  echo.%%i
 )
) else (
 echo Empty string.
)
pause>nul
exit /b

@echo off
 
set /p n="введите номер строки: "
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ^<"read.txt"') do (
if "%%a"=="%n%" (set flg=1& echo %%a - %%b)
)
if not defined flg (echo Такой строки нет в файле)
pause

@echo off
 
set /p n="введите номер строки: "
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ^<"read.txt"') do (
if "%%a"=="%n%" (
if not "%%b"=="" (set flg=1& echo %%a - %%b) else (set ln=1)
))
if "%ln%"=="1" (echo Строка %n% пустая) else (if not defined flg (echo Такой строки нет в файле))
pause

@echo off
 
set /p n="введите номер строки: "
for /f "tokens=1* delims=]" %%a in ('find /v /n "" ^<"FSIV.inf"') do (
if "%%a"=="[%n%" (
if not "%%b"=="" (set flg=1& echo %n% - %%b) else (set ln=1)
))
if "%ln%"=="1" (echo Строка %n% пустая) else (if not defined flg (echo Такой строки нет в файле))
pause

@echo off
set n=2
set file=1.txt
find /n /v "" < "%file%" | findstr /R "\[%n%\].*"
rem FOR &:: где-то здесь использовал for :)

@echo off
setlocal enabledelayedexpansion enableextensions
set file=1.txt
set n=2
 
set tN=%n%
:DC
set /a DC+=1
set /a tN/=10
if %tN% neq 0 goto DC
set /a trim=DC+2
For /F "delims=" %%a in ('find /n /v "" ^< "%file%"') do set /a c+=1& if !c!==%n% set "str=%%a"& echo !str:~%trim%!
pause

@echo off
set text_file=example.txt
echo Enter the number.
echo.
set /p n=
cls
for /f "delims=" %%i in ('
 ^<"%text_file%" find /n /v ""^| findstr /bl [%n%]
') do (
 set "string=%%i"
)
if defined string (
 set "string=%string:*]=%"
) else (
 echo Absent string.
 pause>nul
 goto:eof
)
if defined string (
 for /f "delims=" %%i in ("%string%") do (
  echo.%%i
 )
) else (
 echo Empty string.
)
pause>nul
exit /b