В каталоге и его подкаталогах найти и скопировать в отдельный подкаталог все файлы, созданные после 14:00

@krasnovrus · Регистрация: 15.12.2015

В каталоге, который указан первым параметром bat-файла, и его подкаталогах, найти файлы, созданные после 14 часов (за весь период работы компа), скопировать их в отдельный подкаталог.

Есть команда Findstr, но она здесь не причастна. Хотел использовать XCOPY, есть там выборка /D m -d -y, позволяющая копировать файлы,измененные не ранее указанной даты, но про время не сказано ничего.

Помогите основную часть программы написать. Я думаю,что вся программа в одну - две строчки, но ума не приложу,как реализовать данную сортировку.

Спасибо!

@b0gus · 15.12.2015, 20:30

Сообщение от krasnovrus

В каталоге, который указан первым параметром bat-файла, и его подкаталогах, найти файлы, созданные после 14 часов (за весь период работы компа), скопировать их в отдельный подкаталог.

Windows Batch file

@echo off
:: файл "батника" сохранить в кодировке 866
cls
SetLocal EnableExtensions EnableDelayedExpansion
if "%~1"=="" echo.%~n0: не указан каталог для поиска файлов&pause&exit /b 1
set "from=%*"
if "%from:~-1%" == "\" set "from=%from:~0,-1%"  &:: на всякий случай избавляемся от завершающего слэша
if NOT exist "%from%" echo.%~n0: отcутствует каталог "%from%"&pause&exit /b 2
 
:: каталог для результата
set "to=диск:\путь1\путь2"
if NOT exist "%to%" md "%to%"
 
:: время создания файлов-кандидатов для копирования в %to%
set "stamp_time=14:00"&set y=!stamp_time::=!
 
for /f "tokens=*" %%v in ('dir "%from%\*.*" /b/s/a:-d') do call :compare %%~tv&&copy "%%v" "%to%\*.*">nul
for %%v in ("%to%\*.*") do goto:OK
echo.%~n0: в каталоге "%from%" нет файлов старше %stamp_time%&pause&exit /b 3
:OK
echo.%~n0: в каталоге "%to%" лежат файлы старше %stamp_time%&pause&exit /b 0
:compare
  setlocal
  set "x=%2"&set "x=!x::=!"
  if %x% LEQ %y% (exit /b 1) else (exit /b 0)

@krasnovrus · 16.12.2015, 11:47 **[ТС]**

Большое спасибо! Наконец, я до конца разобрался с данной программой. Вы-гений!

@krasnovrus 0 / 0 / 0 Регистрация: 15.12.2015 Сообщений: 2
		1
	В каталоге и его подкаталогах найти и скопировать в отдельный подкаталог все файлы, созданные после 14:00 15.12.2015, 15:12. Показов 2069. Ответов 2 Метки нет (Все метки) В каталоге, который указан первым параметром bat-файла, и его подкаталогах, найти файлы, созданные после 14 часов (за весь период работы компа), скопировать их в отдельный подкаталог. Есть команда Findstr, но она здесь не причастна. Хотел использовать XCOPY, есть там выборка /D m -d -y, позволяющая копировать файлы,измененные не ранее указанной даты, но про время не сказано ничего. Помогите основную часть программы написать. Я думаю,что вся программа в одну - две строчки, но ума не приложу,как реализовать данную сортировку. Спасибо! __________________ Помощь в написании контрольных, курсовых и дипломных работ, диссертаций здесь 0

@krasnovrus 0 / 0 / 0 Регистрация: 15.12.2015 Сообщений: 2
	16.12.2015, 11:47 [ТС]	3
	Большое спасибо! Наконец, я до конца разобрался с данной программой. Вы-гений! 0

Опции темы

В каталоге и его подкаталогах найти и скопировать в отдельный подкаталог все файлы, созданные после 14:00

Решение