Выделить из текстового файла n-ую строку (использовать find /n и for)

@echo off
set string_number=5
for /f "tokens=1* delims=]" %%i in ('^< "example.txt" find /n /v "" ^| findstr /R "\[%string_number%\].*"') do echo %%j
pause>nul
exit /b

@echo off
setlocal enabledelayedexpansion
set "n=5"
set "file=file.txt"
 
for /f "usebackq tokens=1* delims=[]" %%A IN (`find /n /v "" "%file%" ^| find "["`) DO if "%%~A"=="%n%" (
  set "ts=%%~B"
  echo.!ts!
)

@echo off
setlocal enabledelayedexpansion
set "n=5"
set "file=file.txt"
 
for /f "usebackq tokens=1* delims=[]" %%A IN (`find /n /v "" "%file%" ^| findstr /R ^\[%n%\]) DO (
  set "ts=%%~B"
  echo.!ts!
)

@echo off
setlocal EnableExtensions
set "n=5"
set "file=file.txt"
 
(for /L %%A IN (1 1 %n%) DO set ts=&set /p ts=)<"%file%"
echo=%ts%
pause

@echo off
setlocal EnableExtensions EnableDelayedExpansion
set "n=5"
set "file=file.txt"
 
set c=0
for /F "UseBackQ delims= eol=" %%A in ("%file%") do set /a c+=1& if !c!==%n% set ts=%%A
echo %ts%
pause

@echo off
setlocal
set "n=5"
set "file=file.txt"
 
set /a n-=1
more +%n% "%file%" > "%file%_"
< "%file%_" set /p ts=
del "%file%_"
echo=%ts%
pause