Параллельный перенос (переименование)

@alpap · Регистрация: 26.04.2015

Студворк — интернет-сервис помощи студентам

Добрый день форумчане!
Имеется в распоряжении папка: "%Userprofile%\Desktop\papka" в которой лежат папки:
Магазин Воздухофлотский
в ней файл "продажа.txt"
Магазин Гагарина
в ней файл "закупка.txt"
Магазин Героев Днепра
в ней файл "работа.txt"
и надо переименовать папку Магазин Воздухофлотский таким образом: взять имя файла "продажа.txt" добавить к Магазин Воздухофлотский, чтобы получилось Магазин Воздухофлотский продажа. Вроде ничего сложного на первый взгляд:
Выделяем имена файлов:

Windows Batch file
1
2
3
4
5
6
7
@echo on
set "mag=%Userprofile%\Desktop\papka"
cd /d "%mag%"
for /r %%i in ("*.txt") do (
 echo "%%~ni"
)
pause

Выделяем имена папок:

Windows Batch file
1
2
3
4
for /f "delims=" %%j in ('dir /ad /b') do (
  echo "%%j"
)
pause

Пробуем переименовать:

Windows Batch file
1
2
3
4
5
6
7
8
9
@echo on
set "mag=%Userprofile%\Desktop\papka"
cd /d "%mag%"
for /r %%i in ("*.txt") do (
 echo "%%~ni"
for /f "delims=" %%j in ('dir /ad /b') do (
  echo "%%j"
  move "%%j" "%%j %%~ni"))
pause

,
но происходит это только для первой позиции, а оно и понятно, первый for перебирает свое содержимое и каждой позиции присваивает первое (ну не первое, по алфавиту.. - не важно) значение второго for. А как сделать чтобы каждой первой позиции for соответствовала первая позиция второго for, затем вторая и т.д., чтобы вышло в итоге:
Магазин Воздухофлотский продажа
Магазин Гагарина закупка
Магазин Героев Днепра работа?

У меня что-то не хватило мозгов.

Dragokas · 07.08.2015, 19:21

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
@echo off
SetLocal EnableExtensions
set "mag=%Userprofile%\Desktop\papka"
for /d %%i in ("%mag%\*") do call :RenX "%%i"
pause
goto :eof
 
:RenX
  For %%a in ("%~1\*.txt") do set "TXT=%%~na"& goto ext
:ext
  move "%~1" "%~1 %TXT%"
Exit /B

@ComSpec · 07.08.2015, 19:38

Windows Batch file
1
2
3
4
5
@echo off
set "mag=%USERPROFILE%\Desktop\papka"
cd /d "%mag%"
for /r %%i in (*.txt) do for %%j in ("%%~dpi.") do move "%%~nxj" "%%~nxj %%~ni"
pause

@alpap · 07.08.2015, 20:12 **[ТС]**

Dragokas, Спасибо, код работает, только зачем pause в строке 5, если для проверки построчно и перед exit ту же роль выполняет - ну неважно. Не обижайтесь, но лучший ответ поставлю ComSpec, скорее из-за моей неопытности - его код для меня проще (понятнее).

Добавлено через 48 секунд
ComSpec, Все так просто оказывается, а я что-то не допер, Спасибо огромное!

Dragokas · 07.08.2015, 23:46

alpap, разница в том, что у меня сделано с защитами (берет только первое имя txt файла) и не использует рекурсию, а значит нет "висячих" команд.

Для идеальной структуры, как у Вас, конечно все будет работать нормально, но если кое-что поменять,
например, рассмотрим следующую ситуацию:

Имеет такую структуру папок:

tree /F
Структура папок тома Soft
Серийный номер тома: 2821-C54A
H:.
│ test.cmd
│
├───1
│ │ test1.txt
│ │
│ └───2
│ test2.txt
│
└───2
Hello.txt

Применяем скрипт ComSpec.
Вывод:

move "1" "1 test1"
move "2" "2 test2"
move "2" "2 Hello"

Результат: папка 2 будет переименована в "2 test2", а совсем не в то, что мы ожидали увидеть.

P.S. И я не обижаюсь.

@alpap · 08.08.2015, 09:49 **[ТС]**

Dragokas, Ну, если бы Вы сразу мне об этом сказали, правда, с Вашей стороны - может я знал, тогда и оценил бы по-другому. Вот теперь знаю - Спасибо большое!

Dragokas · 08.08.2015, 16:47

Не по теме:

Сообщение от alpap

каждой первой позиции for соответствовала первая позиция второго for, затем вторая

Ну, дык. Я делал все в точности с заданием (только первая позиция).
Я сейчас здесь редко. Думаю, важнее получить хотя бы такой ответ, чем не получить его вообще.

@alpap · 08.08.2015, 21:56 **[ТС]**

Dragokas,

Сообщение от Dragokas

Я делал все в точности с заданием

- за что и уважаю.

Новые блоги и статьи Все статьи Все блоги /
BOINC: 22 года — и всё ещё работает Programma_Boinc 12.03.2026 BOINC: 22 года — и всё ещё работает Дэвид Андерсон написал ретроспективу. Кратко: в 2001 году он ушёл из United Devices, где был CTO, и за несколько месяцев написал ядро BOINC — клиент, сервер,. . .	SDL3 для Desktop (MinGW): Создаём пустое окно с нуля для 2D-графики на SDL3, Си и C++ 8Observer8 10.03.2026 Содержание блога Финальные проекты на Си и на C++: hello-sdl3-c. zip hello-sdl3-cpp. zip Результат:	Установка CMake и MinGW 13.1 для сборки С и C++ приложений из консоли и из Qt Creator в EXE 8Observer8 10.03.2026 Содержание блога MinGW - это коллекция инструментов для сборки приложений в EXE. CMake - это система сборки приложений. Здесь описаны базовые шаги для старта программирования с помощью CMake и. . .	Как дизайн сайта влияет на конверсию: 7 решений, которые реально повышают заявки Neotwalker 08.03.2026 Многие до сих пор воспринимают дизайн сайта как “красивую оболочку”. На практике всё иначе: дизайн напрямую влияет на то, оставит человек заявку или уйдёт через несколько секунд. Даже если у вас. . .
Модульная разработка через nuget packages DevAlt 07.03.2026 Сложившийся в . Net-среде способ разработки чаще всего предполагает монорепозиторий в котором находятся все исходники. При создании нового решения, мы просто добавляем нужные проекты и имеем. . .	Модульный подход на примере F# DevAlt 06.03.2026 В блоге дяди Боба наткнулся на такое определение: В этой книге («Подход, основанный на вариантах использования») Ивар утверждает, что архитектура программного обеспечения — это структуры,. . .	Управление камерой с помощью скрипта OrbitControls.js на Three.js: Вращение, зум и панорамирование 8Observer8 05.03.2026 Содержание блога Финальная демка в браузере работает на Desktop и мобильных браузерах. Итоговый код: orbit-controls-threejs-js. zip. Сканируйте QR-код на мобильном. Вращайте камеру одним пальцем,. . .	SDL3 для Web (WebAssembly): Синхронизация спрайтов SDL3 и тел Box2D 8Observer8 04.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-sync-physics-sprites-sdl3-c. zip На первой гифке отладочные линии отключены, а на второй включены:. . .

Параллельный перенос (переименование)

Решение

Решение

@alpap 4340 / 2130 / 661 Регистрация: 26.04.2015 Сообщений: 6,823
	07.08.2015, 20:12 [ТС]
	Dragokas, Спасибо, код работает, только зачем pause в строке 5, если для проверки построчно и перед exit ту же роль выполняет - ну неважно. Не обижайтесь, но лучший ответ поставлю ComSpec, скорее из-за моей неопытности - его код для меня проще (понятнее). Добавлено через 48 секунд ComSpec, Все так просто оказывается, а я что-то не допер, Спасибо огромное! 0

@alpap 4340 / 2130 / 661 Регистрация: 26.04.2015 Сообщений: 6,823
	08.08.2015, 09:49 [ТС]
	Dragokas, Ну, если бы Вы сразу мне об этом сказали, правда, с Вашей стороны - может я знал, тогда и оценил бы по-другому. Вот теперь знаю - Спасибо большое! 0